フォームのテキストボックスにスペースのみが入力されていたらエラーを出力したい

Question

###前提・実現したいこと

フォームからエクセルシートに入力値を転記するシステムを作っています。
フォームにスペースのみ入力されている場合はエラーメッセージを出力する処理を実装中に手詰まっております。Trim関数でスペースだけが入力されている場合はif内の条件に合わないため、何も処理が行われないようにしているはずですが、現時点ではフォームに入力された値すらシートに転記されない状態です。下記、ソースコードになります。どのように処理を記述すればうまくいくのかわかる方、ご教示願います。

###該当のソースコード

Private Sub CommandButton1_Click()

    If TextBox1.Value = "" Or TextBox2.Value = "" Or TextBox3.Value = "" Or TextBox4.Value = "" Or TextBox5.Value = "" Then
        MsgBox "空欄を埋めてください。"
    Else
        n = Worksheets("DB").Cells(Rows.Count, "A").End(xlUp).Row + 1
        If Trim(TextBox1.Value) <> "" Then
            Range("A" & n).Value = TextBox1.Value
        End If
        n = Worksheets("DB").Cells(Rows.Count, "B").End(xlUp).Row + 1
        If Trim(TextBox2.Value) <> "" Then
            Range("B" & n).Value = TextBox2.Value
        End If
        n = Worksheets("DB").Cells(Rows.Count, "C").End(xlUp).Row + 1
        If Trim(TextBox3.Value) <> "" Then
            Range("C" & n).Value = TextBox3.Value
        End If
        n = Worksheets("DB").Cells(Rows.Count, "D").End(xlUp).Row + 1
        If Trim(TextBox4.Value) <> "" Then
            Range("D" & n).Value = TextBox4.Value
        End If
        n = Worksheets("DB").Cells(Rows.Count, "E").End(xlUp).Row + 1
        If Trim(TextBox5.Value) <> "" Then
        Range("E" & n).Value = TextBox5.Value
        End If
        
        TextBox1.Value = ""
        TextBox2.Value = ""
        TextBox3.Value = ""
        TextBox4.Value = ""
        TextBox5.Value = ""
        
    End If
    
End Sub

###試したこと
Trim関数でif文を設置してみましたが、うまくいっておりません。

分かる方、ご教示お願いいたします。

Answer 1

現時点ではフォームに入力された値すらシートに転記されない状態です。

        n = Worksheets("DB").Cells(Rows.Count, "A").End(xlUp).Row + 1
        If Trim(TextBox1.Value) <> "" Then
            Range("A" & n).Value = TextBox1.Value
        End If

上記のコードですが、Range("A" & n).Value というようにシート参照を省略するとアクティブなシートを参照することになります。 Worksheets("DB"). を省略しないほうがいいでしょう。なお、同じオブジェクトを繰り返し参照するときは、変数に代入して変数を使うか、Withを使うといいでしょう。

フォームにスペースのみ入力されている場合はエラーメッセージを出力する

スペースのみの入力も、未入力もエラーメッセージを出すなら、最初のIf文でもTrimを付けないとだめではないでしょうか。また、最初のIf文でチェックしておけば、後半のIf文は必要ないでしょう。

この２点を考慮すると、下記のようなコードになります。

    Dim n As Long

    If Trim(TextBox1.Value) = "" Or Trim(TextBox2.Value) = "" Or _
       Trim(TextBox3.Value) = "" Or Trim(TextBox4.Value) = "" OR _
       Trim(TextBox5.Value) = "" Then
        MsgBox "空欄を埋めてください。"
    Else
        With Worksheets("DB")      
            n = .Cells(Rows.Count, "A").End(xlUp).Row + 1
            .Range("A" & n).Value = TextBox1.Value
            n = .Cells(Rows.Count, "B").End(xlUp).Row + 1
            .Range("B" & n).Value = TextBox2.Value
            n = .Cells(Rows.Count, "C").End(xlUp).Row + 1
           .Range("C" & n).Value = TextBox3.Value
            n = .Cells(Rows.Count, "D").End(xlUp).Row + 1
           .Range("D" & n).Value = TextBox4.Value
            n = .Cells(Rows.Count, "E").End(xlUp).Row + 1
           .Range("E" & n).Value = TextBox5.Value
        End With
        TextBox1.Value = ""
        TextBox2.Value = ""
        TextBox3.Value = ""
        TextBox4.Value = ""
        TextBox5.Value = ""
    End If

Answer 2

If TextBox1.Value = "" Or TextBox2.Value = "" Or TextBox3.Value = "" Or TextBox4.Value = "" Or TextBox5.Value = "" Then

の部分もやはりTrim()を効かせて、

If Trim(TexBox1.Text) = "" Or Trim(TexBox2.Text) = "" Or Trim(TexBox3.Text) = "" Or Trim(TexBox4.Text) = "" Or Trim(TexBox5.Text) = "" Then

としたらよいでしょう。