IF Like "NNN*"で正しく判定されない

Question

下記の、Debug.Print (checkws.Name) 'ここで正しく"2340_XXX勘定"が出力されるのですが、For Eachを回す過程でELSEのMsgBox "2340*からはじまるシート名が見つからないよ" & vbCrLf & "「処理を終了します」"が実行されてしまいます。Likeの使いかたや、型に問題があるのでしょうか。アドバイスを頂けると幸いです。

Sub getData()
 Dim currentPath As String
 Dim getFilePath As String
 Dim opendAready As Workbook
 Dim hanteiwb As Workbook
 Dim hanteiws As Worksheet
 Dim checkws As Worksheet
 
 
 currentPath = ThisWorkbook.Path()
 getFilePath = Dir(currentPath & "*判定*")
 
 
 If getFilePath = "" Then
   MsgBox "*判定*の名称を持つファイル名がないです"
 Else
      For Each openAready In Workbooks
         If openAready.Name = getFilePath Then
          MsgBox "既に*判定ファイルを開いてしまっています。一旦閉じて作業してね" & vbCrLf & "「処理を終了します」"
          Exit Sub
         End If
      Next openAready
      
      Workbooks.Open Filename:=currentPath & "\" & getFilePath, UpdateLinks:=False
      Set hanteiwb = ActiveWorkbook
       For Each checkws In hanteiwb.Worksheets
         Debug.Print (checkws.Name) 'ここ
         If checkws.Name Like "2340*" Then
          Set hanteiws = checkws
         Else
          MsgBox "2340*からはじまるシート名が見つからないよ" & vbCrLf & "「処理を終了します」"
          Exit Sub
         End If
       Next checkws
    'Debug.Print (hanteiws.Name)

      
End If
 
 
End Sub

Comments

[退会済みユーザー]

シート名は
2340_XXX勘定
"2340_XXX勘定"
どちらですか？
下の場合は"が先頭に入ってるので"*2340*"でないとひっかからないと思います。

[radames1000]

開いたファイルのシートはすべて2340からはじまるものですか？

[pegy]

コメント有難うございます。
シート名は2340_XXX勘定です。
また、今試しているシートは2340からはじまるものと2021から始まるものの2種類です。
宜しくお願い申し上げます

Answer 1

Likeの使い方に問題はないように思えます。
開いたファイルに一つでも2340からはじまらないシートがあればElseに流れます。
こんな判定方法はいかがでしょうか。

Dim flag As Boolean

For Each checkws In hanteiwb.Worksheets
    Debug.Print (checkws.Name) 'ここ
    If checkws.Name Like "2340*" Then
        Set hanteiws = checkws
　　　　'処理
        flag = True
    End If
Next checkws

If flag = False Then
    MsgBox "2340*からはじまるシート名が見つからないよ" & vbCrLf & "「処理を終了します」"
    Exit Sub
End If

Comments

[pegy]

コメントを頂きありがとうございます。
あ、申し訳ございません。なんとなく理解することができました。もともとのループの中でIFさせるやり方で行くと、最初にELSEで流れてEnd Subしてしまった場合にはTRUEの場合の処理がされずに処理が終了してしまう可能性があるということですね。
大変失礼いたしました。

[pegy]

拝見したコードではdefaultでflag = false
を格納しておく必要があるのではないでしょうか？

[radames1000]

Booleanの初期値はfalseなので不要ですが、
記載しても問題はありません。

[pegy]

それは存じ上げませんでした。大変勉強になりました。
ありがとうございます