.net タブコントロール、タブの色について

Question

###前提・実現したいこと
.netにおいて、指定したタブの色を変えるコードを書きたいと思っていますが、どのように指定すればいいのかが分かりません。
他サイトを参考に、アクティブなタブの色を変えることには成功したのですが、最初から指定したタブの色を変える方法が分かりません。
タブページはNameもTextも１，２，３というタブで構成されています。

###該当のソースコード

Private Sub TabControl1_DrawItem(ByVal sender As Object, ByVal e As DrawItemEventArgs) Handles TabControl1.DrawItem
        '対象のTabControlを取得
        Dim tab As TabControl = CType(sender, TabControl)
        'タブページのテキストを取得
        Dim txt As String = tab.TabPages(e.Index).Text
        'タブのテキストと背景を描画するためのブラシを決定する
        Dim foreBrush, backBrush As Brush

        If (e.State And DrawItemState.Selected) = DrawItemState.Selected Then
            '選択されているタブのテキストを赤、背景を青とする
            foreBrush = Brushes.Black
            backBrush = Brushes.Orange
        Else
            '選択されていないタブのテキストは灰色、背景を白とする
            foreBrush = Brushes.Gray
            backBrush = Brushes.White
        End If

        'StringFormatを作成
        Dim sf As New StringFormat
        '中央に表示する
        sf.Alignment = StringAlignment.Center
        sf.LineAlignment = StringAlignment.Center

        '背景の描画
        e.Graphics.FillRectangle(backBrush, e.Bounds)
        'Textの描画
        e.Graphics.DrawString(txt, e.Font, foreBrush, RectangleF.op_Implicit(e.Bounds), sf)
    End Sub

###試したこと

e.state = 1

の様にすれば指定できるかもと思い試してみましたがだめでした。
ご教授よろしくお願い致します。

Answer 1

実現したい内容が本当に「最初から指定したタブの色を変える」なのであれば、

        Else
            '選択されていないタブのテキストは灰色、背景を白とする
            foreBrush = Brushes.Gray
            backBrush = Brushes.White
        End If

↓

        Else
            If (e.Index = 0) Then
                foreBrush = Brushes.Gray
                backBrush = Brushes.DimGray
            ElseIf (e.Index = 1) Then
                foreBrush = Brushes.Gray
                backBrush = Brushes.Silver
            Else
                foreBrush = Brushes.Gray
                backBrush = Brushes.White
            End If
        End If

このようにして、e.Indexごとに適宜色を変えてあげることはできます。

ですが、本当に実現したいのは
「最初から指定したタブをアクティブにする」
な気がします……。
だとするなら、TabControlのSelectedIndexを適当なタイミングでセットします。

例えば、フォーム表示時にセットするなら

    Private Sub Form1_Shown(sender As Object, e As EventArgs) Handles Me.Shown
        TabControl1.SelectedIndex = 1
    End Sub

このようなコードをForm1クラスに追加します。

Comments

[churi_yuzuki]

回答ありがとうございます。
いえ、実現したいのは、「指定したタブの色を変える」で合ってるので頂いたコードで実現できました。
ありがとうございます！
e.stateと書いていたので誤解を与えてしまっていたら申し訳ありません。