Unity URP Fogの影響を受けないアルファ付きシェーダー(Particle用)

Unity URPでFogの影響を受けないアルファ付きシェーダー(Particle用)

当方CGデザイナーでシェーダーやプログラミングについては詳しくなく、
かなり当てずっぽうで進めてみたのですが行き詰ってしまったため質問させていただきます。

AR(MagicLeap)で出現を誤魔化すため黒フォグを使っているのですが、
遠景のエフェクトなどは表示させたいです。

fogの影響を受けない設定の記述は見つかったのですが、
テクスチャとカラーのアルファを適用するために
どのような記述をしたら良いのかがわかりません。

Surface ShaderはURPで使えないので、そのあたりも検索の際に混乱してしまっています。
稚拙な質問で恐縮ですが、よろしくお願い致します。

該当のソースコード

Shader "Custom/FogOffEffect"
{
    Properties
    {
	_Color ("Color", Color) = (1,1,1,1)　//追加した記述
        _MainTex ("Texture", 2D) = "white" {}
    }
    SubShader
    {
        Tags { 
		
		"Queue" = "Transparent"　//変更した記述
		"RenderType"="Transparent" 　//変更した記述
	
		}
        LOD 100

        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #pragma nofog　//追加した記述

            #include "UnityCG.cginc"

            struct appdata
            {
                float4 vertex : POSITION;
                float2 uv : TEXCOORD0;
            };

            struct v2f
            {
                float2 uv : TEXCOORD0;
                UNITY_FOG_COORDS(1)
                float4 vertex : SV_POSITION;
            };

            sampler2D _MainTex;
            float4 _MainTex_ST;

            v2f vert (appdata v)
            {
                v2f o;

                o.vertex = UnityObjectToClipPos(v.vertex);
                o.uv = TRANSFORM_TEX(v.uv, _MainTex);
                
				return o;
            }

            fixed4 frag (v2f i) : SV_Target
            {
                // sample the texture
                fixed4 col = tex2D(_MainTex, i.uv);

                return col;
            }
            ENDCG
        }
    }
}

補足情報

Unity 2020.1.17f1

行動規範の内容に同意します

回答1件

nofogはサーフェスシェーダー用のオプションですので、#pragma nofogといった使い方をするわけにはいかないかと思います。あの行は削除してしまっていいでしょうね。

ご提示いただいたコードを下記のように改変してみましたが、いかがでしょうか?

ShaderLab
1Shader "Custom/FogOffEffect"
2{
3    Properties
4    {
5        _Color ("Color", Color) = (1,1,1,1)
6        _MainTex ("Texture", 2D) = "white" {}
7    }
8    SubShader
9    {
10        Tags { 
11
12        "Queue" = "Transparent"
13        "RenderType" = "Transparent"
14
15        }
16        LOD 100
17
18        Pass
19        {
20            // Blend設定を追加
21            Blend SrcAlpha OneMinusSrcAlpha
22
23            // 半透明パーティクルなら、一般的にはデプスを書き込まない方がいいだろうと思い
24            // ZWriteもオフにしました
25            ZWrite Off
26
27            CGPROGRAM
28            #pragma vertex vert
29            #pragma fragment frag
30
31            #include "UnityCG.cginc"
32
33            struct appdata
34            {
35                float4 vertex : POSITION;
36                float2 uv : TEXCOORD0;
37
38                // 個々のパーティクルの色は頂点カラーとして表現されているので、
39                // 入力データとして頂点カラーを追加しました
40                fixed4 color : COLOR;
41            };
42
43            struct v2f
44            {
45                float2 uv : TEXCOORD0;
46
47                // フォグは不要とのことなので、UNITY_FOG_COORDSも必要ないため削除し...
48                //UNITY_FOG_COORDS(1)
49
50                // 代わりに頂点カラー伝達用の変数を追加しました
51                fixed4 color : TEXCOORD1;
52
53                float4 vertex : SV_POSITION;
54            };
55
56            sampler2D _MainTex;
57            float4 _MainTex_ST;
58
59            v2f vert (appdata v)
60            {
61                v2f o;
62
63                o.vertex = UnityObjectToClipPos(v.vertex);
64                o.uv = TRANSFORM_TEX(v.uv, _MainTex);
65
66                // vert内では入力された頂点カラーをそのまま伝達し...
67                o.color = v.color;
68
69                return o;
70            }
71
72            fixed4 frag (v2f i) : SV_Target
73            {
74                fixed4 col = tex2D(_MainTex, i.uv);
75
76                // frag内ではcolに頂点カラーを掛け合わせることで着色しました
77                col *= i.color;
78
79                // ここまでの過程で、colに対してフォグ色を上乗せするような処理は行っていませんので
80                // あとは単にcolを出力してやればフォグなしの外観になるかと思います
81                return col;
82            }
83            ENDCG
84        }
85    }
86}