awkで重複している行の足し算

Question

新木場駅        135,180
新木場駅        96,852
新木場駅        52,325
新小岩駅        141,760
新高円寺駅      33,392
新桜台駅        6,407
新柴又駅        3,660
新宿駅  1,485,666
新宿駅  714,949
新宿駅  474,552
新宿駅  257,455
新宿駅  220,154

上記のような駅の乗降車数のcsvファイルが有ります。
駅名が同じものの乗降車数を足して重複をなくしたいのですが、awkの書き方がわかりません。

希望の出力結果

新木場駅        284,357
新小岩駅        141,760
新高円寺駅      33,392
新桜台駅        6,407
新柴又駅        3,660
新宿駅          3152776

教えていただけますでしょうか？

Answer 1

連想配列を使っていますので、順番通りに駅名が出ませんけど、もう少し頑張ればできるでしょう。
3桁区切りも同様。

#!/usr/bin/awk -f
{
	station = $1;

	passengers = $2;
	gsub(/,/, "", passengers);

	passengersAtStation[station] += passengers;
}

END {
	for (station in passengersAtStation) {
		printf("%s\t%d\n", station, passengersAtStation[station]);
	}
}

解決済になっていますけど、駅名を出現順に、乗降客数を3桁区切りで表示するバージョンを示しておきます。

#!/usr/bin/awk -f
function putCommaAtEvery3Digits(input,		output) {
	for (output = ""; input >= 1000; input = int(input / 1000)) {
		output = sprintf(",%03d", input % 1000) output;
	}
	output = input output;
	
	return output;
}


function registerStation(station,		stationIndex) {
	for (stationIndex = 0; stationIndex < stationCount; stationIndex++) {
		if (stationList[stationIndex] == station) {
			return stationIndex;
		}
	}

	stationList[stationCount++] = station;
	return stationCount;
}


{
	station = $1;
	registerStation(station);

	passengers = $2;
	gsub(/,/, "", passengers);

	passengersAtStation[station] += passengers;
}


END {
	for (stationIndex = 0; stationIndex < stationCount; stationIndex++) {
		station = stationList[stationIndex];
		printf("%s\t%s\n", station, putCommaAtEvery3Digits(passengersAtStation[station]));
	}
}

Comments

[DaichiYasuda]

ファイル名をどこで指定したらよろしいでしょうか？

[DaichiYasuda]

cat で出力して実行できました！
ありがとうございました

[naomi3]

もう実行できているとのことが、ちなみに、awkスクリプトになっているので、このスクリプトファイルに実行権をつければ、コマンド名としてこのファイルを、引数としてcsvファイル（？）を指定すればＯＫです。

[DaichiYasuda]

ありがとうございました！
awkはどうやって覚えられました？？

[naomi3]

「sed／awk」という本です。かなり昔になりますが。