質問をすることでしか得られない、回答やアドバイスがある。

15分調べてもわからないことは、質問しよう!

ただいまの
回答率

87.33%

シェーダを使って円の枠の色を変えたい

解決済

回答 1

投稿

  • 評価
  • クリップ 0
  • VIEW 758

score 13

前提・実現したいこと

シェーダを使って円の枠の色を変えたい
↓実現したいこと
![イメージ説明

↓現状
![イメージ説明

該当のソースコード

Shader "Unlit/Circle"
{
    Properties
    {
        _Color("Color", Color) = (1,0.5,0,1) // 円の内側の色
        _BackgroundColor("Background Color", Color) = (1,1,1,1) // 円の外側の色
        _FrameColor("Frame Color",Color)=(1,0.5,0.1) //円の枠の色
        _MainTex("Texture", 2D) = "white" {}
    }
        SubShader
    {
        Tags {"Queue" = "Transparent" "IgnoreProjector" = "True" "RenderType" = "Transparent"}
        LOD 100

        ZWrite Off
        Blend SrcAlpha OneMinusSrcAlpha

        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            // make fog work
            #pragma multi_compile_fog

            #include "UnityCG.cginc"

            struct appdata
            {
                float4 vertex : POSITION;
                float2 uv : TEXCOORD0;
            };

            struct v2f
            {
                float2 uv : TEXCOORD0;
                UNITY_FOG_COORDS(1)
                float4 vertex : SV_POSITION;
            };

            sampler2D _MainTex;
            float4 _MainTex_ST;

            // プロパティで設定された色を受け取るユニフォーム変数を用意する
            fixed4 _Color;
            fixed4 _BackgroundColor;
            fixed4 _FrameColor;

            v2f vert(appdata v)
            {
                v2f o;
                o.vertex = UnityObjectToClipPos(v.vertex);
                o.uv = TRANSFORM_TEX(v.uv, _MainTex);
                UNITY_TRANSFER_FOG(o,o.vertex);
                return o;
            }

            fixed4 frag(v2f i) : SV_Target
            {
                fixed radius = 0.4;
                fixed r = distance(i.uv, fixed2(0.5,0.5));

                // lerpで色を選択する
                // stepの結果が0なら_Colorを、1なら_BackgroundColorを返させるようにする
                return lerp(_Color, _BackgroundColor, step(radius, r));
            }
            ENDCG
        }
    }
}

補足情報(FW/ツールのバージョンなど)

環境:Windows10、VisualStudio2019、Unity2020.1.0b13 Personal

  • 気になる質問をクリップする

    クリップした質問は、後からいつでもマイページで確認できます。

    またクリップした質問に回答があった際、通知やメールを受け取ることができます。

    クリップを取り消します

  • 良い質問の評価を上げる

    以下のような質問は評価を上げましょう

    • 質問内容が明確
    • 自分も答えを知りたい
    • 質問者以外のユーザにも役立つ

    評価が高い質問は、TOPページの「注目」タブのフィードに表示されやすくなります。

    質問の評価を上げたことを取り消します

  • 評価を下げられる数の上限に達しました

    評価を下げることができません

    • 1日5回まで評価を下げられます
    • 1日に1ユーザに対して2回まで評価を下げられます

    質問の評価を下げる

    teratailでは下記のような質問を「具体的に困っていることがない質問」、「サイトポリシーに違反する質問」と定義し、推奨していません。

    • プログラミングに関係のない質問
    • やってほしいことだけを記載した丸投げの質問
    • 問題・課題が含まれていない質問
    • 意図的に内容が抹消された質問
    • 過去に投稿した質問と同じ内容の質問
    • 広告と受け取られるような投稿

    評価が下がると、TOPページの「アクティブ」「注目」タブのフィードに表示されにくくなります。

    質問の評価を下げたことを取り消します

    この機能は開放されていません

    評価を下げる条件を満たしてません

    評価を下げる理由を選択してください

    詳細な説明はこちら

    上記に当てはまらず、質問内容が明確になっていない質問には「情報の追加・修正依頼」機能からコメントをしてください。

    質問の評価を下げる機能の利用条件

    この機能を利用するためには、以下の事項を行う必要があります。

回答 1

checkベストアンサー

0

シェーダー上で図形を描くのは、感覚的に理解しやすいであろう「位置を決めてピクセルを塗る」といった手順とは異なり「まずピクセルの位置が与えられ、そのピクセルの色を決める」とでも言うような逆向きの発想が要求されるでしょうから、ちょっととっつきにくいかもしれませんね。

枠を描くとなると、境界線上であるかどうかを判定する仕組みを考える必要があるでしょう。
現状では「現在描画しようとしているピクセルの位置が、円の中心からの距離が指定された半径値以上であるか」によって円の内外を判定しています。それを応用すると...

  • まずこのピクセルの位置が円の境界線外側よりも遠いかを判定する。遠いなら背景色で塗り、近いなら境界線色で塗る。
  • 次に円の境界線内側よりも遠いかを判定する。遠いなら色はそのままとし、近いなら塗りつぶし色で塗る。

という風に実装できないでしょうか?

Shader "Unlit/Circle"
{
    Properties
    {
        _Color("Color", Color) = (1,0.5,0,1) // 円の内側の色
        _BackgroundColor("Background Color", Color) = (1,1,1,1) // 円の外側の色
        _FrameColor("Frame Color",Color)=(1,0.5,0.1) //円の枠の色
        _FrameWidth("Frame Width", Range(0.0, 0.1)) = 0.01 // 円の枠の太さ
        _MainTex("Texture", 2D) = "white" {}
    }
        SubShader
    {
        Tags {"Queue" = "Transparent" "IgnoreProjector" = "True" "RenderType" = "Transparent"}
        LOD 100

        ZWrite Off
        Blend SrcAlpha OneMinusSrcAlpha

        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            // make fog work
            #pragma multi_compile_fog

            #include "UnityCG.cginc"

            struct appdata
            {
                float4 vertex : POSITION;
                float2 uv : TEXCOORD0;
            };

            struct v2f
            {
                float2 uv : TEXCOORD0;
                UNITY_FOG_COORDS(1)
                float4 vertex : SV_POSITION;
            };

            sampler2D _MainTex;
            float4 _MainTex_ST;

            // プロパティで設定された色を受け取るユニフォーム変数を用意する
            fixed4 _Color;
            fixed4 _BackgroundColor;
            fixed4 _FrameColor;
            float _FrameWidth;

            v2f vert(appdata v)
            {
                v2f o;
                o.vertex = UnityObjectToClipPos(v.vertex);
                o.uv = TRANSFORM_TEX(v.uv, _MainTex);
                UNITY_TRANSFER_FOG(o,o.vertex);
                return o;
            }

            fixed4 frag(v2f i) : SV_Target
            {
                fixed radius = 0.4;
                fixed r = distance(i.uv, fixed2(0.5,0.5));

                // まず境界線外側について内外判定を行い、色を決定する
                fixed4 color = lerp(_FrameColor, _BackgroundColor, step(radius, r));

                // 次に円の半径を境界線の太さの分だけ縮めて内外判定を行い、最終的な色を決定して返す
                return lerp(_Color, color, step(radius - _FrameWidth, r));
            }
            ENDCG
        }
    }
}

投稿

  • 回答の評価を上げる

    以下のような回答は評価を上げましょう

    • 正しい回答
    • わかりやすい回答
    • ためになる回答

    評価が高い回答ほどページの上位に表示されます。

  • 回答の評価を下げる

    下記のような回答は推奨されていません。

    • 間違っている回答
    • 質問の回答になっていない投稿
    • スパムや攻撃的な表現を用いた投稿

    評価を下げる際はその理由を明確に伝え、適切な回答に修正してもらいましょう。

  • 2020/09/18 21:49

    実装できました。回答ありがとうございます。
    考え方から丁寧に教えていただき、非常に分かりやすいです。
    勉強になります

    キャンセル

15分調べてもわからないことは、teratailで質問しよう!

  • ただいまの回答率 87.33%
  • 質問をまとめることで、思考を整理して素早く解決
  • テンプレート機能で、簡単に質問をまとめられる

関連した質問

同じタグがついた質問を見る