Excel VBA で テスト受験者のグループ分け

Question

Excel VBA で テスト受験者のグループ分けを行いたいです。

約10～20人程度のテスト受験者に対して、3回のグループ分けを行いたいです。
例えば16人をグループ分けする場合、
1回目　8人2グループ
2回目　4人4グループ
3回目　3人5グループ（1人余るので1グループのみ4人）
のような感じです。
難しいところは、「1回目で被った受験者とは2回目、3回目はできるだけ当たらないようにしたい」
ことです。

[やったこと]　上記の16人をグループ分けする場合

Excelファイルに、以下のようなデータを用意しておきます。

インデックス番号　　氏名
1　　　　　　　　　 テスト1
2　　　　　　　　　 テスト2
3　　　　　　　　　 テスト3
・　　　　　　　　　　　・
・　　　　　　　　　　　・
・　　　　　　　　　　　・
16　　　　　　　　　テスト16

VBAで、option base 1 を宣言しておき、
①配列Aにインデックス番号を代入します。インデックス番号の最大値は、グループ分けしたい受験者数です。（A[1] = 1 , A[2] = 2 ・・・・A[16] = 16 みたいな感じ）
②配列Aの中身をシャッフルします。
（A[1] = 6 , A[2] = 2 ・・・・A[16] = 11 みたいな感じ）
③ A[1]からA[8] をグループA　、　A[9]からA[16] をグループBとして1回目のグループ分けが完了。

ここまでコード化できたのですが、2回目以降のグループ分けで、「1回目で被った受験者とは2回目、3回目はできるだけ当たらないようにしたい」というアルゴリズムが考え付きません。
どのような考え方で実現できそうでしょうか。
よろしくお願い致します。

【背景】
テスト受験者のグループ分けを毎回手作業でやっておりました。
方法などはなく、「ただ何となくこれでメンバーが被らず分散されているのではないか」という程度の精度です。（最大人数でも20人なので、目でみて確認しておりました）
しかし、やはりミスや精度に不安がある、加えて何よりも時間がかかるという理由があり、Excel VBAで作れないかとなりました。

【要件について追記】
質問の仕方が慣れておらず申し訳ありません。
要件について以下を追記させて頂きます。

・10人～20人程度で受験者の人数は変化します。（但し、1回目～3回目のグループ分けの間に受験者が変化することはありません。）

・グループ分けの回数は必ず2回以上3回未満です。

・1グループの人数は変化することもあります。
●受験者12人 1回目3人4グループ 2回目4人3グループ
でグループ分けすることもあれば、
●受験者18人 1回目2人9グループ 2回目2人9グループ 3回目3人6グループ
で分けることもあります。

・2回目のグループ分けでは、1回目のメンバーとできるだけ被らないように。
3回目のグループ分けでは、1回目、2回目のメンバーとできるだけ被らないようにしたい。

・「できるだけ被らない」というのは、「被りがどうしようもない」場合は被ることを許可する
というのが理想ですが・・・まさにこの部分のアルゴリズムが考え付きもしません。

・Excel VBA で実現したく思っております。素人目ですが数式では難しいのではと考えております。
（Excel VBA は Excel VBA エキスパートの資格をもっている程度の知識ですが、実務で簡単なマクロなどは作成しております。VBA以外のプログラミング知識はありません。）

要件の記載が足りず申し訳ございませんでした。

Comments

[Orlofsky]

現行のテーブル定義やコードをここが自信ないというコメントと共に、 https://teratail.com/help/question-tips#questionTips3-7 の [コード] で載せないと適切なコメントは付きにくいのでは？

[kitasue]

「1回目で被った受験者とは2回目、3回目はできるだけ当たらないようにしたい」
とのことですが、加えて、
「2回目で被った受験者とは3回目はできるだけ当たらないようにしたい」
という要件はありますか？

[kuma_kuma_]

この答え私の場合だとVBAにしたほうが早いんだけどそれでいい？

[meg_]

どの受験者数であっても、
1回目　2グループ
2回目　4グループ
3回目　5グループ
に分けるのですか？

[access]

皆様、こんなに回答いただけるとは思ってもみませんでした。
本当に有難うございます。

ご指摘の通り、要件の記載が足りなさすぎましたので
追記をさせて頂きました。
お手数をおかけして申し訳ございません。

[kuma_kuma_]

１グループ1人にならないように
2分割づつしていけばいいんだよね？
(前あった人とは被らないように)

あとでVBAで書いておくけどキーワードは
「値が被らないランダムな抽出」と「対戦表」(下半分を略さない)だよ

[access]

kuma_kuma_様
>>１グループ1人にならないように
2分割づつしていけばいいんだよね？
この部分について用件が足りなかったので再び追記させて頂きます。
申し訳ございません。

[access]

要件に以下を追記しました。

・1グループの人数は変化することもあります。
●受験者12人 1回目3人4グループ 2回目4人3グループ
でグループ分けすることもあれば、
●受験者18人 1回目2人9グループ 2回目2人9グループ 3回目3人6グループ
で分けることもあります。

後だしばかりで申し訳ございません。
もっとしっかり質問するべきでした。

Answer 1

文字数オーバの為テスト処理はこちらに書いておきます

• テストパターン1

Public Function test1()
    
    Dim strTestTaker()          As String
    Dim objGrpups               As Object
    Dim varKeys                 As Variant
    Dim varKey                  As Variant
    Dim intIndex                As Integer
    
    ReDim strTestTaker(0 To 19)
    strTestTaker(0) = "Aさん"
    strTestTaker(1) = "Bさん"
    strTestTaker(2) = "Cさん"
    strTestTaker(3) = "Dさん"
    strTestTaker(4) = "Eさん"
    strTestTaker(5) = "Fさん"
    strTestTaker(6) = "Gさん"
    strTestTaker(7) = "Hさん"
    strTestTaker(8) = "Iさん"
    strTestTaker(9) = "Jさん"
    strTestTaker(10) = "Kさん"
    strTestTaker(11) = "Lさん"
    strTestTaker(12) = "Mさん"
    strTestTaker(13) = "Nさん"
    strTestTaker(14) = "Oさん"
    strTestTaker(15) = "Pさん"
    strTestTaker(16) = "Qさん"
    strTestTaker(17) = "Rさん"
    strTestTaker(18) = "Sさん"
    strTestTaker(19) = "Tさん"
    
    '----- テスト受験者グループ分け初期化
    Call initTestTakerGaoups(strTestTaker())

    '----- テスト受験者グループ分け3分割
    Call getTestTakerGaoups(objGrpups, 3)
    Debug.Print "グループ分け3分割"
    For Each varKey In objGrpups.keys
        Debug.Print "" & varKey & ""
        For intIndex = 0 To UBound(objGrpups.Item(varKey))
            Debug.Print "[" & objGrpups.Item(varKey)(intIndex) & "]";
        Next intIndex
        Debug.Print
    Next varKey
    Debug.Print

    '----- テスト受験者グループ分け3分割後5分割
    Call getTestTakerGaoups(objGrpups, 5)
    Debug.Print "グループ分け5分割"
    For Each varKey In objGrpups.keys
        Debug.Print "" & varKey & ""
        For intIndex = 0 To UBound(objGrpups.Item(varKey))
            Debug.Print "[" & objGrpups.Item(varKey)(intIndex) & "]";
        Next intIndex
        Debug.Print
    Next varKey
    Debug.Print

    '----- テスト受験者グループ分け3分割,5分割後8分割
    Call getTestTakerGaoups(objGrpups, 8)
    Debug.Print "グループ分け8分割"
    For Each varKey In objGrpups.keys
        Debug.Print "" & varKey & ""
        For intIndex = 0 To UBound(objGrpups.Item(varKey))
            Debug.Print "[" & objGrpups.Item(varKey)(intIndex) & "]";
        Next intIndex
        Debug.Print
    Next varKey
    Debug.Print

End Function

• テストパターン2

Public Function test2()
    
    Dim strTestTaker()          As String
    Dim objGrpups               As Object
    Dim varKeys                 As Variant
    Dim varKey                  As Variant
    Dim intIndex                As Integer
    
    ReDim strTestTaker(0 To 24)
    strTestTaker(0) = "Aさん"
    strTestTaker(1) = "Bさん"
    strTestTaker(2) = "Cさん"
    strTestTaker(3) = "Dさん"
    strTestTaker(4) = "Eさん"
    strTestTaker(5) = "Fさん"
    strTestTaker(6) = "Gさん"
    strTestTaker(7) = "Hさん"
    strTestTaker(8) = "Iさん"
    strTestTaker(9) = "Jさん"
    strTestTaker(10) = "Kさん"
    strTestTaker(11) = "Lさん"
    strTestTaker(12) = "Mさん"
    strTestTaker(13) = "Nさん"
    strTestTaker(14) = "Oさん"
    strTestTaker(15) = "Pさん"
    strTestTaker(16) = "Qさん"
    strTestTaker(17) = "Rさん"
    strTestTaker(18) = "Sさん"
    strTestTaker(19) = "Tさん"
    strTestTaker(20) = "Uさん"
    strTestTaker(21) = "Vさん"
    strTestTaker(22) = "Wさん"
    strTestTaker(23) = "Xさん"
    strTestTaker(24) = "Yさん"
    
    '----- テスト受験者グループ分け初期化
    Call initTestTakerGaoups(strTestTaker())

    '----- テスト受験者グループ分け2分割
    Call getTestTakerGaoups(objGrpups, 2)
    Debug.Print "グループ分け2分割"
    For Each varKey In objGrpups.keys
        Debug.Print "" & varKey & ""
        For intIndex = 0 To UBound(objGrpups.Item(varKey))
            Debug.Print "[" & objGrpups.Item(varKey)(intIndex) & "]";
        Next intIndex
        Debug.Print
    Next varKey
    Debug.Print

    '----- テスト受験者グループ分け2分割後4分割
    Call getTestTakerGaoups(objGrpups, 4)
    Debug.Print "グループ分け5分割"
    For Each varKey In objGrpups.keys
        Debug.Print "" & varKey & ""
        For intIndex = 0 To UBound(objGrpups.Item(varKey))
            Debug.Print "[" & objGrpups.Item(varKey)(intIndex) & "]";
        Next intIndex
        Debug.Print
    Next varKey
    Debug.Print

    '----- テスト受験者グループ分け2分割,4分割後8分割
    Call getTestTakerGaoups(objGrpups, 8)
    Debug.Print "グループ分け8分割"
    For Each varKey In objGrpups.keys
        Debug.Print "" & varKey & ""
        For intIndex = 0 To UBound(objGrpups.Item(varKey))
            Debug.Print "[" & objGrpups.Item(varKey)(intIndex) & "]";
        Next intIndex
        Debug.Print
    Next varKey
    Debug.Print

    '----- テスト受験者グループ分け2分割,4分割,8分割後16分割
    Call getTestTakerGaoups(objGrpups, 16)
    Debug.Print "グループ分け16分割"
    For Each varKey In objGrpups.keys
        Debug.Print "" & varKey & ""
        For intIndex = 0 To UBound(objGrpups.Item(varKey))
            Debug.Print "[" & objGrpups.Item(varKey)(intIndex) & "]";
        Next intIndex
        Debug.Print
    Next varKey
    Debug.Print

End Function

Answer 2

とりあえず

• 登録人数は任意
• 分割数も任意
• 分割処理を繰り返すので以前に一度でも同じグループになった人にならないようにする

で作りました

使い方はテストを見てもらえばわかると思いますが

    Call initTestTakerGaoups(strTestTaker())

でテスト受験者を登録

    Call getTestTakerGaoups(objGrpups, 8)

で結果を連想配列で取得します。
連想配列からの値の取得方法もテストを見てもらえばわかると思います
(本当はふつうの配列でも良かったんですがデバッグで何の数値か判らなくなる為)

注意点
一定以上「結果を連想配列」で取得すると「同じになった事がない人」が無くなります。
(条件にもよりますが4,5回程度)
その場合は再度「テスト受験者を登録」でリセットしてください。
※わかりずらくなるので処理入れていません。

簡単に説明すると対戦表(objBattleTable)を作ってそこに同じになったかを記録します
普通対戦表は斜めで分けますが検索しやすい様に両側に設定しておく事です。
これはグループ分けの時の判断材料となります。

グループ分けは「余り人数振り分け」で見てもらうと判りやすいですが考え方が
質問者様の内容から変更しています
例として10人を4グループの場合
0. 3,3,4 の3グループ

1. 3,3,2,2の4グループ

の考え方ができますが今回後者を使用しました。
(10人を6グループなどにも対応可能にする為)

あとはテスト受験者抽出ですが条件はあくまでグループ分け処理1回の間に「同じ人が選ばれない」事
ですのでそれだけに気を付ければ良いだけです。

作って動かして確認しているのですが
デバッグが大変ですみませんが検証お願いします。
なにかありましたら対応します。

• メイン処理になります

Private objBattleTable As Object            '対戦テーブル
Private strTestTakersBuffer() As String     'テスト受験者バッファ

Public Sub initTestTakerGaoups(ByRef strTestTakers() As String)
'-------------------------------------------------------------------------------
'   initTestTakerGaoups
'   説明
'       テスト受験者グループ分け初期化
'   パラメータ
'       strTestTakers       :テスト受験者一覧
'   戻り値
'       なし
'-------------------------------------------------------------------------------
    
    Dim intTTFIndex     As Integer              'テスト受験者バッファインデックス
    Dim intTTFIndexA    As Integer              'テスト受験者バッファインデックスA
    Dim intTTFIndexB    As Integer              'テスト受験者バッファインデックスB
    Dim strBTKeyA       As String               '対戦テーブルキーA
    Dim strBTKeyB       As String               '対戦テーブルキーB

On Error GoTo initTestTakerGaoups_Error:

    '----- テスト受験者のバッファと対戦表作成
    ReDim strTestTakersBuffer(0 To UBound(strTestTakers))
    Set objBattleTable = CreateObject("Scripting.Dictionary")
    For intTTFIndex = 0 To UBound(strTestTakers)
        '----- テスト受験者のバッファ
        strTestTakersBuffer(intTTFIndex) = strTestTakers(intTTFIndex)
        '----- 対戦表作成(列)
        strBTKeyA = strTestTakers(intTTFIndex)
        objBattleTable.Add strBTKeyA, CreateObject("Scripting.Dictionary")
        For intTTFIndexB = 0 To UBound(strTestTakers)
            '----- 対戦表作成(行)
            strBTKeyB = strTestTakers(intTTFIndexB)
            objBattleTable.Item(strBTKeyA).Add strBTKeyB, 0
        Next intTTFIndexB
    Next intTTFIndex
    
    '----- 行列同じ場合、(自分同士)の何回同じになったか設定
    For intTTFIndexA = 0 To UBound(strTestTakersBuffer)
        strBTKeyA = strTestTakersBuffer(intTTFIndexA)
        objBattleTable.Item(strBTKeyA).Item(strBTKeyA) = 9999   'Max値
    Next intTTFIndexA

initTestTakerGaoups_End:
On Error Resume Next
Exit Sub

'----- エラー処理
initTestTakerGaoups_Error:
Resume initTestTakerGaoups_End:
End Sub

Public Sub getTestTakerGaoups(ByRef objGrpups As Object, DivisionNumber As Integer)
'-------------------------------------------------------------------------------
'   getTestTakerGaoups
'   説明
'       テスト受験者グループ分け
'   パラメータ
'       objGrpups               : テスト受験者グループ一覧(連想配列)
'       DivisionNumber          : 分割数(グループ数)
'   戻り値
'       objGrpups               : テスト受験者グループ一覧(連想配列)
'-------------------------------------------------------------------------------
    
    Dim strTestTakersTemp() As String           'テスト受験者一時保管
    Dim intTTTIndex         As Integer          'テスト受験者一時保管インデックス
    Dim intGroupsMax()      As Integer          '各グループ毎の最大人数設定
    Dim intGroupNumber      As Integer          'グループの人数
    Dim intGroupNumberMod   As Integer          'グループの人数(あまり)
    
    Dim strTestTakers()     As String           'グループ内のテスト受験者一覧
    Dim intTTIndex          As Integer          'テスト受験者インデックス
    Dim intTTIndexBef       As Integer          'テスト受験者インデックス(前)
    Dim intGroupNo          As Integer          'グループNo
    Dim strGroupName        As String           'グループ名
    Dim strTestTaker        As String           'テスト受験者
    Dim strTestTakerBef     As String           'テスト受験者
    Dim blnInTheSame        As Boolean          '同じになったか
    Dim blnInLoopEnd        As Boolean          'ループの終わり

On Error GoTo getTestTakerGaoups_Error:

    Set objGrpups = CreateObject("Scripting.Dictionary")
    
    '----- バッファから一時保管へコピー
    ReDim strTestTakersTemp(0 To UBound(strTestTakersBuffer))
    For intTTTIndex = 0 To UBound(strTestTakersTemp)
        strTestTakersTemp(intTTTIndex) = strTestTakersBuffer(intTTTIndex)
    Next intTTTIndex

    '----- グループ数計算
    intGroupNumber = (UBound(strTestTakersTemp) + 1) \ DivisionNumber
    If intGroupNumber <= 0 Then
        Call MsgBox("引数エラー:分割数がテスト受験者を超えています。", vbInformation + vbOKOnly)
        Exit Sub
    End If
    
    '----- 各グループ毎の最大人数設定
    intGroupNumberMod = (UBound(strTestTakersTemp) + 1) Mod DivisionNumber
    ReDim intGroupsMax(0 To DivisionNumber - 1)
    For intDivisionIndex = 0 To UBound(intGroupsMax)
        intGroupsMax(intDivisionIndex) = intGroupNumber
    Next intDivisionIndex
    '----- 余り人数振り分け
    For intDivisionIndex = 0 To intGroupNumberMod - 1
            intGroupsMax(intDivisionIndex) = intGroupsMax(intDivisionIndex) + 1
    Next intDivisionIndex

    '----- グループ毎の処理
    For intGroupNo = 0 To UBound(intGroupsMax)
        '----- グループ内のテスト受験者一覧初期化
        ReDim strTestTakers(0 To intGroupsMax(intGroupNo) - 1)
        strGroupName = "グループ" & (intGroupNo + 1)
        
        For intTTIndex = 0 To UBound(strTestTakers)
            
            blnInLoopEnd = False
            Do Until blnInLoopEnd
                '----- 一定範囲のランダム数取得
                'Int((最大値 - 最小値 +1) * Rnd + 最小値)
                intTTTIndex = Int((UBound(strTestTakersTemp) - 0 + 1) * Rnd + 0)
                strTestTaker = strTestTakersTemp(intTTTIndex)   'ランダムで選ばれたテスト受験者
                
                Select Case intTTIndex
                    Case 0
                        '----- 初回は無判定で登録
                        blnInTheSame = False
                        strTestTakers(intTTIndex) = strTestTaker
                
                        '----- テスト受験者一時保管から選んだテスト受験者を削除
                        If UBound(strTestTakersTemp) = 0 Then
                            Erase strTestTakersTemp
                        Else
                            strTestTakersTemp(intTTTIndex) = strTestTakersTemp(UBound(strTestTakersTemp))
                            ReDim Preserve strTestTakersTemp(0 To UBound(strTestTakersTemp) - 1)
                        End If
                                    
                        blnInLoopEnd = True 'ループ終了
                    
                    Case Else
                        '----- グループに登録されている人と一度も同じになったことが無いか判定
                        blnInTheSame = False
                        For intTTIndexBef = 0 To intTTIndex - 1
                            strTestTakerBef = strTestTakers(intTTIndex) 'グループ登録済みテスト受験者
                            If objBattleTable.Item(strTestTaker).Item(strTestTakerBef) > 0 Then
                                blnInTheSame = True
                                Exit For
                            End If
                        Next intTTIndexBef
                
                        If blnInTheSame = False Then
                            '----- グループに登録されている全員と一度も同じになったことが無い場合
                            strTestTakers(intTTIndex) = strTestTaker
                            
                            '----- 対戦表の更新
                            For intTTIndexBef = 0 To intTTIndex - 1
                                strTestTakerBef = strTestTakers(intTTIndex) 'グループ登録済みテスト受験者
                                objBattleTable.Item(strTestTaker).Item(strTestTakerBef) = objBattleTable.Item(strTestTaker).Item(strTestTakerBef) + 1
                                objBattleTable.Item(strTestTakerBef).Item(strTestTaker) = objBattleTable.Item(strTestTakerBef).Item(strTestTaker) + 1
                            Next intTTIndexBef
                             
                            '----- テスト受験者一時保管から選んだテスト受験者を削除
                            If UBound(strTestTakersTemp) = 0 Then
                                Erase strTestTakersTemp
                            Else
                                strTestTakersTemp(intTTTIndex) = strTestTakersTemp(UBound(strTestTakersTemp))
                                ReDim Preserve strTestTakersTemp(0 To UBound(strTestTakersTemp) - 1)
                            End If
                            blnInLoopEnd = True 'ループ終了
                        
                        End If
                End Select
            Loop
        Next intTTIndex

        '----- グループ登録　　    
        objGrpups.Add strGroupName, strTestTakers
    
    Next intGroupNo

getTestTakerGaoups_End:
On Error Resume Next
Exit Sub

'----- エラー処理
getTestTakerGaoups_Error:
    Call MsgBox("ErrNo:" & Err & vbNewLine & Error, vbOKOnly)
Resume getTestTakerGaoups_End:
End Sub

Comments

[access]

こんなにも力を貸して下さいまして本当に有難うございます。
理解に時間がかかるかもしれませんが、じっくり読んで勉強させて頂きます。
取り急ぎお礼申し上げます。

[kuma_kuma_]

いや本当にこの内容説明しずらいと思いますよ。
今回やりたいことの理由を書かれていなかったら理解できませんでした。

私が勝手に考えた方式なので基本となるアルゴリズムはたぶんないです。
読まれておかしいと思ったら質問してください。
後テスト丸投げですみません。
ランダムな結果なので確認が追い付きませんでした。

あと注意点が抜けていたので追記します。

Answer 3

1回目と2回目と3回目のグルーピングするマクロは、別々に書くことをおススメします。
グルーピングも1回目用シート、2回目用シート等に分けて、実行ボタンも分けるイメージです。
でないと、プログラムが煩雑となりアルゴリズムを考えるのが大変です。

そうすると、1回目のシートに誰と誰が一緒だったのかの記録が残っているので
それを利用しましょう。

グループを登録していく際に、毎回重複が無いかチェックするイメージです。
以下のようなイメージです。
グループA
1人目の登録　→　被ることは無いので無条件で登録
2人目の登録　→　（重複チェック）
①1人目の1回目のグループを見て2人目と同じグループかチェック
②同じだったら、違う人を探して違うグループが当たるまで繰り返す。
③違うグループの人がもういない場合は仕方ないので重複しても登録。

3回目は、無理して2回目も考慮する必要は無いと思います。
かなり難しくなると思います。

グルーピングのマクロを別々に書くことと、3回目の時に2回目を妥協すると
だいぶハードルが下がるのではないかと思います。

Answer 4

アルゴリズム無視の暴論になるのですが、以前に作った表はあるのですよね？
それならその表をそのまま生かせば良いのではないでしょうか？

受験する人が全く同じで、組み合わせも前と同じになる、というのなら
組み合わせ表はそのままで、名前だけシャッフルすれば事足りる気がします。
今までにない人数になった場合は、新しく作らないといけませんが、１回作れば後は問題ないですし。

アルゴリズムは他の方に任せます。私には難しすぎる……。
趣旨が違った場合は申し訳ありません。

Answer 5

こういう入力の時はこう出力して欲しいというinputとoutputの例示が無いから質問が漠然としてしまっていると思います。
このままだと要件が曖昧で未定となることが多く質問には回答がつきにくいと思いました。
なるべく避けるという定義が曖昧だと思いますが質問内容に書かれている今知り得る条件だけで考えるなら・・・

こういう時はまず手作業で分配やってみることです。
１回目８人の２グループで２回目４人の４グループだとどうやっても必ず２人は被ります。
なのでそこは仕方ないと割り切って単純にAで1～8と9～16を2つに分けます。
Ａ→Ｂは必ず２人被るという結果しか無いと思いますので単純に順番に割り振り。
Ｂ→Ｃは左端と右端から1人づつ選んで1g2だとBの左端の最初の1と右端のgと真ん中の2という具合に
Ｃの最後５グループ目は残り。

A 12345678 9abcdefg
B 159d 2a6e 37bf 48cg
C 1g2 5ca 986 d4e 2f37

16人固定なら初回Ａをシャッフルした後、各配列番号に換算して実装すれば良いかと。
人数不定となると面倒そうですね。

これは一例を示しただけですが、質問者さんも例示したほうが良いかと思います。
質問後に足りない条件や要件が後出しされると回答者は回答しにくいものです。

Comments

[access]

ご指摘有難うございます。
質問が慣れておらず、ご迷惑をおかけ致します。
要件について追記をさせて頂きました。
せっかく回答くださいましたのに申し訳ございません。

[mjk]

いえいえ。多分修正依頼のやり取りだけだと埒が明かないと思いましたので。
これで質問の要件が整理されて回答がつきやすくなれば良いですね。