引数付きプロシージャの実行

Question

Sub CSV出力(ByVal sht As Worksheet, Optional ByVal rngStart As Range = Nothing)
　　Dim varFile As Variant
　　Dim FSO As New FileSystemObject
　　Dim TS As TextStream
　　Dim lngRowMin As Long, lngRowMax As Long
　　Dim lngColMin As Long, lngColMax As Long
　　Dim i As Long

　　
　　varFile = Application.GetSaveAsFilename(InitialFileName:=sht.Name & ".csv", _
　　　　　　　　　　　　　　　　　　　　　　FileFilter:="CSVファイル(*.csv),*.csv", _
　　　　　　　　　　　　　　　　　　　　　　FilterIndex:=1, _
　　　　　　　　　　　　　　　　　　　　　　Title:="保存ファイルの指定")
　　If varFile = False Then
　　　　Exit Sub
　　End If
　　　　
　　'開始行列、終了行列を取得
　　If rngStart Is Nothing Then
　　　　lngRowMin = 1
　　　　lngColMin = 1
　　Else
　　　　lngRowMin = rngStart.Row
　　　　lngColMin = rngStart.Column
　　End If
　　With rngStart.CurrentRegion
　　　　lngRowMax = .Item(.Count).Row
　　　　lngColMax = .Item(.Count).Column
　　End With
　　
　　Set TS = FSO.CreateTextFile(Filename:=varFile, Overwrite:=True)
　　
　　For i = lngRowMin To lngRowMax
　　　　TS.WriteLine CSV_EditRec(sht, i, lngColMin, lngColMax)
　　Next
　　
　　TS.Close
　　Set TS = Nothing
　　Set FSO = Nothing

　　MsgBox ("CSV出力しました。" & vbLf & vbLf & varFile)
End Sub

Private Function CSV_EditRec(ByVal sht As Worksheet, _
　　　　　　　　　　　　　　　　i As Long, _
　　　　　　　　　　　　　　　　lngColMin As Long, _
　　　　　　　　　　　　　　　　lngColMax As Long) As String
　　Dim strRec As String
　　Dim strCol As String
　　Dim j As Long

　　strRec = ""
　　For j = lngColMin To lngColMax
　　　　Select Case True
　　　　　　Case IsNumeric(sht.Cells(i, j))
　　　　　　　　strCol = CStr(CDbl(sht.Cells(i, j)))
　　　　　　Case IsDate(sht.Cells(i, j))
　　　　　　　　If InStr(sht.Cells(i, j), "-") Then
　　　　　　　　　　strCol = sht.Cells(i, j)
　　　　　　　　Else
　　　　　　　　　　strCol = Format(sht.Cells(i, j), "yyyy/mm/dd")
　　　　　　　　End If
　　　　　　Case InStr(sht.Cells(i, j), ","), InStr(sht.Cells(i, j), """")
　　　　　　　　strCol = """" & sht.Cells(i, j) & """"
　　　　　　Case Else
　　　　　　　　strCol = sht.Cells(i, j)
　　　　End Select
　　　　If strRec = "" Then
　　　　　　strRec = strCol
　　　　Else
　　　　　　strRec = strRec & "," & strCol
　　　　End If
　　Next
　　CSV_EditRec = strRec
End Function

上記はエクセルの真髄様より抜粋させていただいております。
大変、初歩的な質問なのですが、引数付きのプロシージャの実行の仕方がわかりません。
この場合はコールステートメント等で実行するのでしょうか？
また、その場合はどのようなカードを書くのでしょうか？

Comments

[sazi]

> 引数付きのプロシージャの実行の仕方がわかりません。
質問のコードでは、CSV_EditRec()はCSV出力()で使用するコードになっていますが、何が分からないのでしょうか？

[Dis]

申し訳ありません。本当にわかりません。
Subプロシージャのcsv出力を実行できない理由がわかりません。
Functionが実行できない理由はわかるのですが…

仮に、このコードでは、実行できないのが正しいとして、なぜそのような迂遠な方法を取るのかがわかりません。
Subプロシージャで書かれたものを他のSubプロシージャから呼び出して使うことに何の意味があるのでしょうか？

[sazi]

CSV出力()の実行方法が分からないという事ですか？
ユーザーの操作によるものなら、「CSV出力」などのボタンを設けて、そのボタンのクリックイベントで、
call CSV出力()
などとしますが、質問はそういう事ですか？

[Dis]

非常にわかりにくくて申し訳ありません。
私ならCSV出力プロシージャから直接実行できるコードを書くのかなと考えていたので、なぜCSV出力プロシージャを別のプロシージャ（callステートメントを記載したプロシージャ）から実行しなければいけないのかが、わかりません。
これは作り手の癖なのか、このコードを書くにあたっては、必ずcallステートメントを記載したプロシージャを用意しなければいけないのか…
そこらへんがわかりませんでした。

Answer 1

Sub CSV出力()
 Dim sht As Worksheet, rngStart As Range
 Set sht = ActiveSheet
'以下略

としたらどうでしょう。

Comments

[Dis]

大変わかりやすかったです。初歩的な質問にお答えいただきありがとうございました。

Answer 2

Subプロシージャなら、下記のようなフォーマットで

    Call プロシージャ名(引数1, 引数2) 

Callは省略できます。

   プロシージャ名 引数1, 引数2 

Functionプロシージャなら、Callは使いません。
返り値をどのように使うか次第です。
例えば、返り値を変数に代入するなら、下記のような感じです。

    Dim 変数

    変数 = プロシージャ名(引数1, 引数2) 

Comments

[Dis]

丁寧なご回答ありがとうございます。
上記にも書きましたが、なぜこのSubプロシージャは実行できないのかがわかりません。
また実行できないとして、他のプロシージャから実行する理由もわかりません…
(Callステートメントから呼び出すコードは非常にわかりました。ありがとうございます。)

大変申し訳ありませんが、ご教示いただけたらと思います。

[hatena19]

どのシートを出力したいのか明示されていないですが、
アクティブなシートを出力するなら下記のようなコードでどうでしょうか。

Call CSV出力(ActiveSheet)

[Dis]

起動できました。ありがとうございます。
ベストアンサーにさせていただきます。

人様のをコードを借りておきながら、申し訳ないのですが、なぜわざわざcallステートメントを記載したプロシージャとcsv出力プロシージャを分けるかがわかりません。
これは作り手の癖ととらえてよろしいのでしょうか？
（私が書いていないので、なんとも言えませんが、私ならCSV出力プロシージャからそのまま実行できるコードを書くと思ったので）

[hatena19]

Call CSV出力(ActiveSheet)
とすれば、後からこの1行を見たとき、ActiveSheet をCSV出力するとすぐに分かります。
また、ActiveSheetではなく、例えば Sheet1 をCSV出力したい場合は、
Call CSV出力(WorkSheets("Shhet1"))
とできます。
つまり使い勝手が格段に向上します。