VBA マクロの処理後に特定のセルを上書きする方法

Question

以下の「現状のソース」を実行すると「転記先（現状の状況）」のように転記が実行されます。
そこで、一通りの天気が終わった後に担当者が「I」もしくは「O」の時にそこから左の「開発」列と「ファイル名」列を何も記載されていない空白のセルに書き換えたい（今回でいうとA10、B10、A15,B15）のですがインターネットで調べてもよくわかりませんので教えていただきたいです。

よろしくお願いします。

転記元

転記先（現状の状況）

現状のソース

Sub sample1()

    Dim lngRowsNo       As Long                     ' 書きこむ位置
    Dim lngSheetIndex   As Long                     ' シートの番号
    Dim strFile         As String                   ' Excelファイルの場所
    Dim xlsAcq          As New Excel.Application    ' 取得側Excel
    Dim wbAcq           As Workbook                 ' 取得側Excelブック
    Dim wsAcq           As Worksheet                ' 取得側Excelシート
    Dim wsSet           As Worksheet                ' 設定側Excelシート
    Const strPath       As String = "パスを指定する"
    Set wsSet = ActiveSheet
    Dim i As Long

     strFile = Dir(strPath & "*.xls")
    lngRowsNo = 3
    Do Until strFile = ""
        '----- Excelブックを開く
        Set wbAcq = Workbooks.Open(strPath & strFile)

        '----- シートを検索
        For lngSheetIndex = 1 To wbAcq.Worksheets.Count
            '----- 「更新」シートを検索
            If wbAcq.Worksheets(lngSheetIndex).Name = "更新" Then
                '----- 「更新」シートを変数へ登録
                Set wsAcq = wbAcq.Worksheets(lngSheetIndex)
                '----- 「更新」シートの内容を現在のシートにコピー(自由に変更して下さい)
                With wsAcq
                Dim fname As String        'ファイル名
                Dim n As Long                  'ループで使用します。
                Dim m As Long                  'ループで使用します。
                Dim ec1 As Long               '各開発の一番下の担当者のセルを取得
                Dim ec2 As Long               '各開発の 月の一番右（最後）のセルを取得
                Dim ColumnNo As Long    ' 転記先の列番号（初期値４）
                Dim ColumnNo2 As Long    ' 転記元の列番号（初期値５）＋３されていく
                
                ColumnNo = 4
                ColumnNo2 = 5

                For i = 1 To .UsedRange.Rows.Count

                  If (Left(.Cells(i, 2).Value, 3) = "開発A" Or Left(.Cells(i, 2).Value, 3) = "開発B" Or Left(.Cells(i, 2).Value, 3) = "開発C") And .Cells(i, 2).MergeCells = False Then
                     '月を取得して転記
                    ec2 = .Cells(i + 1, 5).End(xlToRight).Column + 1
                    For col = 5 To ec2
                    
                        wsSet.Cells(2, ColumnNo).Value = .Cells(i + 1, ColumnNo2).Value
                        
                        ColumnNo = ColumnNo + 1
                        ColumnNo2 = ColumnNo2 + 3
                        
                    Next col

                    ' ------ 開発〇から一番上の担当者のセル位置を相対的にCells(i + 3, 3)として取得し
                     'データの入っているところまでループさせる (その時、開発名を転記)
                     ec1 = .Cells(i + 3, 2).End(xlDown).Row
                        For n = i + 3 To ec1
                        
                        '担当者が空白の時スキップする
                        If Cells(n, 3) = "" Then
                        GoTo NEXT99
                        End If
                        
                            'ファイル名
                            fname = ActiveWorkbook.Name
                            wsSet.Cells(lngRowsNo, 1).Value = fname
                            
                            '開発
                            wsSet.Cells(lngRowsNo, 2).Value = .Cells(i, 2).Value
                            
                             '担当者
                            wsSet.Cells(lngRowsNo, 3).Value = .Cells(n, 3).Value
                            
                             '工数
                            wsSet.Cells(lngRowsNo, 4).Value = .Cells(n, 5).Value
                            
                            wsSet.Cells(lngRowsNo, 5).Value = .Cells(n, 8).Value
                            
                            wsSet.Cells(lngRowsNo, 6).Value = .Cells(n, 11).Value
                            
                            wsSet.Cells(lngRowsNo, 7).Value = .Cells(n, 14).Value
                            
                            wsSet.Cells(lngRowsNo, 8).Value = .Cells(n, 17).Value
                            
                            wsSet.Cells(lngRowsNo, 9).Value = .Cells(n, 20).Value
                            
                            wsSet.Cells(lngRowsNo, 10).Value = .Cells(n, 23).Value
                            
                            wsSet.Cells(lngRowsNo, 11).Value = .Cells(n, 26).Value
                            
                            wsSet.Cells(lngRowsNo, 12).Value = .Cells(n, 29).Value
                            
                            wsSet.Cells(lngRowsNo, 13).Value = .Cells(n, 32).Value
                            
                             '１行下へ
                            lngRowsNo = lngRowsNo + 1
                            
                            
                            
NEXT99:
                        Next n
                    End If
                Next i
                End With
               
                '----- 検索の終了
                Exit For
            End If
        Next lngSheetIndex

        '----- シート参照の解放
        Set wsAcq = Nothing
        '----- ブックを閉じる
        wbAcq.Close Savechanges:=False
        '----- 次のファイルへ
        strFile = Dir()
    Loop

    '----- Excelへの参照の解放
    Set xlsAcq = Nothing

End Sub

Comments

[tatsu99]

何故、担当者がI又はOの時、その人のファイル名と開発の欄を空白にされたいのでしょうか。
担当者I、Oの方は何か特別な人なのでしょうか。差支えなければ、空白にしたい業務的な理由を教えていただけませんでしょうか。

[icecleam]

ご質問ありがとうございます。
すみません、特に理由はないのですが、マクロを勉強する過程で、こちらの処理を行うにはどのようなコードを書けば良いのか単純に気になってしまったのでご質問させていただきました。

Answer 1

End Subの直前に以下の行を追加してください。

    Dim maxrow As Long  '最終行
    maxrow = wsSet.Cells(Rows.Count, 3).End(xlUp).Row 'C列で最終行を求める
    For i = 3 To maxrow
        If wsSet.Cells(i, "C").Value = "I" Or wsSet.Cells(i, "C").Value = "O" Then
            wsSet.Cells(i, "A").Value = ""
            wsSet.Cells(i, "B").Value = ""
        End If
    Next

Answer 2

If文で担当者を判定して、IまたはOの場合転記しなければ良いのでは？

                             '担当者
                            wsSet.Cells(lngRowsNo, 3).Value = .Cells(n, 3).Value
                            If .Cells(n, 3).Value <> "I" And .Cells(n, 3).Value <> "O" Then
                              ' 工数の転記
                            End If