VimのFiler(netrw?)のキーバインドを変更したい

Question

以下を参考にVimのキーバインドを変更しました。
http://qiita.com/tekkoc/items/98adcadfa4bdc8b5a6ca

s+h,j,k,l

でウィンドウの異動ができるようになりましたが表示中のウィンドウにnetrwが表示されているとnetrwのソート変更のキー(s)と競合しウィンドウの異動ができなくなってしまいます。

netrwのキーマップを変更したいのですが可能でしょうか？

Answer 1

こういう場合は help を参照するのが鉄則です。

有志によって提供されている日本語版 help で :help netrw-usermaps を参照すると、g:Netrw_UserMaps と言う変数を設定すれば良さそうです。

ドキュメントをみた限りだと、以下のようにすれば良さそうです。

function! NetrwMapping_sh(islocal) abort
  return "normal! \<C-w>h"
endfunction
function! NetrwMapping_sj(islocal) abort
  return "normal! \<C-w>j"
endfunction
function! NetrwMapping_sk(islocal) abort
  return "normal! \<C-w>k"
endfunction
function! NetrwMapping_sl(islocal) abort
  return "normal! \<C-w>l"
endfunction

let g:Netrw_UserMaps = [
\   ['sh', 'NetrwMapping_sh'],
\   ['sj', 'NetrwMapping_sj'],
\   ['sk', 'NetrwMapping_sk'],
\   ['sl', 'NetrwMapping_sl'],
\ ]

ちょっと冗長ですね。実際に試してないので、うまく動かなかったらすいません。
netrw は古くからあるプラグインで、カスタマイズ方法も正直イケてない部分が多いです。最悪別の filer 系のプラグインで置き換えることも検討するといいかもしれません。

Comments

[退会済みユーザー]

できました！
ありがとうございますm(__)m