「コピーしてダウンロード」と同じボタンを作りたいです。

Question

###前提・実現したいこと
SharePoint Foundation2010で、WebDAV機能は使えない環境です。
ドキュメントライブラリにはExcelとPDFのファイルがたくさん入っています。
権限はサイト管理者までなのでサーバで何かすることはできません。

最終的にやりたいことは
「ボタン1個押したら当該のドキュメントライブラリをまるごとローカル環境にコピーできる」
なんですが
まず最初に、ファイル1個だけダウンロードできるボタンを作りたいです。
リボンにある「コピーしてダウンロード」のボタンと同じ感じです。

###試したこと

最初はバッチファイルでできるかなーって思ったんですが

Const FromNw = "\SharePointのライブラリのネットワークのパス" '
Const ToLocal = "C:\自分のローカル環境のパス" '

Dim FSO As Object
Dim WSNet As Object
Set FSO = CreateObject("Scripting.FileSystemObject")
Set WSNet = CreateObject("WScript.Network")
If FSO.DriveExists("Z") Then WSNet.RemoveNetworkDrive "Z:"
WSNet.MapNetworkdrive "Z:", FromNW
FSO.CopyFolder "Z:\" , ToLocal
WSNet.RemoveNetworkDrive "Z:"
MsgBox "コピーできた", vbInformation
Set FSO = Nothing
Set WSNet = Nothing

って感じでしょうか…
でもWebDAVがないのでこれは使えなくて

「コピーしてダウンロード」のボタンのところはなんて書いてあるんだろうと思って
見たんですが、init.jsは力不足で読み切れず、RESTでなんかしてる…？くらいしかわかりませんでした。

JavaScriptで書くなら

downloadfile('ファイルURL', 'ローカルのファイル名');

みたいなのでしょうか… でもこれを書いても何も起きません。

何か良い方法があったらご教示ください。
よろしくお願いします。

Answer 1

自分の解決模索スレみたいになってて申し訳ありません…。

この書き方だと
日本語のURLや日本語のファイル名の場合には
objXmlHttp.statusで404エラーが出て取ってこられないことが判明し
そこの部分でも途方に暮れています。

VBSだから読み込むファイルはShift-JISであってると思うのですが
これをどうにかしてないのでURLとしてobjXmlHttpでGETするときに支障があるのかも
というところまでしかわかっていません。

読んだファイルを何かにエンコードしないといけないのでしょうか。何に…？どうやって…？

Comments

[sumire_cl]

「そこにあるものを全部取ってくる」
という考え方が、Webでは「危険」なのだと教えてくださるかたがいらっしゃいました。

そりゃそうですよね…。

でもSharePointで、いわば「外のWeb」とはちょっと違う感じで使うものなので
引き続きなんらかの解決方法を探していきたいです。

Answer 2

情報提供だけですがどうぞ

Download a file from a SharePoint library with VBScript

VBA - Download files from sharepoint

Comments

[sumire_cl]

ありがとうございます。

2個目のはWevDAV前提なので私の環境ではダメで
1個目のはSOAPで持ってくるやつですね。
VBSでSOAPってこう使うのかー。へえー！勉強になりました。
けど、ファイル名を指定して1個ずつ持ってくるのはもうできてしまっているので
あとは「このフォルダにあるファイル全部」みたいな指定ができるかとか
そのフォルダにあるファイル一覧を取れるかとかみたいなところです。
ファイルを持ってくるのはこういう方法もあるんだなあというのが学習できました。ありがとうございます。

Answer 3

ファイルが置いてある場所とファイル名の一覧をテキストファイルから読んでくるようにしました。
テキストファイルの1行目に置き場所のURLを書いて、2行目以降にファイル名を列挙するような感じです。

Set objShell = WScript.CreateObject("WScript.Shell")
Set objXmlHttp = WScript.CreateObject("MSXML2.XmlHttp")
Set objFso = WScript.CreateObject("Scripting.FileSystemObject")

'ファイル一覧が列挙されてるテキストファイルを読み込んで配列に格納(1行目に置いてある場所のURL)
Set objFile = objFso.OpenTextFile("filelist.txt")
Dim aryRet()
Dim gyosu : gyosu = 0
Do Until objFile.AtEndOfStream
  redim Preserve aryRet(gyosu)
  aryRet(gyosu) = objFile.ReadLine
	gyosu = gyosu + 1
Loop
objFile.Close

'置いてある場所のURLが1行目に書いてある
cReqPath = aryRet(0)

'2行目以降のファイル名を読んで順にダウンロード
Dim i
for i = 1 to gyosu-1 step 1
  cFileName = aryRet(i)
  objXmlHttp.Open "GET", cReqPath & cFileName, False
  objXmlHttp.Send
  intStatus = objXmlHttp.status
  If (intStatus <> 200) Then
    WScript.Echo "FAILED" & vbCrLf & vbCrLf & "HTTP status code is " & intStatus & vbCrLf & cFileName
    WScript.Quit
  End If

  Set objStream = WScript.CreateObject("ADODB.Stream")
  objStream.Open
  objStream.Type = 1
  objStream.Write objXmlHttp.responseBody
  objStream.SaveToFile objShell.CurrentDirectory & "\" & cFileName, 2
  objStream.Close
  Set objStream = Nothing
next

WScript.Echo "カレントフォルダ" & vbCrLf & objShell.CurrentDirectory & vbCrLf & "にダウンロードしました。"
Set objXmlHttp = Nothing

WScript.Quit

次はSharePointから、ファイルの置き場所のURLと、置いてあるファイル全部のファイル名一覧をテキストにする何かを作るといいような気がしますが、どうしたらいいのかわかりません…。

Answer 4

決まった場所からファイル名を引数で指定してダウンロードするのは
このページを写しつつ
なんかできたっぽいです。
（ファイルの置き場所は1か所に決まっているのでそのまま書いてます）

Const cReqPath = "http://ファイルが置いてある場所/"
Set objShell = WScript.CreateObject("WScript.Shell")
Set objXmlHttp = WScript.CreateObject("MSXML2.XmlHttp")

Set dFilenm = WScript.Arguments

for i = 0 to dFilenm.Count -1 step 1
  cFileName = dFilenm(i)

  objXmlHttp.Open "GET", cReqPath & cFileName, False
  objXmlHttp.Send
  intStatus = objXmlHttp.status
  If (intStatus <> 200) Then
    WScript.Echo "FAILED" & vbCrLf & vbCrLf & "HTTP status code is " & intStatus
    WScript.Quit
  End If

  Set objStream = WScript.CreateObject("ADODB.Stream")
  objStream.Open
  objStream.Type = 1
  objStream.Write objXmlHttp.responseBody
  objStream.SaveToFile objShell.CurrentDirectory & "\" & cFileName, 2
  objStream.Close
  Set objStream = Nothing
next

Set objXmlHttp = Nothing
WScript.Quit

あとは
「その置き場所にあるファイル全部」
というのをどう書いたらいいのか…。