データグリッドビューのチェックボックスについて

Question

はじめて利用させていただきます。

VB.NETで開発を行っている初心者です。

今回VisualStudioでDataGridViewを題材として開発の勉強を行っているのですが手がつまりました。

お力添えをお願いします。

■現在の状況
DataGridViewでCSVを読み込み、表示させている状態です。
一番左の列がチェックボックス
二つがテキストカラム
１つがリンクカラムとなっています。

■実現させたいこと
１.チェックボックスをクリックした時に、行を全選択させたい。
（行のヘッダーをクリックした時と同じ状態）

２．チェックボックスにチェックを複数入れた状態で削除のボタンをクリック
した時に削除できるようにしたい。
ここの部分は削除ボタンを作成したのでイベント的にはボタンクリックのイベントになると思われます。

以上です。

セルをクリックしたときに行を全選択できるようにして、削除ボタンを押したらその選択されている行を削除ボタンを押すことによって削除できるところまではなんとかできました。

チェックボックスにチェックを入れたら行が前選択される
（複数のチェックボックスにチェックを入れて行の削除を行いたいのです）

このことがどう頑張ってもできないのでお助けください。
数多ある中で頻出している題材だとは思うのですがん煎撮ぞ宜しくお願い致します。

Answer 1

多分ですが、チェックボックスをクリックしたらチェックされた行を識別したいという事でしょうか？
それならこれでどうでしょうか？

全て選択、解除のリンクラベルクリック

    Private Sub lnk_全て_LinkClicked(sender As System.Object, e As System.Windows.Forms.LinkLabelLinkClickedEventArgs) Handles lnk_全て.LinkClicked, lnk_解除.LinkClicked
        For _カウンター = 0 To データグリッド.RowCount - 1
            If sender Is lnk_全て Then
                データグリッド(clm_選択.Index, _カウンター).Value = True
            Else
                データグリッド(clm_選択.Index, _カウンター).Value = False
            End If
        Next
    End Sub

データグリッドの選択チェックが変更された

    Private Sub データグリッド_CellValueChanged(sender As Object, e As System.Windows.Forms.DataGridViewCellEventArgs) Handles データグリッド.CellValueChanged
        If データグリッド.RowCount <= 0 Then
            Exit Sub
        End If

        If e.ColumnIndex = clm_選択.Index Then
            If データグリッド(clm_選択.Index, e.RowIndex).Value Then
                データグリッド.Rows(e.RowIndex).DefaultCellStyle.BackColor = Color.DarkSlateBlue
                データグリッド.Rows(e.RowIndex).DefaultCellStyle.ForeColor = Color.White
            Else
                データグリッド.Rows(e.RowIndex).DefaultCellStyle.BackColor = Color.Empty
                データグリッド.Rows(e.RowIndex).DefaultCellStyle.ForeColor = Color.Empty
            End If
        End If
    End Sub

Answer 2

質問を読むと、どこまでできているのかよくわからないのですが…。
2.チェックボックスにチェックを複数入れた状態で削除のボタンをクリックした時に削除できるようにしたい。
の方は以下でできると思います。(同じようなことをやっていて他の方に教えていただいたのですが・・。)

Private Sub ButtonDelete_Click_1(sender As Object, e As EventArgs) Handles ButtonDelete.Click
      
   '最下行から上に向かってチェックボックスにチェックが入っているかどうかループで判断していく
    Dim i As Integer
          For i = DataGridView1.Rows.Count - 1 To 0 Step -1
                'チェックが入っている場合は行削除
         If DataGridView1(colSELFLG, i).Value = True Then
                   DataGridView1.Rows.RemoveAt(i)
               End If
           Next

   End Sub

Answer 3

こんにちは。
こうですかね。

Public Class Form1

    Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
        With dgv
            .AllowUserToAddRows = False
            .Columns.Add(New DataGridViewCheckBoxColumn() With {.HeaderText = "check",
                                                                .Name = "column1"})
            .Columns.Add("column2", "text1")
            .Columns.Add("column3", "text2")
            .Rows.Add(False, "A1", "B1")
            .Rows.Add(False, "A2", "B2")
            .Rows.Add(False, "A3", "B3")
        End With
        AddHandler dgv.CurrentCellDirtyStateChanged, AddressOf dgv_CurrentCellDirtyStateChanged
        AddHandler dgv.CellValueChanged, AddressOf dgv_CellValueChanged
    End Sub

    Sub dgv_CurrentCellDirtyStateChanged(ByVal sender As Object, ByVal e As EventArgs)
        If dgv.CurrentCellAddress.X = 0 AndAlso dgv.IsCurrentCellDirty Then
            dgv.CommitEdit(DataGridViewDataErrorContexts.Commit)
        End If
    End Sub

    Sub dgv_CellValueChanged(ByVal sender As Object, ByVal e As DataGridViewCellEventArgs)
        dgv.SuspendLayout()
        If e.ColumnIndex = 0 Then
            For Each row As DataGridViewRow In dgv.Rows
                row.Selected = CBool(row.Cells(0).Value)
            Next
        End If
    End Sub

End Class

Answer 4

初めまして
DataGridViewのオプションで「MultiSelect」を「True」、「SelectionMode」を「FullRowSelect」にして以下のようにしてはどうでしょうか。

＜VB＞
Private Sub DataGridView1_LostFocus(sender As Object, e As System.EventArgs) Handles DataGridView1.LostFocus

    Me.DataGridView1.EndEdit()
    For Rw As Integer = 0 To Me.DataGridView1.RowCount - 1
        Dim Ck As Boolean = Me.DataGridView1.Rows(Rw).Cells(0).Value
        If Ck = True Then
            Me.DataGridView1.Rows(Rw).Selected = True
        Else
            Me.DataGridView1.Rows(Rw).Selected = False
        End If
    Next
End Sub