excelで3行目が空白だったらその列を削除と実装したが複数空白行がある場合にうまく行かない

Question

お世話になっております。

　A　　　　　B　　　C　　E　　F　G
1　タイトル　ほげ　
2　項目　　　広島　大津　　　　　北海道
3　要素　　　○　　　△　　　　　　□

のような図があり
件名の通り　3行目の項目が空白だったらその列を削除したく

Sub delCol3gyoumeNai()
    Dim i
    Dim MaxCol As Long
    MaxCol = Cells(3, Columns.Count).End(xlToLeft).Column
    For i = 2 To MaxCol
        If Cells(3, i).Value = "" Then
            Columns(i).Delete
        End If
    Next
    
End Sub

のようなプログラムを走らせてE、F列を削除させようとしました。

ですが一回上記のプログラムを動かしただけでは一行しか削除されず
E,F行を削除するには2回動作させなければいけなくなってしまいました。

デバッガで追ってみるとそりゃそうだよね……という動作をしていました……
（削除する→次の行へ　となったら連続した場合は上手く行かない）

一旦全部確認して削除フラグを行ごとに立ててやるのかな？と思いましたが
VBAは不慣れなためもしかしてそれっぽい命令があるのかと思い質問失礼いたします。

上記　列を削除するVBAで連続して削除したい列がある場合はどのような実装方法があるか伺ってよろしいでしょうか？

なんという語句でググるのか不明だったのです……
やっぱり配列用意してフラグしか無いのでしょうか？

上記何か情報をお持ちになっていらっしゃる方はコメント頂けますと嬉しく思います。

Answer 1

列削除すると、右側の列は移動しますので、左側から削除していくとうまく行かないですね。

そういう場合は、右側から削除していくといいでしょう。

Sub delCol3gyoumeNai()
    Dim i As Long
    Dim MaxCol As Long
    MaxCol = Cells(3, Columns.Count).End(xlToLeft).Column
    For i = MaxCol To 2 Step -1
        If Cells(3, i).Value = "" Then
            Columns(i).Delete
        End If
    Next
End Sub

別案

Unionで複数列を纏めて、一気に削除する。

Sub delCol3gyoumeNai1()
    Dim i As Long
    Dim MaxCol As Long
    Dim r As Range
    
    MaxCol = Cells(3, Columns.Count).End(xlToLeft).Column
    For i = 1 To MaxCol
        If Cells(3, i).Value = "" Then
            If r Is Nothing Then
                Set r = Columns(i)
            Else
                Set r = Union(r, Columns(i))
            End If
        End If
    Next

    r.Delete
End Sub

Comments

[ma2hiro]

hatena19さん
ありがとうございますっ
なんかフラグ立ててやるのは面倒かと思っていたのですが
```
For i = MaxCol To 2 Step -1
```
と最大値からやる方法でしたら一回で出来ますねっ
ありがとうございます。
解決しました。