質問をすることでしか得られない、回答やアドバイスがある。

15分調べてもわからないことは、質問しよう!

ただいまの
回答率

88.93%

VBA Dictionaryオブジェクトの質問

解決済

回答 1

投稿

  • 評価
  • クリップ 0
  • VIEW 2,325

cd987456

score 33

Dictionaryオブジェクトを使って割り付けをしています。
2つのシートがあります。
『抽出結果』シートと『条件』シートです。
『条件』シートのA列、B列、c列にデータが入っています。
『抽出結果』シートのA列、B列にデータが入っています。

やりたいことは、
『抽出結果』シートのA列とB列のデータと『条件』シートのA列とB列のデータが一致したら
『条件』シートのC列のデータを『抽出結果』シートのC列に記載する。 

先日このサイトで教えてもらったコードを自分なりに変更して書いてみました。

Public Sub dic_04_2()
    Dim mydic As Object
    Dim i As Long
    Dim ary1
    Dim ary2(2 To 180000, 0) As Long
    Dim maxrow As Long

    Application.ScreenUpdating = False
    Application.EnableEvents = False

    Set mydic = CreateObject("Scripting.Dictionary")

    With Sheets("条件")
        maxrow = .Cells(Rows.Count, 1).End(xlUp).Row
        ary1 = .Range(.Cells(2, 1), .Cells(maxrow, 3))
        For i = maxrow To 2 Step -1
            mydic(ary1(i - 1, 1) & "," & ary1(i - 1, 2)) = ary1(i - 1, 3)
        Next i
    End With

    With Sheets("抽出結果")
        maxrow = .Cells(Rows.Count, 1).End(xlUp).Row
        For i = 2 To maxrow
            ary2(i, 0) = mydic.Item(.Cells(i, 1).Value & "," & .Cells(i, 2).Value)
        Next
        .Range(.Cells(2, 3), .Cells(maxrow, 3)) = ary2
    End With

    Set mydic = Nothing

    Application.EnableEvents = True
    Application.ScreenUpdating = True
End Sub


エラーにはならないですが、2つの条件に一致するように上手く処理されません。
修正点を教えて下さい。

  • 気になる質問をクリップする

    クリップした質問は、後からいつでもマイページで確認できます。

    またクリップした質問に回答があった際、通知やメールを受け取ることができます。

    クリップを取り消します

  • 良い質問の評価を上げる

    以下のような質問は評価を上げましょう

    • 質問内容が明確
    • 自分も答えを知りたい
    • 質問者以外のユーザにも役立つ

    評価が高い質問は、TOPページの「注目」タブのフィードに表示されやすくなります。

    質問の評価を上げたことを取り消します

  • 評価を下げられる数の上限に達しました

    評価を下げることができません

    • 1日5回まで評価を下げられます
    • 1日に1ユーザに対して2回まで評価を下げられます

    質問の評価を下げる

    teratailでは下記のような質問を「具体的に困っていることがない質問」、「サイトポリシーに違反する質問」と定義し、推奨していません。

    • プログラミングに関係のない質問
    • やってほしいことだけを記載した丸投げの質問
    • 問題・課題が含まれていない質問
    • 意図的に内容が抹消された質問
    • 過去に投稿した質問と同じ内容の質問
    • 広告と受け取られるような投稿

    評価が下がると、TOPページの「アクティブ」「注目」タブのフィードに表示されにくくなります。

    質問の評価を下げたことを取り消します

    この機能は開放されていません

    評価を下げる条件を満たしてません

    評価を下げる理由を選択してください

    詳細な説明はこちら

    上記に当てはまらず、質問内容が明確になっていない質問には「情報の追加・修正依頼」機能からコメントをしてください。

    質問の評価を下げる機能の利用条件

    この機能を利用するためには、以下の事項を行う必要があります。

回答 1

checkベストアンサー

0

当方のサンプルでは、提示のコードで問題なく結果が書き込まれました。

具体的に、どのようにうまくいかないのでしょうか。
エラーがでるなら、そのエラー内容、
結果が想定と違うなら、サンプルのデータとその結果を提示してもらえませんか。

ちなみに、
Dim ary2(2 To 180000, 0) As Long
は、私のサンプルが参照するセルが数値だったので、Long にしましたが、
文字列だったら、String にするなどそちらのデータ型にあわせてくださいね。

動作検証

質問のコード、さらに下記のチューンナップコード、
どちらでも下図のように想定の結果となりました。

イメージ説明

ダミーのデータでなく、実際に想定外の結果になるデータを提示できませんか。

さらにチューンナップ

コードを見直してみたら、"抽出結果"シートでセル毎に読み込みしていたので、それも 配列 に一気に読み込むようにしてみました。これで、前回よりさらに倍以上高速化できました。

あと、参照結果の書き込み用の配列も動的配列にして、配列のサイズをデータ数に合わせて、無駄にメモリを使用しないようにしました。

Public Sub dic_04_4()
    Dim mydic As Object
    Dim i As Long
    Dim ary1()
    Dim ary2() '動的配列として宣言
    Dim maxrow As Long

    Application.ScreenUpdating = False
    Application.EnableEvents = False

    Set mydic = CreateObject("Scripting.Dictionary")

    With Sheets("条件")
        maxrow = .Cells(Rows.Count, 1).End(xlUp).Row
        ary1 = .Range(.Cells(2, 1), .Cells(maxrow, 3)).Value
        For i = UBound(ary1) To LBound(ary1) Step -1
            mydic(ary1(i, 1) & "," & ary1(i, 2)) = ary1(i, 3)
        Next i
    End With

    With Sheets("抽出結果")
        maxrow = .Cells(Rows.Count, 1).End(xlUp).Row
        ReDim ary2(2 To maxrow, 0) '動的配列のサイズを宣言    
        Erase ary1 '配列の初期化
        ary1 = .Range(.Cells(2, 1), .Cells(maxrow, 2)).Value
        For i = LBound(ary1) To UBound(ary1)
            ary2(i + 1, 0) = mydic.Item(ary1(i, 1) & "," & ary1(i, 2))
        Next
        .Range(.Cells(2, 3), .Cells(maxrow, 3)).Value = ary2
    End With

    Set mydic = Nothing
    Application.EnableEvents = True
    Application.ScreenUpdating = True
End Sub

投稿

編集

  • 回答の評価を上げる

    以下のような回答は評価を上げましょう

    • 正しい回答
    • わかりやすい回答
    • ためになる回答

    評価が高い回答ほどページの上位に表示されます。

  • 回答の評価を下げる

    下記のような回答は推奨されていません。

    • 間違っている回答
    • 質問の回答になっていない投稿
    • スパムや攻撃的な表現を用いた投稿

    評価を下げる際はその理由を明確に伝え、適切な回答に修正してもらいましょう。

  • 2017/05/01 18:12

    回答ありがとうございます。
    条件シートの内容が A列が取引先、B列が商品名、C列が納期 となっています。
    A列とB列のデータが重複していることはありません。

    例えば、条件シートに以下のデータがあったとします。
     取引先A社  テレビ  2017/5/1
     取引先B社  テレビ  2017/4/3

    抽出結果シートには
     取引先A社  テレビ  2017/4/3
     取引先B社  テレビ  2017/4/3
    と表示されます。※エラーは出ません。
    ★抽出結果シートは
     取引先A社  テレビ  2017/5/1
     取引先B社  テレビ  2017/4/3
    となってほしいのですが、上手くいきません。
    条件シート、抽出結果シート共に2列の条件が一致した時のデータを返してほしいです。




    キャンセル

  • 2017/05/02 10:44

    回答ありがとうございます。
    上手く処理できていました。
    検証データに余分なデータが混じっていました。
    データの重複を監視するプログラムも入れた方がよかったです。
    すいませんでした。

    チューンナップして頂いたコードでさらに早く処理出来ました。
    ありがとうございました。

    キャンセル

15分調べてもわからないことは、teratailで質問しよう!

  • ただいまの回答率 88.93%
  • 質問をまとめることで、思考を整理して素早く解決
  • テンプレート機能で、簡単に質問をまとめられる

関連した質問

同じタグがついた質問を見る