vbsからコマンド実行して、その処理が終わるまで次の処理に行かないようにしたい

Question

VBSファイルから外部コマンドを実行して、その処理が終わるまで次の処理を走らさないようにしたいです。

WshShell.Runを使用することで、それは可能だということはわかったのですが、
今度は管理者権限でコマンド実行する方法が分かりません。
WshShell.Runでも管理者権限で実行できるのでしょうか？

現状はこれでコマンド実行できているのですが、処理が終わる前に次の処理が走ってしまいます。。

Set app = Wscript.CreateObject("Shell.Application")
	'app.ShellExecute "Dism.exe", "/online /enable-feature /featurename:NetFX3 /All /Source:C:\sources\sxs /LimitAccess", ,"runas"

下記のようにWshShell.Runにすると、管理者権限で実行できない。。

	Dim WshShell
	Set WshShell = WScript.CreateObject("WScript.Shell")
	WshShell.Run("Dism.exe /online /enable-feature /featurename:NetFX3 /All /Source:C:\sources\sxs /LimitAccess")

どなたかご教授いただけると幸いです。

Answer 1

自身を管理者権限で再起動する手段ではいかがでしょうか？
VBScriptを管理者権限で実行する

Win10x64で動作しました。

手順

• hoge.wsfをダブルクリックして起動
• UAC画面が表示されるので「はい」を選択
• dism.exe画面が表示～実行される
• 終了（長いのでCtrl+Cで中断）後に「end」表示される。

hoge.wsf

<job>
<script language="VBScript">
' Vista以上なら、このスクリプトを管理者権限で再起動する
do while WScript.Arguments.Count=0 and WScript.Version>=5.7
    'WScript.Echo "for runas ScriptFullName[" & WScript.ScriptFullName & "]"
    'Run this script as admin.
    Set sha=CreateObject("Shell.Application")
    sha.ShellExecute "wscript.exe","""" + WScript.ScriptFullName + """ uac","","runas"
    WScript.Quit
loop
'WScript.Echo "main ScriptFullName[" & WScript.ScriptFullName & "]"

' 実際の処理

Set WshShell = WScript.CreateObject("WScript.Shell")
' 1=画面表示, True=同期
WshShell.Run "Dism.exe /Online /Cleanup-Image /ScanHealth", 1, True

' 終了後に表示される
WScript.Echo "end"
</script>
</job>

Answer 2

両立は出来ないと思うので、プロセス起動後に、プロセス一覧を取得して、実行中のプロセスが終了するまでsleepしながら、ループするくらいでしょうか。

Comments

[javabigineer]

ご解答ありがとうございます。
プロセスの起動等、よくわかっていないのですが、shellexecuteのやり方にプロセス起動の処理を追加するようなイメージでしょうか？

[otn]

shellexecute =「プロセスの起動」
です。

[javabigineer]

プロセスが終了するまでループとは、たとえばどのような処理になるでしょうか？
自分で調べるべきということは重々承知しておりますが、急ぎの案件ですのでお力添えいただけると助かります！

[otn]

ループは、do ～ loop です。プロセスが終了したら、exit doでループを抜けます。
実行中のプロセス一覧を得るのは、「vbs プロセス一覧」とかでググって下さい。
> 急ぎの案件ですので
急がば回れです。

Answer 3

スクリプトの中で管理者権限を持つユーザーに昇格することはできません。管理者権限で起動したコマンドプロンプトから自分のスクリプトを起動するか、自分のスクリプトを起動するバッチファイルを作って、それを管理者権限で実行すれば良いと思います。

Comments

[javabigineer]

runas では管理者権限で実行できないということでしょうか？
実行ファイルは複数にしたくないのですが、やりようないんですかね。。

[tohshima]

言葉足らずでした。
「スクリプトの途中の処理から管理者権限が必要な処理を行えない」ですね。おっしゃるように、runasも手段の一つだと思います。