Linuxのawkコマンドでテキストから数字のみを表示し合計を求めたい

Question

###前提・実現したいこと
awkコマンドの練習をしています。不特定多数のテキストから数字のみを取り出しそれを行毎に表示し最後に合計を出したいと思っています。

###試したこと
awk -F '[^0-9]+' '{print $0}' test.txt

###発生している問題・エラーメッセージ
区切り文字に数字以外の正規表現 [^0-9]+ を使用し、print $1 $2とやっていけば出てくると思ったのですが

先頭に数字がない場合、例えば 「ABC123DEF431」だったとすると
区切り文字が先に来ることになるので$1がブランクになり$2に123が格納されます。

先頭に数字以外の文字がある場合その行は数字が来るまでの文字をどう削除すればいいのか
(例えばBEGINで処理できるのか)
また$0だと行のまま数字以外も含め入力がそのまま出るので$1 $2 $3 ....と書かなくても格納されたその行の数字をすべて表示させるには
どうすればいいのか調べても具体的な例が出てこないため困っております。

小数点や記号も文字として考慮して設計してます。
0も数字扱いです。

合計に関してはENDで処理すればできるだろうと考えています。

ご教示いただけますと幸いです。
よろしくお願いいたします。

Answer 1

訂正：失礼、実行条件間違えてたので直しました。

正確にマッチしているかはわかりませんが、例えば以下のスクリプトを試してみてください。
(自分も久々にawk動かしたので大分忘れてます。man awkしました :-P)

# t.awk
BEGIN { FS="[^0-9]+" }
$1 != "" || $2 != "" {
  s=""
  for (i = 1; i <= NF; i++) {
    if ($i != "") { printf "%s%s", s, $i; total += $i; s = " " }
  }
  print ""
}
END { print total }

$ awk -f t.awk test.txt

筆問者さんへのアドバイスですが・・・
linuxのコマンドの使い方を理解するのにネット上でサンプルを探すことも悪くはないと思いますが、基本はmanを見ましょう。膨大な行数があるように見えるmanですが、不要な情報を適宜読み飛ばしてエッセンスの部分を見つける訓練をしましょう。そういう習慣をつければlinuxのコマンドたちをつかうのも楽になっていきますよ。

Answer 2

awkは初めて使うのでawkっぽいかどうかはわかりませんが、awkは変数、if文、for文、組み込み関数と色々使えます。
https://linuxjm.osdn.jp/html/GNU_gawk/man1/gawk.1.html

小数には対応してません。

#!/bin/bash

awk '
    BEGIN {
        FS = "[^0-9]+";
        sum = 0;
    }
    {
        for (field=1; field<NF; field++) {
            if ($field ~/^[0-9]+$/) {
                printf("%d,", $field);
                sum += $field;
            }
        }
        print "";
    }
    END {
        printf("合計は%d\n", sum);
    }
'

Answer 3

やりたいことがコレで合ってるかわかりませんが…
こういうことですかね

awk -F '[^0-9]+' '{for(i=1;i<=NF;i++){a+=$i;if($i!="")print $i}}END{print "sum:"a}' test3.txt

blacknon@BS-PUB-DEVELOP:~$ cat test3.txt
ABC123DEF431
112rtr333
3435dfs343
23435
blacknon@BS-PUB-DEVELOP:~$ awk -F '[^0-9]+' '{for(i=1;i<=NF;i++){a+=$i;if($i!="")print $i}}END{print "sum:"a}' test3.txt
123
431
112
333
3435
343
23435
sum:28212

Answer 4

awk -F '[^0-9]+' '{for(i=1;i<=NF;i++){sum+=$i};$1=$1;print $0}END{print "SUM="sum}' test.txt 

Comments

[otn]

> また$0だと行のまま数字以外も含め入力がそのまま出るので$1 $2 $3 ....と書かなくても格納されたその行の数字をすべて表示させるには

$1=$1 とすればいいです。

Answer 5

状況にもよると思いますが、例えば、sudo cat /proc/vmallocinfo の ioremapの列の数字を取り出して、それの合計を求めることができます。

sudo cat /proc/vmallocinfo | grep "ioremap" | awk '{print $2}' | paste -s -d "+" | bc

これで、550068224と出てきました。（私の環境です）
これでどうでしょうか？