【VBA】特定の文字までを取得する方法

Question

VBAのことでお聞きしたいことがあります。

■やりたいこと
・サイトのディレクトリデータが入っている列から最後の「／」以降の文字を除いた文字を取得

例）「/test/test2/index.html」とデータがあったら「/test/test2」と取得したい
ただしすべて「/test/test2」というディレクトリになっておらず「/about/index.html」や「/campany/price/test/index.html」などの場合もある。
またファイル名もバラバラ。

指定した文字以降を取得するというコードは見つけたのですが指定する文字が「/」だといくつもあってうまく取得できないじゃんと悩んでおります。

Answer 1

InStrRev関数を使えば右から検索してくれます

Dim url
url = "/test/test2/index.html"
Dim lastindex As Integer
lastindex = InStrRev(url, "/")
MsgBox (Mid(url, 1, lastindex))

みたいな感じで
いろいろなエラーは考慮していません

Answer 2

Midで切り出すのが定番かと思いますが、敢えて別の方法を書いてみます。

Dim items() As String
items = Split("/test/test2/index.html", "/")
ReDim Preserve items(UBound(items) - 1)
path2 = Join(items, "/")
Debug.Print path2

Answer 3

Function DirPath(s)
  Dim i
  i = InStrRev(s, "/")
  If i < 0 Then
    DirPath = s
    Exit Function
  End If
  DirPath = Left(s, i-1)
End Function

' DirPath("/foo/bar/baz")) = /foo/bar
' DirPath("/foo/bar/"))    = /foo/bar
' DirPath("/foo"))         = /foo
' DirPath("/"))            = 空

もし最後の / を残したいのであれば i-1 の部分を i にして下さい。

Answer 4

フルパスからディレクトリパスを取得するのでしたら、以下の正規表現で抽出可能です。
「^.*/」

下記例では、full_path からdir_path への変換を行っています。

    Dim full_path As String
    Dim dir_path As String
    
    full_path = "/test/test2/index.html"
    
    Dim reg, Match
    
    Set reg = CreateObject("VBScript.RegExp")
    reg.Pattern = "^.*/"     'パターン設定
    reg.Global = True       '文字列全体検索
    
    Set Match = reg.Execute(full_path)
    If Match.Count > 0 Then
        dir_path = Match(0).Value
    End If