IntegerにTrueを代入できるのはなぜ？

Question

Private Function APP_Model() As Integer
'この関数は、製品モデルを盤情報に追加します。
Dim mydb As Database
Dim CL_Model_Shousai As New Model_Shousai
Dim sts As Integer
Dim i As Integer
Dim Mas_ID As Long

Set mydb = CurrentDb

APP_Model = True

sts = False
For i = 0 To Me!仕様.ListCount
    If Me!仕様.Selected(i) = True Then
        sts = True
        
        Exit For
    End If
Next

If sts = False Then
    MsgBox "引用データを選択して下さい。", vbCritical + vbOKOnly

    Exit Function

End If

If vbNo = MsgBox("モデル引用を行います。", vbYesNo + vbInformation) Then
    Exit Function
End If

For i = 0 To Me!仕様.ListCount
    If Me!仕様.Selected(i) = True Then
        
        Mas_ID = Me!仕様.Column(0, i)
        
        If True <> CL_Model_Shousai.Copy_One(mydb, Mas_ID, Set_Model_ID) Then
            
            MsgBox "製品モデル詳細の Copy に失敗しました。", vbCritical + vbOKOnly

            APP_Model = False
    
            Exit Function
        End If
    
    End If
Next

End Function
上記のコードでPrivate Function APP_Model() As Integerと宣言して
integerのはずなのになぜtrueなど代入できるのですか？
APP_Model = TrueなどAPP_Model = False

Answer 1

VBA では Integer と Boolean が自動で変換されます。
以下のコードを実行すれば分かると思いますが、VBA は True が -1 で False が 0 なんですね。

Dim i As Integer
i = True
Debug.Print i     ' i = -1
i = False
Debug.Print i     ' i = 0

Dim b As Boolean
b = -1
Debug.Print b     ' b = True
b = 0
Debug.Print b     ' b = False
b = 3
Debug.Print b     ' b = True

VBA に限らず多くの言語で True、False の代わりに数値を使用することができます。

0 が False で、0以外 が True ということが多いです。

これにより If文 の条件として数値が利用できたりします。

昔の言語には Boolean型 なんてなかったので、数値の 0/1 で真偽を判定していたことの名残ともいえます。

それにしても Private Function APP_Model() As Boolean と宣言していないのはバグですよね。
As Integer のままでも問題はないのでしょうが。

Comments

[twck]

ついでに。
題名と質問文の内容が合っていないので、題名を「関数名を関数内で使用」ではなく、「IntegerにTrueを代入できるのはなぜ？」に変えていただけないでしょうか？

[sobue]

昔の言語やバージョンだと便利な型がなかったのですね^ - ^しかも自動変換とか…今回、アクセスから.NETにのせかえする話ですけど年数もあいまってこれは大変だ…(~_~;)

Answer 2

Access って VBA ですかね。

VB.NET には 「 Option Strict On 」 という設定があって、
Off だと Integer 型に Boolean を突っ込んでも怒られないのですが（何か勝手に変換される）、
On にしておくとその辺厳しくなって色々エラーが出る、という設定があるのですが･･･

ぐぐってみましたが、VBA って Strict 的な設定ないのかな･･･？ 見つからなかったです。
VBA はちょっと緩そうなので、デフォルト Off 的な挙動で、On にはできないんですかね･･･？

ちなみに Access は手元にないので Excel の VBA でちょっと試してみました

Sub Macro1()
    Dim i As Integer
    MsgBox (i)   '0

    i = 123
    MsgBox (i)   '123

    i = True
    MsgBox (i)   '-1
    
    i = False
    MsgBox (i)   '0
End Sub

Excel VBA だと -1, 0 に変換されてるみたいですね。