Erlang : register/0がうまく動かない

Question

前提

検索してみましたが、思っていた解答がなかったのでここに質問させていただきます。
Erlangの勉強を始めたばかりの初心者なので、
ソースコードに突っ込みどころがあるとは思いますがお許しください。

実現したいこと

図1の該当のソースコードのp_sleeping()とp_wake_up()のそれぞれをsleepとwakeで登録したい。

発生している問題

start(Name, Fun) ->
  register(Name, spawn(Fun)),
  io:format("Finish_register~n").

上記のコードのregister/2が思った通りに動かない。
エラーは吐かないがwhereis/0でundefinedが返ってくる。

該当のソースコード

-module(exercises_v1).
-author("MaSaKai").

%%-compile(export_all).
-export([rpc/1, generate_sleeping_process/0, generate_wake_process/0]).

rpc(Pid) ->
  Pid ! {self(), start_sleep},
  Pid ! {self(), start_wake_up},
  receive
    {Pid, Fun} ->
      Fun()
  after 5000 ->
    io:format("Time out!~n")
  end.

p_sleeping() ->
  receive
    {Pid_rpc, start_sleep} ->
      start(sleeping, S_Fun = fun() -> io:format("SLEEP!~n") end),
      Pid_rpc ! {self(), S_Fun}
  end.

p_wake_up() ->
  receive
    {Pid_rpc, start_wake_up} ->
      start(waking_up, W_Fun = fun() -> io:format("Wake Up!~n") end),
      Pid_rpc ! {self(), W_Fun}
  end.

generate_sleeping_process() ->
  spawn(fun p_sleeping/0).

generate_wake_process() ->
  spawn(fun p_wake_up/0).

start(Name, Fun) ->
  register(Name, spawn(Fun)),
  io:format("Finish_register~n").

図1 :　該当のソースコード(Erlang)

補足情報

Verion : Erlang (SMP,ASYNC_THREADS) (BEAM) emulator version 10.6
Editor : Intellij

Answer 1

上記のコードのregister/2が思った通りに動かない。
エラーは吐かないがwhereis/0でundefinedが返ってくる。

undefinedが返ってくる理由は、register/2で登録したプロセスがwhereis/0を呼んだときにすでに終了しているからです。

Erlangのプロセスはspawn/2で起動し、引数として渡された関数を実行します。そして関数から戻るとプロセスも終了します。ご質問のコードではspawn/2にfun() -> io:format("SLEEP!~n") endという関数を渡しています。この関数はターミナルSLEEP!と表示したらすぐに戻りますので、せっかく起動したプロセスもすぐに終了してしまいます。

同じような関数で少し実験してみましょう。以下のようなプログラムを書いてみます。

examples.erl

-module(examples).
-export([hello/0]).

hello() ->
    io:format("hello[~p]: Hello!~n", [self()]).

examplesモジュールのhello関数はターミナルに自分のPIDとHello!という文字列を表示してすぐに戻ります。これをspawn/3で実行してみましょう。

$ erl

> c("examples").
{ok,examples}

> Pid1 = spawn(examples, hello, []).
hello[<0.91.0>]: Hello!
<0.91.0>

%% erlang:is_process_alive/1は与えられたPIDを持つプロセスが
%% 存在するならtrueを返す
> is_process_alive(Pid1).
false

このようにPIDが<0.91.0>のプロセスが起動したものの、is_process_alive/1を実行したときにはすでに終了してしまっていることがわかります。

うまく動かすには関数がすぐに終了しないように関数の実行を途中で止めなければいけません。例えば以下のechoのようにreceiveを呼ぶと、何かメッセージを受信するまでその場で待たされますので、とりあえずはうまくいきます。

-export([hello/0, echo/0, rpc/2]).

%% この関数は受信したメッセージを送信者に送り返す。メッセージを1つ受信したら関数から戻る
echo() ->
    receive
        %% 送信者へメッセージを送り返す
        {Sender, Msg} ->
            io:format("echo[~p]: Received ~p from ~p~n", [self(), Msg, Sender]),
            Sender ! {self(), Msg}
    end.

rpc(Pid, Msg) ->
    Pid ! {self(), Msg},
    io:format("rpc[~p]: Sent ~p to ~p~n", [self(), Msg, Pid]),
    receive
        {Pid, Msg1} ->
            io:format("rpc[~p]: Received ~p from ~p~n", [self(), Msg1, Pid])
    after 5000 ->
        io:format("Time out!~n")
    end.

実行してみます。

> Pid2 = spawn(examples, echo, []).
<0.94.0>

> is_process_alive(Pid2).
true

%% メッセージを送信する
> examples:rpc(Pid2, "Hey!").
rpc[<0.84.0>]: Sent "Hey!" to <0.94.0>
echo[<0.94.0>]: Received "Hey!" from <0.84.0>
rpc[<0.84.0>]: Received "Hey!" from <0.94.0>
ok

%% receiveを実行したあとに関数から戻るのでプロセスが終了する
> is_process_alive(Pid2).
false

このように1回だけメッセージが受信できるようになりました。

もしプロセスにいくつもメッセージを受信させたいなら、関数から戻らないように関数内で自分自身を呼び出す必要があります。

-export([hello/0, echo/0, echo_loop/0, rpc/2]).

%% この関数は受信したメッセージを送信者に送り返す
%% quitというメッセージを受信しない限りは、自分自身を呼び出すことで同じ処理を繰り返す
echo_loop() ->
    receive
        %% quitを受信したら終了する
        {Sender, quit} ->
            io:format("echo_loop[~p]: Received quit from ~p~n", [self(), Sender]),
            Sender ! {self(), "Bye."};
        %% それ以外のメッセージは送信者へ送り返す
        {Sender, Msg} ->
            io:format("echo_loop[~p]: Received ~p from ~p~n", [self(), Msg, Sender]),
            Sender ! {self(), Msg},
            %% 終了しないように自分自身を呼び出す
            echo_loop()
    end.

> Pid3 = spawn(examples, echo_loop, []).
<0.104.0>

> examples:rpc(Pid3, "Howdy!").
rpc[<0.102.0>]: Sent "Howdy!" to <0.104.0>
echo_loop[<0.104.0>]: Received "Howdy!" from <0.102.0>
rpc[<0.102.0>]: Received "Howdy!" from <0.104.0>
ok

%% まだプロセスが動いている
> is_process_alive(Pid3).
true

> examples:rpc(Pid3, "Yo!").
rpc[<0.102.0>]: Sent "Yo!" to <0.104.0>
echo_loop[<0.104.0>]: Received "Yo!" from <0.102.0>
rpc[<0.102.0>]: Received "Yo!" from <0.104.0>
ok

%% quitメッセージを送るとecho_loop/0関数から戻るのでプロセスが終了する
> examples:rpc(Pid3, quit).
rpc[<0.102.0>]: Sent quit to <0.104.0>
echo_loop[<0.104.0>]: Received quit from <0.102.0>
rpc[<0.102.0>]: Received "Bye." from <0.104.0>
ok

> is_process_alive(Pid3).
false

ご質問のプログラムに戻ります。

図1の該当のソースコードのp_sleeping()とp_wake_up()のそれぞれをsleepとwakeで登録したい。

p_sleeping/0関数の中でstart(sleeping, S_Fun = fun() -> io:format("SLEEP!~n") end)のようにするのではなく、generate_sleeping_process/0関数でstart(sleep, fun p_sleeping/0)のようにすれば登録できます。

rpc(Pid) ->
  %% 内容は変更なし

p_sleeping() ->
  receive
    {Pid_rpc, start_sleep} ->
      %% ここでstart/2を呼ぶのはやめる
      S_Fun = fun() -> io:format("SLEEP!~n") end,
      Pid_rpc ! {self(), S_Fun}
  end.

p_wake_up() ->
  receive
    {Pid_rpc, start_wake_up} ->
      %% ここでstart/2を呼ぶのはやめる
      W_Fun = fun() -> io:format("Wake Up!~n") end,
      Pid_rpc ! {self(), W_Fun}
  end.

generate_sleeping_process() ->
  %% start/2を呼ぶように変更する
  start(sleep, fun p_sleeping/0).

generate_wake_process() ->
  %% start/2を呼ぶように変更する
  start(wake, fun p_wake_up/0).

start(Name, Fun) ->
  register(Name, spawn(Fun)),
  io:format("Finish_register~n").

実行結果

> c("exercises_v1").
{ok,exercises_v1}

> exercises_v1:generate_sleeping_process().
Finish_register
ok

> exercises_v1:generate_wake_process().
Finish_register
ok

> PidS = whereis(sleep).
<0.95.0>

> PidW = whereis(wake).
<0.97.0>

> exercises_v1:rpc(PidS).
SLEEP!
ok

> exercises_v1:rpc(PidW).
Wake Up!
ok

%% p_sleeping/0関数は1回receiveすると戻るので、2回目の呼び出しはできない
> exercises_v1a:rpc(PidS).
Time out!
ok

ただし、上の最後のrpc(PidS)呼び出しがtime outになることからわかるとおり、p_sleeping/0関数とp_wake_up/0関数はメッセージを1回ずつしか受信できません。メッセージを何度も受信させたい場合はecho_loop/0関数のように自分自身を呼び出す必要があります。

Comments

[MaSaKai]

回答ありがとうございます。
自分のプロセスに対する考え方が誤っていたことが十分にわかりました。
詳細に説明していただきわかりやすかったです。