VBA を使用してWeb上の画像を貼り付ける方法

Question

【環境】
mac
Excel 2016

Excel上に画像URLが縦に並んでいるとします。（http://〜）
その横にURLにアクセスすると表示される画像を貼り付ける事は可能でしょうか？

ActiveSheet.Pictures.Insert("{画像URL}").Select

を使用してみたのですが、

実行時エラー '1004':
Pictures クラスの Insert プロパティを取得できません。

と表示されました。

現状この方法では貼り付ける事は出来ないのでしょうか？

※追記
以下の方法で画像の貼り付けは出来たのですが、
画像のサイズがセルのサイズとなってしまい、縦横比率がおかしくなってしまいます。
縦横比率を保つようにする事は可能なのでしょうか？

Private Declare Function URLDownloadToFile Lib "urlmon" Alias _
"URLDownloadToFileA" (ByVal pCaller As Long, ByVal szURL As String, ByVal _
szFileName As String, ByVal dwReserved As Long, ByVal lpfnCB As Long) As Long

Sub PicDownLoad()
Dim strFname As String, strUrl As String
Dim retValue As Long, i As Long
Dim endRow As Long
endRow = Cells(Rows.Count, 1).End(xlUp).Row
For i = 1 To endRow
strUrl = Cells(i, 1).Text
If strUrl <> "" Then
strFname = "D:\rinji\" & Mid(strUrl, InStrRev(strUrl, "/") + 1)
retValue = URLDownloadToFile(0, strUrl, strFname, 0, 0)
If retValu = 0 Then
With Cells(i, 2)
Set objShape = ActiveSheet.Shapes.AddPicture( _
Filename:=strFname, LinkToFile:=False, _
SaveWithDocument:=True, Left:=.Left, _
Top:=.Top, Width:=.Width, Height:=.Height)
End With
Else
MsgBox "DownLoad Fail " & Chr(10) & strUrl
End If
End If
Next i
End Sub

Answer 1

縦横比を保ち、余白（yohaku)をとって、中央に配置する。

With Cells(i, 2)
    Set objShape = ActiveSheet.Shapes.AddPicture( _
    Filename:=strFname, LinkToFile:=False, _
    SaveWithDocument:=True, Left:=.Left, _
    Top:=.Top, Width:=1, Height:=1) 'サイズ１で貼り付け
    
    Cel_Top = .Top
    Cel_Left = .Left
    Cel_Width = .Width
    Cel_Height = .Height
    yohaku = 10

    With objShape
        .LockAspectRatio = msoTrue
        .ScaleHeight 1, msoTrue
        .ScaleWidth 1, msoTrue
 
        '画像サイズをセルの幅、高さに合わせる
        rx = Cel_Width / .Width
        ry = Cel_Height / .Height
 
        If rx > ry Then
            .Height = .Height * ry - yohaku
            .Width = .Width - yohaku
        Else
            .Height = .Height - yohaku
            .Width = .Width * rx - yohaku
        End If
        'セルの芯に
        .Left = Cel_Left + (Cel_Width - .Width) / 2
        .Top = Cel_Top + (Cel_Height - .Height) / 2
        
     End With
    
End With

Answer 2

別の方法ですが、これはいかがでしょうか。
検証環境：Windows7,Excel2010

Dim r As Long
For r = 1 To 2
    Set Picture = ActiveSheet.Shapes.AddPicture( _
        Filename:=Cells(r, 1), _
        LinkToFile:=False, SaveWithDocument:=True, _
        Left:=Cells(r, 2).Left, Top:=Cells(r, 2).Top, _
        Width:=-1, Height:=-1)
Next

Answer 3

こちらの環境は
Windows7
Excel2010
ですが、以下のようなコードで取得できています。

Sub test()
    'セルからURLを取得する
    Dim strURL As String
    strURL = ActiveSheet.Cells(1, 1)
    'URLからイメージを作成する
    ActiveSheet.Pictures.Insert strURL
End Sub

mac/excel2016とは環境が違うので何とも言えませんが、お試しください。

追記

追記の内容で、画像サイズがセルの大きさになってしまうのは、貼り付ける際に

With Cells(i, 2)
    '（中略）
    Width:=.Width, Height:=.Height)
End With

としているからだと思います。

以下のように幅・高さを指定しないで貼り付けるとオリジナルサイズで貼り付くと思います。

Sub test2()
    'セルからURLを取得する
    Dim strURL As String
    strURL = ActiveSheet.Cells(i, 1)
    'URLからイメージを作成する
    With Cells(i, 2)
        Set objShape = ActiveSheet.Shapes.AddPicture( _
                            Filename:=strURL, LinkToFile:=False, _
                            SaveWithDocument:=True, Left:=.Left, _
                            Top:=.Top, Width:=0, Height:=0)
        objShape.ScaleHeight 1, msoTrue
        objShape.ScaleWidth 1, msoTrue
    End With
End Sub