シェーダ（マンデルブロ集合）について

Question

以下GLSLスクリプトはhttps://wgld.org/d/glsl/g005.htmlから引用させていただきました。
ちなみに、マンデルブロ集合の式は

Zn+1＝Zn^2+C
Z0=0

そこで、以下のスクリプト内で、 (★部分)z = vec2(z.x * z.x - z.y * z.y, 2.0 * z.x * z.y) + x + y
とゆう式がありますが、この式があまり理解できません。。
なんとなく、Znの二乗をしてるのかな？とゆう解釈です

Znの二乗をするのであれば、
Zn^2=z.x^2+(2z.xz.y)+z.y^2
となるはずです。
vec2のy値部分 2.0 * z.x * z.yは、**(2z.xz.y)だろうなあと、理解できるのですが
vec2のx値、z.x * z.x - z.y * z.y**は何故マイナスなのでしょうか、、、？

precision mediump float;
uniform float time;
uniform vec2  mouse;
uniform vec2  resolution;

vec3 hsv(float h, float s, float v){
    vec4 t = vec4(1.0, 2.0 / 3.0, 1.0 / 3.0, 3.0);
    vec3 p = abs(fract(vec3(h) + t.xyz) * 6.0 - vec3(t.w));
    return v * mix(vec3(t.x), clamp(p - vec3(t.x), 0.0, 1.0), s);
}

void main(void){
    vec2 m = vec2(mouse.x * 2.0 - 1.0, -mouse.y * 2.0 + 1.0);
    vec2 p = (gl_FragCoord.xy * 2.0 - resolution) / min(resolution.x, resolution.y);
    
    int j = 0;
    vec2 x = vec2(-0.345, 0.654);
    vec2 y = vec2(time * 0.005, 0.0);
    vec2 z = p;
    for(int i = 0; i < 360; i++){
        j++;
        if(length(z) > 2.0){break;}
//★★★★★★★★
        z = vec2(z.x * z.x - z.y * z.y, 2.0 * z.x * z.y) + x + y;
//★★★★★★★★
    }
    
    float h = abs(mod(time * 15.0 - float(j), 360.0) / 360.0);;
    vec3 rgb = hsv(h, 1.0, 1.0);
    gl_FragColor = vec4(rgb, 1.0);
    
}

Answer 1

シェーダはよくわからないのですが、
マンデルブロ集合は複素平面での集合であったと記憶にあります。

なので、単に複素平面でのy座標(i)を2乗したら負になるというだけかと。

Zn^2=z.x^2+(2z.xz.y)+z.y^2

ではなく

Zn^2=(z.x + z.y**i)^2 = z.x^2 + (2z.xz.y)i** - z.y^2

と解釈できるのではと思います。