コマンドボタンの.Tagに配列を入れ込みたい

Question

複数のコマンドボタンを作り、それぞれのボタンから関連ﾃﾞｰﾀを表示させたいので、Controls.Add.Tagに複数のデータを登録したく、配列Dataを作成しましたが、「型が一致しません」とエラーが表示され処理されません。
1、Tagに配列は入れられないでしょうか。
2　Tagに配列が入らない場合、複数の数値を入れる方法は内でしょうか。

以下が対象コードです。「''ここに配列を追加しました。」と「 '''配列をここに飛ばしたいです。」のコメントを入れさせていただきました。
よろしくお願いします。

Private Const MAX_CONTROL_NUMBER = 100
Private ctrlbtn(1 To MAX_CONTROL_NUMBER) As New EventButtonClass
Sub UserForm_Initialize()
    Set myCol = New Collection

    Dim row As Long
    row = ActiveCell.row '行番号取得

    With Me
        Dim n As Long
        For n = 1 To 5
            Dim lbl As MSForms.Label
            Set lbl = .Controls.Add("Forms.Label.1", "url" & n, True)
            With lbl
                 .Top = 34 * n                   'Top位置(表示位置を移動する)
                 .Left = 70                          'Left位置
                 .Height = 20                        '高さ
                 .Width = 250                        '幅
                 .BorderStyle = fmBorderStyleSingle  '枠線
                 .BackColor = RGB(128, 128, 128)     '背景色
                 .ForeColor = RGB(255, 255, 255)     '文字色
                 .Font.Name = "メイリオ"             'テキストのスタイル
                 .TextAlign = 2                      'テキストの位置
                 .FontSize = 16                      'テキストのサイズ
                 .Caption = Cells(row, 5)         '''ここにパスワードの題名を付ける
            End With

            Dim NewB As CommandButton
            
            Dim Data(1 To 2) ''ここに配列を追加しました。
            Data(1) = row
            Data(2) = n
            
            Set NewB = UserForm2.Controls.Add("Forms.CommandButton.1", "url" & n, True)
            Call ctrlbtn(n).SetCtrl(NewB)
            With NewB
                .Top = 34 * n
                .Left = 10
                .Height = 20
                .Width = 50
                .Caption = "関連ﾃﾞｰﾀ"
                .Tag = Data ''ここに配列を追加しました。
            End With
            row = row + 1
         Next

    End With
End Sub

クラスのコード

Private WithEvents tgtCtrl As MSForms.CommandButton
Public Sub SetCtrl(new_ctrl As MSForms.CommandButton)
  Set tgtCtrl = new_ctrl
End Sub
Private Sub tgtCtrl_Click()
  Dim intRow As Long
  Dim intcol As Long
  intRow = tgtCtrl.Tag(1)  '''配列をここに飛ばしたいです。
  intcol = tgtCtrl.Tag(2)

End Sub

Answer 1

hatena19様の言われているクラスにセルも格納は下記の様な感じと思います。

            Call ctrlBtn(n).SetCtrl(NewB, Cells(Row, n))

Private WithEvents tgtCtrl As MSForms.CommandButton
Private tgtRange As Range
 
Public Sub SetCtrl(new_ctrl As MSForms.CommandButton, new_Range As Range)
  Set tgtCtrl = new_ctrl
  Set tgtRange = new_Range
End Sub
 
Private Sub tgtCtrl_Click()
  MsgBox "コントロール名: " & tgtCtrl.Name & " - " & tgtRange.Row & " - " & tgtRange.Column
  Dim intRow As Long
  Dim intcol As Long
  intRow = tgtRange.Row
  intcol = tgtRange.Column
End Sub

---

(追記)
Publicを使ってこれにセットする方法もあると思います。(好んで使っています)

            Call ctrlbtn(n).SetCtrl(NewB)
            Set ctrlbtn(n).tgtRange = Cells(row, n)

Private WithEvents tgtCtrl As MSForms.CommandButton
Public tgtRange As Range
Public Sub SetCtrl(new_ctrl As MSForms.CommandButton)
  Set tgtCtrl = new_ctrl
End Sub
Private Sub tgtCtrl_Click()
  MsgBox "コントロール名: " & tgtCtrl.Name & " - " & tgtRange.row & " - " & tgtRange.Column
  Dim intRow As Long
  Dim intcol As Long
  intRow = tgtRange.row
  intcol = tgtRange.Column
End Sub

Comments

[ice930]

セルの格納もできるんですね！
ありがとうございます！
早速使わせていただきます！

Answer 2

下記のような感じでしょうか。

    .Tag = Join(Data, ",") ''ここに配列を追加しました。 

  intRow = Split(tgtCtrl.Tag,",")(0)  '''配列をここに飛ばしたいです。
  intcol = Split(tgtCtrl.Tag,",")(1)  ''''インデックスは0起点になる

Join でカンマ区切り文字列に変換してTagに格納。
SPlit でカンマで分割した配列に変換

VBA - コード中で生成されたコマンドボタンの処理の指定｜teratail
上記の質問の続きですね。
たぶん、セットになるラベルコントロールとセルの参照に使うのだと思いますが、
せっかくクラスを使うのならクラスにラベルコントロールとセルも格納するようにした方が読みやすいコードになると思います。

Comments

[ice930]

joinで文字列を作り、SPlitで配列に変更するんですね！
クラスにセルも格納することにしました！
ありがとうございました！

Answer 3

＞1、Tagに配列は入れられないでしょうか。
はい、String型ですので、文字列しか入りません。

＞2　Tagに配列が入らない場合、複数の数値を入れる方法は内でしょうか。
カンマ区切りで入れるとか。