データーチェックロジック

Question

毎度毎度、お世話になっております。

データーのチェックロジックについてご教授下さい。
D列にあるMACアドレスがK列に存在しない場合は、H列にNo_matchと記入するように
データーのチェックを行いたいのですが、

下記コードだと、上手く行きません。。。。
K列内に絶対にあるのに、最初のデーターチェックでNo_matchとなってしまいます。。。
ただ単に、ループで各データーを見るだけじゃダメなんですね。。。
VBAの中で、ワークシート関数を使うとか・・・。。。

'作業前後でMACアドレスの差分チェックを行う。
'作業前のMACアドレス(D列)を元に作業後のMACアドレ(K列)スの比較を行う。
'K列にD列のMACアドレスが無かった場合には、H列にNo_matchと入力する。
    
    i = 3
    Do While Cells(i, "D").Value <> ""
        j = 3
        Do While Cells(j, "K").Value <> ""
            If Cells(i, "D").Value <> Cells(j, "K").Value Then
                Cells(i, "H").Value = "No_match"
            End If
            j = j + 1
        Loop
        i = i + 1
    Loop

どなたかご教授下さい。

Answer 1

問題点の整理

まず提示コードの処理を整理すると、以下のような流れになっています。

①D列取得行を先頭に設定

（D列ループを開始）
 ②K列取得行を先頭に設定
 
 （K列ループ開始）
   ③D列・K列から１セルずつ取り出す
   ④D列から取り出したセルの値とK列から取り出したセルの値を比較
    ⇒一致していれば何もしない
    ⇒不一致なら"No_match"
   ⑤K列取得行カウントアップ
 （K列ループここまで）
 
 ⑥D列取得行カウントアップ
（D列ループここまで）

やりたいことは
「K列に一致するセルを見つけたら空欄、見つからなければ"No_match"を記述する処理」
だと思いますが、提示コードの処理の流れは、
「K列に不一致セルが（１つでも）あれば"No_Match"を記述し、一致するセルがあっても何もしない処理」
となっています。

④でセルの一致判定をしていますが、ループを抜ける処理は特にないためすべての行に対して処理が行われます。

つまり、途中で一致するセルを見つけたとしてもK列の次以降のセルとの比較を続けてしまうため、どこかで不一致セルを見つけた時点で"No_match"を書き込んでしまいます。
ほとんどが不一致のものの中から一致するものの有無を探すわけですから、ほぼ必ず"No-match"となってしまうのではないでしょうか？

修正案①

今のコードをベースに修正するのなら、④の判定部分を
⇒一致していれば空欄にしてExitDo
⇒不一致なら"No_match"を記述
という流れに変更すればいいでしょう。

修正案②

提示コードをベースにせず、私が独自で作成するとしたら、NuuさんのアドバイスにもあるFindを使うと思います。

Sub test()
    Dim rngSrchArea As Range    '検索範囲
    Set rngSrchArea = Range("K:K")
    
    'D列をループ処理
    Dim iRow As Integer
    For iRow = 3 To Cells(Rows.Count, "D").End(xlUp).Row
        'D列の値を検索範囲から検索
        If rngSrchArea.Find(What:=Cells(iRow, "D").Value) Is Nothing Then
            '一致するものがなければH列に"No_match"を記述
            Cells(iRow, "H").Value = "No_match"
        End If
    Next
End Sub

別案（Excel関数）

今回やりたい内容は、VBAを使わずに実現することもできます。
たとえばH3セルに=IF(COUNTIF(K:K,D3)>0,"","No_match")と記述し、この式をH列の対象範囲にコピーすれば、目的の結果が得られると思います。

「セルに式は残したくない、値で入れたい」とか「ほかでもマクロを使っているからこれもマクロの方がラクチン！」というのであれば選択肢には入りませんが、一応別案として紹介しました。

参考になれば幸いです。

Comments

[退会済みユーザー]

アドバイス有難うございます。

Answer 2

Findを使ったコードを書いてみました。動作検証済みです。
参考になりましたら幸いです。

'作業前MACアドレス
D_FirstRow = 3
D_LastRow = Cells(Rows.Count, "D").End(xlUp).Row
Set BeforeWork = Range(Cells(D_FirstRow, "D"), Cells(D_LastRow, "D"))

'作業後MACアドレス
K_FirstRow = 3
K_LastRow = Cells(Rows.Count, "K").End(xlUp).Row
Set AfterWork = Range(Cells(K_FirstRow, "K"), Cells(K_LastRow, "K"))

'データチェック
For Each target In AfterWork
    Set result = BeforeWork.Find(What:=target.Value)
    '作業前MACアドレスと一致しなかった場合
    If result Is Nothing Then
        Cells(target.Row, "H").Value = "No_match"
    '作業前MACアドレスと一致した場合
    Else
        Cells(target.Row, "H").Value = ""
    End If
Next

Comments

[退会済みユーザー]

少しずつ勉強し、今後の参考にさせていただきます。

Answer 3

数式を貼り付けちゃうとか
マクロより数式なら結構わかる人がいるような気がする

**間違い**
Application.ScreenUpdating = False
 For i = 3 To 16
  Cells(i, "H") = "=IF(" & Cells(i, "K").Address & ">0,IF(ISERROR(MATCH(" & Cells(i, "K").Address & ",$D$3:$D$14,0)),""No_match"",IF(MATCH(" & Cells(i, "K").Address & ",$D$3:$D$14,0),"""",""No_match"")),""No_match"")"
 Next i

参照列逆だった

**修正**
Application.ScreenUpdating = False
 For i = 3 To 14
  Cells(i, "H") = "=IF(" & Cells(i, "D").Address & ">0,IF(ISERROR(MATCH(" & Cells(i, "D").Address & ",$k$3:$k$15,0)),""No_match"",IF(MATCH(" & Cells(i, "D").Address & ",$k$3:$k$15,0),"""",""No_match"")),""No_match"")"
 Next i

Answer 4

WorksheetFunctionを使うと遅くなるとか賛否両論あると思いますが、コードをすっきりさせるので以下のようなコードに直してみました。End(xlUp)を使うとセルの終わりのチェックが省けるのとCOUNTIF関数の範囲指定が確定できます。

    MaxRow = Range("K65536").End(xlUp).Row
    For i = 3 To MaxRow
        cnt =  Application.WorksheetFunction.COUNTIF(Range("D3:D" & Trim(str(MaxRow))),Range("K" & Trim(str(i)))  
        If cnt = 0 Then
            Cells(i, "H").Value = "No_match"
        End if
    Next

Answer 5

コードをパッと見ると、ループが必ず最後まで回っているので、K列の一番最後と比べる様になっていますね…
こんな形で如何でしょうか？
この様なループを回さなくてもfindを使ったり、色々な手立てもあると思いますよ。

'作業前後でMACアドレスの差分チェックを行う。
'作業前のMACアドレス(D列)を元に作業後のMACアドレス(K列)の比較を行う。
'K列にD列のMACアドレスが無かった場合には、H列にNo_matchと入力する。

    i = 3
    Do While Cells(i, "D").Value <> ""
        j = 3
        Cells(i, "H").Value = "No_match"
        Do While Cells(j, "K").Value <> ""
            If Cells(i, "D").Value = Cells(j, "K").Value Then
                Cells(i, "H").Value = ""
                exit Do
            End If
            j = j + 1
        Loop
        i = i + 1
    Loop

Comments

[退会済みユーザー]

H列のMACアドレスが、K列で見つかった場合、exit doをするとのことですが、この場合、
if文を抜けて、jが+1カウントアップされるのでしょうか？

iがカウントアップされないといけないような気がしますが・・・・。

[motuo]

見つかった時点でK列のループを抜ける、というつもりで書いてみました。その意味で変数jのカウントアップは不要ですよね？
また、書いたexit doはK列のDo whileに対して有効なのでiはカウントアップされますよ。

[jawa]

横から失礼しますm(__)m

処理をわかりやすくするコツとして、わかりやすい変数名を命名するというものがあります。
iやjという変数名でもプログラムは動いてくれますが、人が見た時に直観的ではないですよね？

今回の場合、たとえばi⇒iRow_D、j⇒iRow_Kのような名前にすると、iRow_KはK列ループを抜けた後D列ループの先頭でリセットされるのでカウントアップは不要ということがわかりやすくなると思いますよ。