Excel VBAのエラー処理（On Error Resume Nextの処理）がうまくいきません

Question

Excel VBAのエラー処理（On Error Resume Nextでの処理）について

Excel VBAの勉強をしています。
エラー処理の練習として、次のコードを書いたところ、自分の予想と違う処理となりました。

●自分の予想
e002ラベルの処理の後、exit_handleラベルの処理に飛び、Exit Subによってプロシージャが終わる。

●実際の挙動
e002ラベルの処理の後、exit_handleラベルの処理には飛ばず、End Subによってプロシージャが終わる。

なぜ「実際の挙動」の動きをするのか、理由をご存知の方教えていただけないでしょうか。

ちなみに、On Error Resume Next　を　On Error GoTo e002　にした場合、なぜか「自分の予想」通りの動きができました。理由は分かりません・・・

また、あくまで　On Error Resume Next　を使用した上で、自分がやりたいこと（「自分の予想」の動き）をすることは可能でしょうか。
可能であれば、コードをどのように書き換えればよいでしょうか。

Sub test()

On Error GoTo e001

Worksheets("存在しないシート").Select

On Error GoTo 0

from_e001:

'★ここを　On Error Resume Nextではなく、　On Error GoTo e002　にするとなぜか「自分の予想」どおりの動きができる。
On Error Resume Next

    Worksheets("存在しないシート").Select
    
    If Err.Number <> 0 Then
    
        MsgBox "ここはResume内部でエラーした場合の処理です"
        MsgBox "ここからエラーe002ラベルに飛びます"
        GoTo e002
        
    End If
    
    MsgBox "エラーなくここまで来たので、最後に終了処理に入ります。"
    
On Error GoTo 0
    
GoTo exit_handle

exit_handle:

    On Error Resume Next
    MsgBox "終了処理をします！"
    On Error GoTo 0
    Exit Sub

e001:
   
    MsgBox "エラー処理（e001ラベル）に飛びました"
    MsgBox "ここからResumeによって元の処理の続きに行きます"
    Resume Next

e002:

    MsgBox "エラー処理（e002ラベル）に飛びました"
    MsgBox "ここから終了処理(exit_handle)に飛びます"
    Resume exit_handle

End Sub

Answer 1

Resume exit_handleは、エラーになっています。エラー処理中じゃ無いところでResumeを実行したというエラーです。
この時点では、On Error Resume Nextが有効なので、そのエラーで止まりませんが、次の行でErr.Numberを見ると該当する20になっているのが分かります。

On Error Goto xxxxで飛んだ先ではResumeするまでエラー処理中ですが、On Error Resume Nextすると、エラーが発生した時点で次の命令にResumeしています。
次の命令に移った時点ではエラー処理中では無いので、（その後でGotoしようがどうしようが）Resume命令は実行できません。

可能であれば、コードをどのように書き換えればよいでしょうか。

ResumeではなくGotoすればいいかと。

Comments

[exnjinia]

理由がよく理解できました。
とても分かりやすい回答ありがとうございました。

Answer 2

また、あくまで　On Error Resume Next　を使用した上で、自分がやりたいこと（「自分の予想」の動き）をすることは可能でしょうか。

今回の件の場合、On Error Resume Nextは適さないんじゃないんですかね？

出口(Exit sub)を一つに纏めたい意図はわかりますし、そうすることは正解でしょう。
ですが、Gotoでとんだ先でまたGotoで飛ぶというのは、
俗にいうスパゲティコードと呼ばれるものではないでしょうか？
それを避けるためにOn Error Resume Nextと言われているのかなぁとは
思いますが。。。
あと、出来るだけエラーを無効にしておく範囲も狭めておかないと、
想定外のエラーが見つからず、デバッグに苦労することになると思います。

エラーが発生したかどうかは、エラーナンバーを変数に記録してやれば、
後からでも判別可能です。

Sub test()
    Dim e As Long

    On Error GoTo e001
    Worksheets("存在しないシート").Select
    On Error GoTo 0

from_e001:
    '★ここを　On Error Resume Nextではなく、　On Error GoTo e002　にするとなぜか「自分の予想」どおりの動きができる。
    On Error GoTo e002
    Worksheets("存在しないシート").Select
    On Error GoTo 0

    If e = 0 Then
        MsgBox "エラーなくここまで来たので、最後に終了処理に入ります。"
    Else
        MsgBox "e002へ飛びました。"
    End If

exit_handle:
    MsgBox "終了処理をします！"
    Exit Sub

e001:
    MsgBox "エラー処理（e001ラベル）に飛びました"
    MsgBox "ここからResumeによって元の処理の続きに行きます"
    Resume Next

e002:
    MsgBox "エラー処理（e002ラベル）に飛びました"
    MsgBox "ここから終了処理に飛びます"
    e = Err.Number
    Resume Next
End Sub

Comments

[exnjinia]

エラーハンドリングの方法を考えるうえで参考になります！
回答ありがとうございました。