エクセルからメール送信の件 VBA

Question

エクセルからメール送信です
自分のパソコンからは
送れるのですが
USBにコピーして
ちがうパソコンだと

Dim objOutlook As Outlook.Application

ここが
ユーザー定義型は定義されていません
って表示でできません

理由もわかりません

助けてください

Option Explicit

'設定シート情報
Private Const SETTING_SHEET_NAME As String = "設定シート"
Private Const RANGE_TO As String = "B3"
Private Const RANGE_CC As String = "B4"
Private Const RANGE_BCC As String = "B5"
Private Const RANGE_SUBJECT As String = "B6"
Private Const RANGE_BODY As String = "A8:B37"

'送信ボタン押下時の処理
Public Sub SendBtnClicck()
Dim wsSetting As Worksheet
Set wsSetting = ThisWorkbook.Sheets(SETTING_SHEET_NAME)

If wsSetting.OLEObjects("OptBtnSend").Object.Value Then
    Call SendEmail
End If

End Sub

'ファイル保存時の処理
Private Sub Workbook_AfterSave(ByVal Success As Boolean)
Dim wsSetting As Worksheet
Set wsSetting = ThisWorkbook.Sheets(SETTING_SHEET_NAME)

If wsSetting.OLEObjects("OptBtnSave").Object.Value Then
    Call SendEmail
End If

End Sub

'メール送信の処理
Private Sub SendEmail()
On Error GoTo ErrorHandler

Dim objOutlook As Outlook.Application
Dim objMail As Outlook.MailItem
Dim wsSetting As Worksheet

Set objOutlook = New Outlook.Application
Set objMail = objOutlook.CreateItem(olMailItem)
Set wsSetting = ThisWorkbook.Sheets(SETTING_SHEET_NAME)

'設定シートの値を設定する
With wsSetting
    objMail.TO = .Range(RANGE_TO).Value             'TO
    objMail.CC = .Range(RANGE_CC).Value             'CC
    objMail.BCC = .Range(RANGE_BCC).Value           'BCC
    objMail.Subject = .Range(RANGE_SUBJECT).Value   '件名
   objMail.Body = WorksheetFunction.TextJoin(vbLf, False, .Range(RANGE_BODY).Value)         '本文
    'メールの形式
    If wsSetting.OLEObjects("OptBtnHTML").Object.Value Then
        objMail.BodyFormat = olFormatHTML
    End If
    If wsSetting.OLEObjects("OptBtnPlain").Object.Value Then
        objMail.BodyFormat = olFormatPlain
    End If
End With

'メール送信
objMail.Send

GoTo Finally

ErrorHandler:
MsgBox "メールの送信に失敗しました", vbOKOnly + vbCritical

Finally:
Set objOutlook = Nothing

End Sub

Comments

[fumu7]

「ちがうパソコン」には、Outlookがインストールされていますか？

[Kasai5363]

はい、されています。

[fumu7]

https://tonari-it.com/vba-outlook-object/　の記事で説明されているライブラリの参照設定はされていますか？

Answer 1

参照設定なしで下記コードだとどうですか？

Private Sub SendEmail()
On Error GoTo ErrorHandler

'Dim objOutlook As Outlook.Application
Dim objOutlook As Object
'Dim objMail As Outlook.MailItem
Dim objMail As Object
Dim wsSetting As Worksheet

'Set objOutlook = New Outlook.Application
Set objOutlook = CreateObject("Outlook.Application")
Const olMailItem　= 0
Set objMail = objOutlook.CreateItem(olMailItem)
Set wsSetting = ThisWorkbook.Sheets(SETTING_SHEET_NAME) 

'　以下略

Comments

[Kasai5363]

みなさん　ありがとうございました。
理由わかりませんが　コピペ　コピペの繰り返しで
なぜか送れるようになりました
心から感謝します。

Answer 2

OutLookのバージョンが違っていて、参照設定が無効になっている可能性が高いかな。
VBEの画面で、ツール→参照設定 と辿って確かめてみてはどうでしょうか。

Comments

[Kasai5363]

参照不可になっていて、そこは
マクロセキュリティオフで直ったのですが
送れませんでした。Outlookのバージョンは
新しくて大丈夫ですよね？

[jinoji]

バージョン違いで別のOutLookの選択肢がありませんか？

[jinoji]

参照不可になっているのを外して、
そのパソコンに入っているOutLookのバージョンのMicrosoft OutLook xx object library を選び直したら動くのではないかと思います。