C67～L67行を最終行に罫線と数式をコピーしたい

Question

最終行に６７行をコピーしたいのすが、斜めにコピーされていきます。
すみません、教えてください。

Sub セルコピー()

Range("C67:L67").Copy
  
  n = Cells(Rows.Count, "C").End(xlUp).Row + 1

Range("C" & n).Select
Selection.PasteSpecial Paste:=xlPasteAll

  n = Cells(Rows.Count, "D").End(xlUp).Row + 1

Range("D" & n).Select
Selection.PasteSpecial Paste:=xlPasteAll

 n = Cells(Rows.Count, "E").End(xlUp).Row + 1

Range("E" & n).Select
Selection.PasteSpecial Paste:=xlPasteAll

 n = Cells(Rows.Count, "F").End(xlUp).Row + 1

Range("F" & n).Select
Selection.PasteSpecial Paste:=xlPasteAll

n = Cells(Rows.Count, "G").End(xlUp).Row + 1

Range("G" & n).Select
Selection.PasteSpecial Paste:=xlPasteAll

 n = Cells(Rows.Count, "H").End(xlUp).Row + 1

Range("H" & n).Select
Selection.PasteSpecial Paste:=xlPasteAll

 n = Cells(Rows.Count, "I").End(xlUp).Row + 1

Range("I" & n).Select
Selection.PasteSpecial Paste:=xlPasteAll

n = Cells(Rows.Count, "J").End(xlUp).Row + 1

Range("J" & n).Select
Selection.PasteSpecial Paste:=xlPasteAll

n = Cells(Rows.Count, "K").End(xlUp).Row + 1

Range("K" & n).Select
Selection.PasteSpecial Paste:=xlPasteAll

n = Cells(Rows.Count, "L").End(xlUp).Row + 1

Range("L" & n).Select
Selection.PasteSpecial Paste:=xlPasteAll

End Sub

Answer 1

n = Cells(Rows.Count, "C").End(xlUp).Row + 1

セルに記入したあと、また最終行を取得してますので当然、
1行づつどんどんｎの値が増えていきます。

変数ｎは行番号なので、1回取得してしまえば、あとは使いまわして使えます。
何度も取得する必要がないし、無駄です。

あと、貼り付けの際は、左上の一つのセルを指定することで、
コピーした範囲全部を貼り付けますので、
何度も貼り付ける必要がありません。

Sub セルコピー()
    Dim n As Long

    Range("C67:L67").Copy

    n = Cells(Rows.Count, "C").End(xlUp).Row + 1
    Range("C" & n).PasteSpecial
End Sub

あと、セルを選択するのは、目的ではないので、
選択することは無意味です。

例えば、
「C100セルに貼り付けたい」と思っていたら、
「C100セルに貼り付ける　→　Range("C100").PasteSpecial」と書けばいい話です。

ただし、マクロの記録では記録されませんが、
copyの命令には、貼り付け先を指定できる仕組みが用意されていますので、
以下のようにも書くことができます。

Sub さんぷる()
    With Range("C67:L67")
        .Copy .End(xlDown).Offset(1)
    End With
End Sub

セルの位置の指定の表現は、さまざまな書き方（考え方）で
書けるようになっていますので、臨機応変に使えるよう勉強されると、
応用が利くと思います。

Comments

[退会済みユーザー]

回答、ありがとうございます。都度変わる一番下のセルは、それぞれ指定しないといけないと思っていました。スッキリと指定できるのですね。勉強していきます。