セルに値を入れたら隣のセルにボタンを自動生成させる方法

Question

失礼しました。
詳しく用途をご説明します。

B列とC列のセルに何かしらの値をいれると
A列にBC列の値を引数とした関数を呼び出すボタンを生成させます。
また、
BとCどちらかでも欠けていたらボタンは生成しない。
値を消したらボタンも消えるようにしたいです。
生成されたボタンの名前は「ボタン2」のようになりますが、
「login」のように別の文字列に変えたいです。

用途としては、
特定サイトのアカウント情報の管理です。
B列にアカウントID、C列にパスワードを入れてボタンを押すと
IEでログインページに行ってフォームを入力する作業をさせたいと考えています。

↓完成のイメージです↓

------修正前の質問--------
そのボタンを押すと、セルに入れた値を引数として関数を呼び出すようにしたいです。

いろいろ検索してみましたが解決策が見つからなかったのでここで質問させてもらいました。
よろしくお願いします。

Comments

[Mr_Roboto]

関数はボタンを押さなくても適切に入れれば呼び出されると思うのですが、具体的にどうしたいかもう少し詳しく書いて頂けますか？

[Mr_Roboto]

あと、タイトルと質問の内容が違うように思います。

[horik]

失礼しました。詳しい内容を追記しました。

Answer 1

こんな感じでしょうか。

Private Sub Worksheet_Change(ByVal Target As Range)

    With Target
        ' BCセル以外は無視
        If .Column <> 2 And .Column <> 3 Then Exit Sub
        
        ' 一旦削除
        Dim btn As Shape
        For Each btn In ActiveSheet.Shapes
            If btn.Name = "btn" & .Row Then
                btn.Delete
            End If
        Next btn
    
        ' 両方入力されてたら作成
        If Cells(.Row, 2) <> "" And Cells(.Row, 3) <> "" Then
            Buttons.Add(Cells(.Row, 1).Left, Cells(.Row, 1).Top, Cells(.Row, 1).Width, Cells(.Row, 1).Height).Select
            Selection.Name = "btn" & .Row
            Selection.Text = "login"
            Selection.OnAction = "'" & ActiveSheet.Name & ".onButton """ & Cells(.Row, 2) & """,""" & Cells(.Row, 3) & """'"
        End If
        
        .Select
        
    End With
    
End Sub

Sub onButton(b As String, c As String)
    MsgBox b & "," & c
End Sub

Comments

[horik]

ありがとうございます！
期待通りの動きになりました。

Answer 2

質問文の内容に回答するとこんな感じになると思います。

Sub ボタン1_Click()

    'シートからセルの値を取得
    Dim strVal As String
    strVal = ActiveSheet.Cells(1, 1)
    
    '取得した値を元にtest関数を呼び出す
    Call test(strVal)
    
End Sub

Private Sub test(vVal As String)
    '引数の内容をメッセージ表示
    MsgBox vVal
End Sub

質問タイトルの内容とは全く異なりますが・・・。

質問タイトルの内容だとこんな感じでしょうか？（・・・かなりやっつけですが。）

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim nextCell As Range
    
    Set nextCell = Cells(Target.Row, Target.Column + 1)
    
    ActiveSheet.Buttons.Add(nextCell.Left, nextCell.Top, nextCell.Width, nextCell.Height).Select
    Selection.OnAction = "test"
    
End Sub

Comments

[horik]

ありがとうございます。

Microsoft Excel個のオブジェクト→Sheet1(sheet1)に
上のコードを書いたらボタンが生成されるようになりました。

しかしボタンを押すと以下の警告が出てしまします。
マクロ 'ブック1!test' が見つかりません。

[jawa]

エラーが発生しているのは、ボタンを押したときに呼び出すことにしているtest関数が、参照できる範囲に存在していないからです。
サンプルコードでは仮に"test"関数を呼び出すことにしていますが、本来はlogin_click関数のようなものを作成して呼び出すことになると思います。

また、セルの位置にあわせてボタンを生成していますが、ボタン自体は自分がどのセルに張り付いているのかを知りません。
どのボタンを押しても同じ関数を呼び出すのであれば、関数の中でどの行に対応するボタンが押されたのかを判別する必要があります。

例えば、ボタンの名前(表示名ではなくオブジェクト名)を"Button_"+行番号のようにすると判別ができるようになります。

その他、質問本文の変更を受けて実装が必要と思われるものを洗い出してみました。

①B列・C列の変更時のみボタン生成する
　⇒Target.Colmnで判定して対象外なら何もしない

②同じ行にボタンを作成しない
　⇒既に存在するボタン名なら作成しない

③B/C列が未入力ならボタンを消す
　⇒②と同様に、ボタン作成済みかを判断してあればボタンを消す

以上のことを行うために、以下のサイトが参考になると思います。
[Excel-Excel!](http://www.excel-excel.com/tipsctr/vbac_8.html)

がんばってみてください。

[horik]

ありがとうございます。
さらにカスタマイズできそうな感じがしてきました。