ACCESSのフォームでレコードを登録する際に、テキストボックスが空白の場合は登録しない方法

Question

Accessにて、データベースにレコードを登録するフォームを作成しています。

テキストボックスに入力した情報を登録するところまではできたのですが、
下記の2点をクリアするにはどうしたらよろしいでしょうか？

　◎テキストのボックスの値が全て空白だった場合は、無動作
⇒下記コードにて、できるようになりました！
ありがとうございます。

　◎テキストボックスの入力項目で、全ての項目が埋まっていなくてもエラーが出ず登録される
⇒3か所だけ、テキストボックスに文字を入力しても、無動作になってしまいます。原因がわかりません。

コード

Private Sub brn_regi_Click()
  


    Dim Rst As DAO.Recordset
    Set Rst = CurrentDb.OpenRecordset("PartsList２", dbOpenTable)
    

    Dim fld As Variant
    Dim NotNull As Boolean
    
    For Each fld In Rst.Fields
        If fld.Name <> "ID" Then
            If Nz(Me(fld.Name).Value) <> "" Then
                NotNull = True
                Exit For
            End If
        End If
    Next
    If NotNull = False Then GoTo Exit_Sub

    Rst.AddNew
    For Each fld In Rst.Fields
        If fld.Name <> "ID" Then
            fld.Value = Me(fld.Name).Value
            Me(fld.Name).Value = Null
        End If
    Next
    Rst.Update
    MsgBox "登録が完了しました"

Exit_Sub:


        
    Rst.Close
    Set Rst = Nothing
    
    Dim cl As Control
    On Error Resume Next
    For Each cl In Me.Controls
        With cl
            If .ControlType = acTextBox Then
                .Value = Null
            End If
        End With
    Next cl

End Sub

ご教授よろしくお願いします。

Answer 1

◎テキストのボックスの値が全て空白だった場合は、無動作

Private Sub brn_regi_Click()
    If Nz(Me!txUse_Place)="" And Nz(Me!txClass_1)="" And Nz(Me!txClass_2)="" And Nz(Me!txPartsName_D)="" Then
        Exit Sub
    End If
    
    '以下略

◎テキストボックスの入力項目で、全ての項目が埋まっていなくてもエラーが出ず登録される

数値型のフィールドに ""（空文字列）を入力しようとしているのが原因です。
下記のコードでテキストボックスに""を代入せずに、Nullを代入しましょう。

    For Each cl In Me.Controls
        With cl
            If .ControlType = acTextBox Then
                '.Value = "" 下記に修正 
                .Value = Null
            End If
        End With
    Next cl

---

追記 フィールド数が多い場合のコードの簡潔化

テーブルのフィールド名とフォーム上のテキストボックス名は同じにしておく。
（テーブルからウィザードで作成すると自動で同じ名前にしてくれるので楽、その後、コントロールソースとレコードソースを削除）

一応、「ID」フィールドはオートナンバー型のフィールドと仮定してスルーするようにしてありますが、実際のテーブルに合わせてください。

Private Sub brn_regi_Click()
    Dim Rst As DAO.Recordset
    Set Rst = CurrentDb.OpenRecordset("T_Data", dbOpenTable)

    Dim fld As Variant, NotNull As Boolean
    For Each fld In Rst.Fields
        If fld.Name <> "ID" Then
            If Nz(Me(fld.Name).Value) <> "" Then
                NotNull = True
                Exit For
            End If
        End If
    Next
    If NotNull = False Then GoTo Exit_Sub

    Rst.AddNew
    For Each fld In Rst.Fields
        If fld.Name <> "ID" Then
            fld.Value = Me(fld.Name).Value
            Me(fld.Name).Value = Null
        End If
    Next
    Rst.Update
    MsgBox "登録が完了しました"
    
Exit_Sub:
    Rst.Close
    Set Rst = Nothing
End Sub

Comments

[YISS]

◎テキストのボックスの値が全て空白だった場合は、無動作
⇒長くなってしまうので、コードを一部省略して記載したのですが、
　　フィールドが全部で２２項目あります。
　　教えて頂いたコードに当てはめると、かなり長くなってしまうのですが、
　　何か完結に書く方法など無いでしょうか？

◎テキストボックスの入力項目で、全ての項目が埋まっていなくてもエラーが出ず登録される
　⇒データは、数値型です。
　　フィールドの情報と、エラーの画像を質問欄に追記しました。

[hatena19]

連結フォームにすれば、
DoCmd.RunCommand acCmdSaveRecord
と１行ですみ一番完結になりますが、連結フォームを使わない理由はなんでしょうか。
連結フォームだと勝手に登録されてしまうということであれば、下記の方法で保存ボタンのみで保存できるようにもできます。

レコード入力時に「保存」コマンドボタンでのみレコード保存できるようにする https://hatenachips.blog.fc2.com/blog-entry-162.html

[YISS]

返信遅くなり申し訳ありません。
そして、何度も回答頂きありがとうございます。

教えて頂いたコードで修正中なのですが、エラーがでてきてきますので、
現在自分で原因調査中です。
新しく出たエラーコードを、投稿しておきますので、
もし、お分かりでしたら、教えて頂けると助かります。

[hatena19]

数値型フィールドに対するデータ型のエラーなので、数値でないものを代入してませんか。
例えば、123,245 とカンマで桁区切りしているとか、\123 とか 123円 などと単位を付けているとか。

[YISS]

◎テキストのボックスの値が全て空白だった場合は、無動作
⇒この動作確認を行いたく、テキストボックスは全て未入力の状態で登録ボタンを押しています

[hatena19]

エラーが出たとき、[デバッグ]ボタンを押して、イミディエイトウィンドウで、
?fld.Name
と入力してEnterキーを押したらどうなりますか。
テーブルのフィールド名が表示されますか。
もし、表示されたら、そのフィールド名で、
?Me("フィールド名").Value
と入力してEnterキーを押したらどうなりますか。

[YISS]

フィールド名が出てきたので、?Me("フィールド名").Valueを入力。
下記のエラーコードが出てきます。
実行時エラー”438”：
オブジェクトは、このプロパティまたはメソッドをサポートしていません。

ちなみにそのフィールドは、数値型です。

[YISS]

すみません。該当箇所ですが、先にラベル名＝テーブルのフィールド名になっていた為、テーブルのフィールド名＝フォーム上のテキストボックス名になっていませんでした。
修正して再トライしてみます。

[YISS]

先ほどの件ですが、該当箇所を
テーブルのフィールド名＝フォーム上のテキストボックス名
に修正したところ、エラーメッセージの問題は解消されました。

ただ、テキストボックスが25ヵ所あるのですが、その内3つだけ、
文字を入力しても無動作になります。
何が原因かわかりますでしょうか？

[hatena19]

ステップ実行で該当コードの式の値がどうなっているか確認してください。
コード自体には問題がないはずですので（こちらのサンプルで確認済み）どこかに間違いがあるはずです。
ここまでくるとデバッグ作業の領域ですので、実物のファイルがないこちらからではアドバイスは難しいです。

[YISS]

検証して、無事解決できました。
何度もありがとうございました。