コンボボックスに表示されるアイテムについて

あるフォームに有るコマンドボタン（Addbtn）を押すと表示されるコンボボックスに、アイテムを登録したく以下のコードを作成しました。
（題名に「アイテム」と書きましたが、ドロップダウンリストで言う選択できる項目（文字列）のことです。名前が分からず「アイテム」と書かせていただきました。）

前回、表内のデータの情報を抜き出して重複データを削除し、「カンマ区切りの文字列」（strData）に変換してドロップダウンリストに登録する方法を当サイトでご教授いただきましたので、それを参考にしています。

改善したいこと：
「.AddItem strData」で登録すると「カンマ入りの文字列」が1つだけ登録されます。
この「アイテム」の個数はデータの種類の数によって変動するので、変数分登録したいのですが、この場合（複数の場合）はどの様に登録すればよいでしょうか。
他の記載方法（指定方法）効率的な方法などご教授いただければ幸いです。

Public Sub Addbtn_Click()
     Dim Data As New Collection
     Dim intD As Long
     Dim i As Long
     Dim strData As String, ii
     Dim cmbAdd_1 As MSForms.ComboBox

     intD = Cells(3, 2).End(xlDown).Row '最終行
     
     On Error Resume Next 'ｼﾞｬﾝﾙの列を3行目から最下層まで巡視
       For i = 3 To intD
        Data.Add Cells(i, 2).Value, Cells(i, 2).Value
       Next i
     On Error GoTo 0 'エラーの場合は通過してここから
        
      For Each ii In Data
       strData = strData & "," & ii
      Next
      strData = Mid(strData, 2)’文字列化
    
     Set cmdAdd_1 = .Controls.Add("Forms.ComboBox.1", "Tzya", True)
 With NForm
      With cmdAdd_1
        .AddItem strData'ここです！！！！！！！
        .Top = 58
        .Left = 70
        .Height = 20
        .Width = 250
        .BorderStyle = fmBorderStyleSingle
        .BackColor = RGB(255, 255, 255)
        .ForeColor = RGB(0, 0, 0)
        .Font.Name = "メイリオ"
        .TextAlign = 2
        .FontSize = 10
        .Text = ""
    End With
  End With

End Sub

※「ここです！！！！！！！」と記載させていただきました。

「ボタンを押して表示されるコントロール」はよく扱うのですが、コード上でコンボボックスを作成するのは初めてです。
根本的に間違えている場合などもありましたら、アドバイスいただければ幸いです。

よろしくお願いします。

行動規範の内容に同意します

回答1件

ベストアンサー

ここです！！！！！！！の部分を下記のように修正してください。

vba
1      With cmdAdd_1
2        .List = Split(strData, ",")'ここです！！！！！！！

.Listプロパティには配列を代入できます。Split関数で文字列を配列に変換します。

別案

Collection の代わりに Dictionary を使うと追加したデータを簡単に配列として取り出せますのでシンプルなコードにできます。Keysプロパティでキーを配列として、Itemsプロパティでアイテムを配列として取り出せます。
ただし、参照設定で Microsoft Scripting Runtime にチェックを入れておく必要があります。

vba
1Public Sub Addbtn_Click()
2    Dim Data As New Dictionary
3    Dim intD As Long, i As Long
4    intD = Cells(3, 1).End(xlDown).Row    '最終行
5    For i = 3 To intD
6        Data(Cells(i, 1).Value) = i
7    Next i
8
9    Dim cmdAdd_1 As MSForms.ComboBox
10    Set cmdAdd_1 = Me.Controls.Add("Forms.ComboBox.1", "Tzya", True)
11    With cmdAdd_1
12        .List = Data.Keys
13        .Top = 58
14        .Left = 70
15        .Height = 20
16        .Width = 250
17        .BorderStyle = fmBorderStyleSingle
18        .BackColor = RGB(255, 255, 255)
19        .ForeColor = RGB(0, 0, 0)
20        .Font.Name = "メイリオ"
21        .TextAlign = 2
22        .FontSize = 10
23        .Text = ""
24    End With
25End Sub