Excel VBA IEを用いたスクレイピングで使用するオブジェクトについて教えてください

Question

Excel VBAのInternetExplorerを用いたスクレイピングで使用するオブジェクトについて教えてください（主にInternetExplorerクラス）

Excel VBAでIEを使用したスクレイピングの勉強をしています。

その際、書籍やサイトを見るとInternetExplorerクラスが使われています。

たとえば、テキストを取得するときは
ie.document.body.InnerText

サイト上に設置されたボタンを押すときには
ie.document.getElementById("Button")

ここで質問なのですが、こうしたInternetExplorerクラスのプロパティ、メソッドはどこを見れば一覧を確認できるのでしょうか。

オブジェクトブラウザで検索すると、InternetExplorerクラスはヒットするのでdocumentがそのメンバであることは確認できます。

しかし、document以下は検索してもヒットせず、documentやその下の（上記の例であればbodyやgetElementByIdなど）のプロパティ、メソッドはどういった種類のものがあるのかがわかりません。

様々な書籍やサイトで当たり前のように使われているInternetExplorerクラスですが、皆様はどのようにして内容や使い方を確認しているのでしょうか。

InternetExplorerクラスについてというよりも基本的なオブジェクトの概念やVBEの使い方の問題かもしれませんが、どうすればInternetExplorerクラスを使用する際に
・ie.document.body.InnerText
・ie.document.getElementById("Button")
などの存在を調べることができるのか教えていただけると幸いです。

※ちなみに、bodyやgetElementByIdはオブジェクトブラウザで検索するとそれぞれ5～6件ヒットするのですが、いずれも所属するクラスがInternetExplorerやdocumentではありませんでした。ただ、「HTMLDocument」など、IE関連っぽいものなので、もしかするとこれらが実はdocumentクラスのメンバなのでしょうか。

Answer 1

確かにDocument「プロパティ」は、Object型の定義なので、オブジェクトブラウザだけでは確認が難しいですね。

私の場合、IEでスクレイピングをする際には、以下の3個のタイプライブラリ(参照設定で指定する物)を参照します。

• Microsoft Internet Controls(SHDocVw)

InternetExplorerそのものの操作

• Microsoft HTML Object Library(MSHTML)

HTMLの操作

• Microsoft Shell Controls And Automation(Shell32)

既存のIEの探索

この3つは私の経験則上必要なものであり、自分が使った範囲では足りていると思いますが、場合によっては追加が必要かもしれません。
しかし、ie.document.body.InnerTextやie.document.getElementById("Button")を探すうえでは上記で足りるはずです。

---

オブジェクトブラウザだけでは確認が難しい、となると実際に実行してみてどのような中身が入るのかを確認するのが一つの手段となります。

以下のコードを実行した場合を例として確認方法を見ていきます。

'SHDocVw = Microsoft Internet Controls
'MSHTML = Microsoft HTML Object Library
'Shell32 = Microsoft Shell Controls And Automation

Sub teratail255119()
    Dim ie As SHDocVw.InternetExplorer
    Set ie = VBA.Interaction.CreateObject("InternetExplorer.Application")
    ie.Visible = True
    ie.navigate "https://www.google.com/"
    
    Do Until ie.readyState = SHDocVw.tagREADYSTATE.READYSTATE_COMPLETE
        VBA.Interaction.DoEvents
    Loop
    
    'ie.documentがMSHTML.HTMLDocument型の変数に代入可能なCOMオブジェクトかどうか。
    Debug.Print TypeOf ie.document Is MSHTML.HTMLDocument
    
    Dim htmlDoc As MSHTML.HTMLDocument
    Set htmlDoc = ie.document
    
    Stop 'ブレークポイント
    
End Sub

上記のコードを実行すると、Stopステートメントで動作が止まると思いますので、その時点のie変数を「ローカルウィンドウ」で確認してみます(以下の画像)。

ローカルウィンドウから、DocumentはObject型のプロパティだが、中身にHTMLDocumentが入っていることがわかります。

「HTMLDocument」で調べると、MSHTMLライブラリにHTMLDocumentという型が含まれているのがわかります。しかし、表示上の型名は被ることがあるのでこの時点ではまだ何とも言えません。

では、ie.DocumentがMSHTML.HTMLDocumentどうかを確認するために、MSHTML.HTMLDocument型の変数にie.Documentを代入してみます(判定だけならTypeOf オブジェクト式 Is 型でもいいですが変数に入れたほうがわかりやすいので)。

    Dim htmlDoc As MSHTML.HTMLDocument
    Set htmlDoc = ie.document

代入を行うと、エラーが発生しないためie.Documentの中身がMSHTML.HTMLDocumentであることがわかります。

あとは、htmlDocに対する入力補完や、オブジェクトブラウザの表示から類推していけば何とかなるでしょう。

Comments

[exnjinia]

画像までつけていただいてありがとうございます。
調べ方の勉強になりました！

Answer 2

初めまして

VBAでもDOM操作をしているようなので、ネットで検索されるとよいかもしれません。
（DOM操作とかjavascriptとか…）

解説が書いてあるサイトがありましたので記載いたします。
VBAのIEエレメント基本操作

Comments

[exnjinia]

ありがとうございます！
リンク先のサイト、勉強になります。