Dir関数を用いてフォルダ内のブック名を表示するプログラムで発生するエラー

Question

前提・実現したいこと

エクセルVBAの練習として、Dir関数を用いて該当フォルダ内にあるブックの名前を表示するコードを書いています。以下のような問題が発生しています。どこに問題があるかわかる方ご回答いただければ幸いです。

発生している問題・エラーメッセージ

7行目：メッセージボックスは表示されるが空白である。実際は該当フォルダに入っているブック名が「○○.xlsx」と表示されるようにしたい。
8行目：「プロシージャの呼び出し、または引数は不正です。」

該当のソースコード

Sub message()
Dim フォルダー名 As String
Dim ブック名 As String
フォルダー名 = ThisWorkbook.Path & "¥"
ブック名 = Dir("フォルダー名" & "*.xlsx")
Do While ブック名 <> " "
MsgBox ブック名
ブック名 = Dir()
Loop
End Sub

試したこと

5行目において、変数「フォルダー名」にダブルクォーテーションを付けた状態で上記の問題が発生します。ダブルクォーテーションがないと、5行目で「ファイル名または番号が不正です。」とエラーが出てしまいます。

Comments

[imihito]

コードの記載されているブックはどこに保存されていますか？
もしかしてOneDriveなどではないですか？

[meg_]

コードは「コードの挿入」で記入してください。

[sunaday]

ご回答いただきありがとうございます。

保存場所を変更することで解決できました。
OneDriveに保存されている状態でできなかったのは何故でしょうか？

コードの記入の仕方、以後気を付けます。

Answer 1

修正点は２箇所

変数は"で囲んではいけない。囲むと単なる文字列になる。
" "は半角空白、Dir関数がファイルが見つからないときに返すのは ""（空文字列、長さ0の文字列）

Sub message()
    Dim フォルダー名 As String
    Dim ブック名 As String
    フォルダー名 = ThisWorkbook.Path & "\"
    ブック名 = Dir(フォルダー名 & "*.xlsx")
    Do While ブック名 <> ""
        MsgBox ブック名
        ブック名 = Dir()
    Loop
End Sub

Comments

[sunaday]

回答いただきありがとうございます。
変数の”を外し、6行目の""を空文字列にしたところ、５行目を実行しようとしたときに「ファイル名または番号が不正です。」と表示されてしまいます。
この場合どのように書き換えたらよいでしょうか、、?

[hatena19]

回答のコードで確認しましたが、エラーなく正常に実行できています。
回答のコードをコピーしてそれを実行して確認してください。

Answer 2

OneDriveに保存されている状態でできなかったのは何故でしょうか？

についての回答です。

「ローカルウィンドウ」などで、ThisWorkbook.Pathのパスを確認すればわかるのですが、
OneDrive上のファイルの場合https://d.docs.live.net/~で始まるパス(WEB上のURL)となってしまいます。

https://~のパスはDir関数にはフォルダと認識されないため「ファイル名または番号が不正です。」のエラーが発生します。

対処としては、OneDriveに保存されている状態でもC:\~のようなローカルのパスを取得できるのがベストですが、調査不足で取得方法は不明です。

他の対処としては以下が考えられます。

• ユーザーに設定を変えて貰う

参考

OneDriveの仕様が変わったのでしょうか？ - マイクロソフト コミュニティ

• 特定の文字列から始まったらEnviron("OneDrive")でパスの先頭を置き換える

'かなり適当＆決め打ちの処理。
Dim fso As Object 'As Scripting.FileSystemObject
Set fso = VBA.Interaction.CreateObject("Scripting.FileSystemObject")

Dim p As String
p = ThisWorkbook.Path


If VBA.Strings.InStr(1, p, "https://d.docs.live.net/", vbBinaryCompare) = 1 Then
    'OneDriveのパスなら～
    Dim s() As String
    s = VBA.Strings.Split(p, "/", Limit:=5, Compare:=vbBinaryCompare)
    
    p = fso.GetAbsolutePathName(fso.BuildPath(VBA.Interaction.Environ$("OneDrive"), s(UBound(s))))
End If

MsgBox p

• (ファイル名の列挙が目的であれば)Shell.Applicationを使用する

Sub message2()
'https://teratail.com/questions/250814 (Dir関数を用いてフォルダ内のブック名を表示するプログラムで発生するエラー)
    
    'Shell32.~となっている型宣言は、「参照設定」から「Microsoft Shell Controls And Automation」を参照すると使用可能。
    
    'ファイル列挙に必要なオブジェクトをインスタンス。
    Dim appShell As Object 'As Shell32.Shell
    Set appShell = VBA.Interaction.CreateObject("Shell.Application")
    
    '探索するフォルダーを指定。
    Dim rootDir As Object 'As Shell32.Folder3
    Set rootDir = appShell.Namespace(ThisWorkbook.Path)
    
    'rootDirの中のファイル・フォルダーの集合。
    Dim dirItems As Object 'As Shell32.FolderItems3
    Set dirItems = rootDir.Items()
    
    
    'dirItems.Filterの1個目の引数に指定する定数。
        'https://docs.microsoft.com/en-us/windows/win32/api/shobjidl_core/ne-shobjidl_core-_shcontf
    Const SHCONTF_FOLDERS = &H20&       'フォルダのみを探す場合。
    Const SHCONTF_NONFOLDERS = &H40&    'ファイルのみを探す場合。
    
    '「*.xlsx」のファイルのみにフィルター。
    dirItems.Filter SHCONTF_NONFOLDERS, "*.xlsx"
    
    Dim ブック名 As String
    
    Dim itm As Object 'As Shell32.FolderItem
    For Each itm In dirItems
        ブック名 = itm.Name
        MsgBox ブック名
    Next itm
    
End Sub