スレッドを作成したが動かない

Question

ボタンを押すと1秒ごとにテキストボックスに時間を表示する
スレッドを作成したのですが動きません。
「有効ではないスレッド間の操作: コントロールが作成されたスレッド以外のスレッドからコントロール 'TextBox1' がアクセスされました。」
というエラーメッセージが表示されます。

どこが間違っているのでしょうか？
ご教授お願いします。

Public Class Form1
    Private Sub Button1_Click(sender As System.Object, e As System.EventArgs) Handles Button1.Click
        BackgroundWorker1.RunWorkerAsync()
    End Sub

    Private Sub BackgroundWorker1_DoWork(sender As System.Object, e As System.ComponentModel.DoWorkEventArgs) 
Handles BackgroundWorker1.DoWork
        Do
            TextBox1.Text = Now.ToLongTimeString
            Threading.Thread.Sleep(1000)
        Loop
    End Sub
End Class

Answer 1

TextBox などのコントロールはそれを作ったスレッド以外からアクセスできません。

DoWork は別スレッドになりますので、書籍にこの方法が本当に書いてあったのなら、書籍が間違っています。
しかし、もしかしたら RunWorkerCompleted イベントではありませんでしたか？ それならばメインスレッドで実行されるのでコントロールにアクセスできます。

または、Control.Invoke を使ってみてください。これはメインスレッドで実行するもので、DoWork 中でも使えます。

Answer 2

スレッドのバックグラウンド処理内ではコントロールのプロパティを直接いじることは出来ません。
時計表示くらいならTimerコントロールを使ったほうが楽です。
Timerイベント内ならコントロールをのプロパティを直接いじれます。

時計を表示するよ

Comments

[k_mail]

visual Basic 2010 逆引き大全　555の極意
という参考書に書かれているものを書き写したつもりなのですが。。。。
なので、動くとは思うのですね。
どこか書き間違いがあると思われるのです。。。
Timerイベントもチェックしてみます。
ありがとうございます。

[PineMatsu]

ここを参考にしてみてください。同じような質問がありました。
http://dobon.net/vb/bbs/log3-38/23055.html

Answer 3

他の回答およびエラーメッセージにあるように、コントロールは通常、他のスレッドから操作できません。
Invokeメソッドを使うことで回避できます。
以前、下記のサイトを参考にして実装したことがあるので、見てみてください。
http://www.atmarkit.co.jp/ait/articles/0506/17/news111.html

Answer 4

スレッドからコントロールをいじれないという事です。
自分も同じようなところで悩んでおり、勉強がてら、書いてみました。

Imports System.Threading
Public Class Form1

    Private bc As Thread
    Private Delegate Function Dele(ByVal str As String) As Integer

    Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
        bc = New Thread(AddressOf DoBackgroundWorker) With {
            .Name = "MyProcess"
        }
        bc.IsBackground = True
        bc.Start()
    End Sub

    Private Sub DoBackgroundWorker()

　　　　'スレッドの名前を取得
        Dim threadName As String = System.Threading.Thread.CurrentThread.Name
        'WriteTextのDelegateの作成
        Dim dlg As New Dele(AddressOf WriteText)

　　　　'メイン処理
        Do
            Dim count As Integer = CInt(Me.Invoke(dlg, New Object() {threadName}))
            Threading.Thread.Sleep(1000)
        Loop


    End Sub

    Private Function WriteText(ByVal str As String) As Integer
        'メイン処理からここが呼ばれる
        TextBox1.Text = Now.ToLongTimeString
        Return TextBox1.Lines.Length
    End Function

End Class

参考URL：https://codezine.jp/article/detail/139#invoke

Answer 5

WPFであればDispatcherを使えば可能です。

Answer 6

他の方のおっしゃる通り、DoWorkからは、コントロールを直接操作できません。
また、ProgressChanged、RunWorkerCompletedからは、コントロールを直接操作できます。

Invokeの使い方は以下の通りです。

Public Class Form1

    Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
        BackgroundWorker1.RunWorkerAsync()
    End Sub

    Private Sub BackgroundWorker1_DoWork(sender As Object, e As System.ComponentModel.DoWorkEventArgs) Handles BackgroundWorker1.DoWork
        Do
            Dim param As MethodInvoker = AddressOf SetText
            Me.Invoke(param)
            Threading.Thread.Sleep(1000)
        Loop
    End Sub

    Private Sub SetText()
        TextBox1.Text = Now.ToLongTimeString
    End Sub

End Class