VB.NETにおける、画面遷移処理の共通化について

Question

###実現したいこと
VB.NETを利用して、新たな業務画面の構築をしようと考えています。
現在は、そのシステムの基盤となる基底クラス等の設計をしているところなのですが、画面遷移の共通化で躓いています。

###発生している問題
画面遷移をする時に、下記のコードを書けば遷移できるのですが、この同じような処理を各フォームに入れるのは少し面倒だと感じています。
(form1からform2に遷移する場合…)

Dim form2 As New form2 '遷移先
form2.Show()
My.Application.ApplicationContext.MainForm = form2
form1.Dispose() 'form1を閉じる

なので、理想としては子クラスは下記の様に実装して遷移は基底クラスにやらせたいと考えています。

Dim form2 As New form2 '遷移先
forwardScreen(form1,form2) 'form1を閉じてform2へ遷移する

###試したこと
下記の様に基底クラスを実装してみましたが、上手くいきませんでした。

    ''' <summary>
    ''' 画面を遷移する
    ''' </summary>
    ''' <param name="TransitionOriginal">遷移元</param>
    ''' <param name="TransitionTarget">遷移先</param>
    Protected Sub forwardScreen(TransitionOriginal As Form, TransitionTarget As form)
        TransitionTarget.Show()
        My.Application.ApplicationContext.MainForm = TransitionTarget
        TransitionOriginal.Dispose()
    End Sub

分かる方がいらっしゃいましたら、ご教示ください。

宜しくお願い致します。

Answer 1

うまくいきますが、何が問題でした？

基底クラス（BaseForm.vb）

Public Class BaseForm
    Inherits Form

    ''' <summary>
    ''' 画面を遷移する
    ''' </summary>
    ''' <param name="TransitionOriginal">遷移元</param>
    ''' <param name="TransitionTarget">遷移先</param>
    Protected Sub forwardScreen(TransitionOriginal As Form, TransitionTarget As Form)
        TransitionTarget.Show()
        My.Application.ApplicationContext.MainForm = TransitionTarget
        TransitionOriginal.Dispose()
    End Sub

End Class

Form1.vb

Public Class Form1
    Inherits BaseForm '★System.Windows.Forms.Form から BaseForm に変更

    Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
        Dim form2 As New Form2 '遷移先
        forwardScreen(Me, form2) 'form1を閉じてform2へ遷移する
    End Sub
End Class

Form1.Designer.vb

<Global.Microsoft.VisualBasic.CompilerServices.DesignerGenerated()> _
Partial Class Form1
    Inherits BaseForm '★System.Windows.Forms.Form から BaseForm に変更

    '～以下省略
End Class

Form2.vb

Public Class Form2
    Inherits BaseForm '★System.Windows.Forms.Form から BaseForm に変更

    Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
        Dim form1 As New Form1 '遷移先
        forwardScreen(Me, form1) 'form2を閉じてform1へ遷移する
    End Sub
End Class

Form2.Designer.vb

<Global.Microsoft.VisualBasic.CompilerServices.DesignerGenerated()> _
Partial Class Form2
    Inherits BaseForm '★System.Windows.Forms.Form から BaseForm に変更

    '～以下省略
End Class

Comments

[motuo]

ありがとうございました。form1 = Meとして基底クラスでform1.disposeとしても動作しなかったのですが、ご提示いただいた方法で問題なく遷移出来ました。
ありがとうございました。