VBAでエクセルにデータ型を指定してCSVをインポートする際に項目行もインポートしたい

Question

やりたいこと

エクセル（2019）にCSVファイルをVBAで項目のデータ型を指定してインポートしたい。
CSVファイルは1行目に各項目があり、2行目以降がデータ行となっている。
2行目以降をインポートするということはできた。
1行目からインポートしたいが、インポートしようとするとエラーとなってしまう。

現状のコード

Sub Import()
    Dim buf As String, tmp As Variant, n As Long
    Close #1
    Open "C:\vba\sample.csv" For Input As #1
        Do Until EOF(1)
            Line Input #1, buf
            tmp = Split(buf, ",")
            n = n + 1
            '応募日時
            Cells(n, 1).Value = DateValue(tmp(0))
            '年齢
            With Cells(n, 2)
                .NumberFormat = "@"
                .Value = tmp(1)
            End With
            '生年
            With Cells(n, 3)
                .NumberFormat = "@"
                .Value = tmp(2)
            End With
            '姓
            Cells(n, 4).Value = tmp(3)
            '名
            Cells(n, 5).Value = tmp(4)
        Loop
    Close #1
End Sub

表示されるエラー

実行時エラー'13':
型が一致しません

おそらく、2行目以降のデータのデータ型を指定してしまっているため、文字型である1行目の項目名がデータ型が一致せず読み込めないのかと思われます。

CSVファイルの1行目から読み込める方法を教えていただけますでしょうか。

Answer 1

いろいろ方法はあります。

1行目は書式設定しないようにするとか。nで行数を判定できます。

        Do Until EOF(1)
            Line Input #1, buf
            tmp = Split(buf, ",")
            n = n + 1
            '応募日時
             Cells(n, 1).Value = DateValue(tmp(0))
            '年齢
            With Cells(n, 2)
                If n > 1 Then .NumberFormat = "@"
                .Value = tmp(1)
            End With
            '生年
            With Cells(n, 3)
                If n > 1 Then .NumberFormat = "@"
                .Value = tmp(2)
            End With
            '姓
            Cells(n, 4).Value = tmp(3)
            '名
            Cells(n, 5).Value = tmp(4)
        Loop

あるいは、書式指定せずにすべて読み込んでから、2列目、3列目の2行目以降はまとめて書式設定するとか。
こちらの方が1セルずつ書式設定するより高速です。

Do Until EOF(1)

’ 略

Loop

Dim rng As range
Set rng = Cells(1,1).CurrentRegion
Set rng = rng.Offset(1, 1).Resize(rng.Rows.Count - 1, 2)
rng.NumberFormat = "@"

追記

コメントで指摘がありましたが、
Cells(n, 1).Value = DateValue(tmp(0))
でDateValueがエラーの原因ですね。
日付にならない文字列だとエラーになります。
そもそも DateValue は必要ないです。
日付と判断できる文字列ならExcelが自動で日付にしてくれますので。

必用なら上記の後の方法であとから書式設定すればいいでしょう。

Comments

[xail2222]

書式設定でエラーはでなかったはず。DateValueでエラーが出てるのでは？

[hatena19]

なるほど、そのようですね。そこを見落としてました。
そもそも DateValue は必要ないですよね。Excel君がよしなにしてくれますので。
回答に追記しておきました。

Answer 2

n = n + 1
の行の後で、
①n=1のケースと
②それ以外のケースに分けて処理する。

①では、項目行の処理なので、それを記述する。
②は、従来の記述の部分を使用する。

このようにすれば、良いと思いますが、いかがでしょうか。