オブジェクト指向プログラミングと手続き型プログラミングの違い

Question

オブジェクト指向プログラミングと手続き型プログラミングの違い

オブジェクト指向プログラミングと手続き型プログラミングの違いがよくわかりません。例などを出して分かりやすく教えていただけませんか？

Comments

[iwamoto_takaaki]

判らない理由がわかりません。例などを出して分かりやすく教えてください。

Answer 1

わかりやすい説明はあちこちに溢れています。それを見てなお分からなかったのなら、ここで僅かな説明を見ても同じでしょう。

それよりは自分がどう理解しているかを述べて、その間違った部分を正してもらうのがいいのではないかと思います。

Answer 2

手続き型というのはその定義が少しぶれる場合があります。定義の仕方によっては手続き型とオブジェクト指向は直交した概念になり得ます。そこで、広義の手続き型かそうでないか、オブジェクト指向かそうでないかを見比べます。手続き型は命令型と同義の場合が多いですが、非手続き型にはいくつか種類がありますので関数型を採用します。

【点の移動距離】
二次元平面において、複数の点が与えられる。初期位置を点(0,0)として、最初に与えられた点まで線分を引く。その点からまた与えられた点まで線分を引く。全ての線分の長さの合計を求めよ。
最初行には与えられる点の個数N(0<N<=1000)が与えられる。次の行から、点のX座標とY座標を示す整数値(-1000<=X<=1000)が空白区切りで与えられる。
長さの精度は必要としない。

N
X0 Y0
...
XN YN

上記の問題をとくプログラムをサンプルとして提示します。

言語はCrystalです。Rubyに似てますがRubyではありません。提示するのは全体として構成の考え方です。全てがそうなっているというわけではありません。特に関数型については純粋関数型ではありません(純粋関数型にするにはモナドがないとIO関係を書くことが難しいです)。

命令型非オブジェクト指向

struct Point
  property x, y
  def initialize(@x : Int32, @y : Int32)
  end
end

struct Data
  property point, length
  def initialize(@point = Point.new(0, 0), @length = 0.0)
  end
end

def move(data_pointer : Pointer(Data), next_point : Point) : Nil
  data = data_pointer.value
  length = Math.sqrt((data.point.x - next_point.x)**2 +
      (data.point.y - next_point.y)**2)
  data.point.x = next_point.x
  data.point.y = next_point.y
  data.length += length
  data_pointer.value = data
end

n = gets.to_s.to_i
data = Data.new
n.times do
  x, y = gets.to_s.split.map {|s| s.to_i}
  point = Point.new(x, y)
  move(pointerof(data), point)
end
puts data.length

命令型オブジェクト指向

class Point
  property x, y
  def initialize(@x : Int32, @y : Int32)
  end
end

class Data
  property point, length
  def initialize(@point = Point.new(0, 0), @length = 0.0)
  end
  def move(next_point : Point) : Nil
    length = Math.sqrt((@point.x - next_point.x)**2 +
        (@point.y - next_point.y)**2)
    @point.x = next_point.x
    @point.y = next_point.y
    @length += length
    nil
  end
end

n = gets.to_s.to_i
data = Data.new
n.times do
  x, y = gets.to_s.split.map {|s| s.to_i}
  point = Point.new(x, y)
  data.move(point)
end
puts data.length

関数型非オブジェクト指向

struct Point
  getter x, y
  def initialize(@x : Int32, @y : Int32)
  end
end

struct Data
  getter point, length
  def initialize(@point = Point.new(0, 0), @length = 0.0)
  end
end

def move(data : Data, next_point : Point)
  length = Math.sqrt((data.point.x - next_point.x)**2 +
      (data.point.y - next_point.y)**2)
  Data.new(next_point, data.length + length)
end

n = gets.to_s.to_i
point_list = n.times.map do
  x, y = gets.to_s.split.map {|s| s.to_i}
  Point.new(x, y)
end
data = point_list.reduce(Data.new) do |acc, point|
  move(acc, point)
end
puts data.length

関数型オブジェクト指向

class Point
  getter x, y
  def initialize(@x : Int32, @y : Int32)
  end
end

class Data
  getter point, length
  def initialize(@point = Point.new(0, 0), @length = 0.0)
  end
  def move(next_point : Point)
    length = Math.sqrt((@point.x - next_point.x)**2 +
        (@point.y - next_point.y)**2)
    Data.new(next_point, @length + length)
  end
end

n = gets.to_s.to_i
point_list = n.times.map do
  x, y = gets.to_s.split.map {|s| s.to_i}
  Point.new(x, y)
end
data = point_list.reduce(Data.new) do |acc, point|
  acc.move(point)
end
puts data.length