バッチのファイル名と引数について

Question

やはり上手く行きません。
以下のバッチを>MyCopy.bat test.txtと実行した所、
(test.txtと言うファイルを日付_test.txtと言うファイル名でコピーする)

test.txt_20170504.txtというファイルが出来てしまいました。
test_201705.txtの様にしたいのですが、一体どうすればよいのでしょうか？

---

set year=%date:~0,4%
set month=%date:~5,2%
set day=%date:~8,2%

set newdate=%year%%month%%day%
echo %newdate%

copy %1 %1_%newdate%.txt

ホント・・・バッチってよく分かりません。。。。。
昨日から、何十回と書き直したことか・・・・

どなたか助けてください。

Answer 1

%~n1などで、コマンドライン引数で渡されたファイルパスからファイル名などを抽出することができます。

@echo off
set year=%date:~0,4%
set month=%date:~5,2%
set day=%date:~8,2%
set filename=test.txt

set newdate=%year%%month%%day%
echo 日付部分：%newdate%

echo コピー元：%1

rem ドライブ名(d)＋ディレクトリ名(p)＋元ファイル名(n)＋日付(newdate)＋拡張子(x)
rem c:\users\hoge\file_20170504.txt など
set dst_path=%~dpn1_%newdate%%~x1
echo コピー先（フルパス）：%dst_path%

pause

参考：バッチファイルでファイルパスからファイル名や拡張子を自由に取り出す方法

Answer 2

%1にはバッチファイル起動時に指定した引数が入るので、最後のCOPYコマンドの変数展開結果は以下のようになっています。

copy test.txt test.txt_日付.txt

従って、copyコマンドのcopy先ファイル名には%1をそのまま使うのではなく、拡張子をとったものを指定する必要があります。拡張子が.を含んで4文字固定という前提でよいならば、以下のように出来ます。

set name=%1
set name=%name:~0,-4%
copy %1 %name%_%newdate%.txt

やみくもに修正するのではなく、echoなどで変数の中身を確認しながら進めてください。

Answer 3

これがお望みの結果になるかわかりませんが

set year=%date:~0,4%
set month=%date:~5,2%
set day=%date:~8,2%
set filename=test.txt

set newdate=%year%%month%%day%
echo %newdate%
for /f %%i in ('echo %filename%') do set fname=%%~ni
echo %fname%_%newdate%.txt

Result

20170504
test_20170504.txt