Public変数が呼び出せない

Question

#Publicで宣言した変数が別のプロシージャから呼び出せない

#エラー　変数が定義されていません。
呼び出したいのは、UniPageNです。支払通知書の分割で、ページ数が1枚目の時とそれ以降の時で読むタグを変更したいです。

Option Explicit


Sub mergePDF(stPg As Long, edPg As Long, wkAr() As String, wkctm As String, ExpFld As String)
    Dim acObjUni As New Acrobat.AcroPDDoc            '結合用に使うAcrobatオブジェクト
    Dim acObjIns As New Acrobat.AcroPDDoc            '追加用に使うAcrobatオブジェクト
    Dim rsUni As Long '結合用PDF戻り値
    Dim rsIns As Long    '挿入用PDF戻り値
    Dim i As Long
    Dim wkInsFile As String
    Public UniPageN As Long: UniPageN = 0     'ページ数
    rsUni = acObjUni.Create()
    Debug.Print ("rsUni:" & rsUni)
    
'   For i = stPg To (edPg - stPg) + 1
    For i = stPg To edPg
        
        wkInsFile = wkAr(0) & "\" & wkAr(i)
        Debug.Print ("wkInsFile:" & wkInsFile)
        rsIns = acObjIns.Open(wkInsFile)
        Debug.Print ("rsIns:" & rsIns)
        rsUni = acObjUni.InsertPages(UniPageN - 1, acObjIns, 0, 1, True)
        Debug.Print ("rsUni:" & rsUni)
'       rsUni = acObjUni.InsertPages(UniPageN - 1, acObjIns, 0, 1, False)
        rsIns = acObjIns.Close()
        Debug.Print ("rsIns:" & rsIns)
        
        UniPageN = UniPageN + 1
        Debug.Print ("UniPageN:" & UniPageN)
        
    Next
    'PDFに名前を付けて保存
    rsUni = acObjUni.Save(PDSaveFull, ExpFld & "\支払通知書_" & Trim(wkctm) & "_" & Format(Now(), "yyyymmddhhmmss") & ".pdf")
    Debug.Print ("rsUni:" & rsUni)
    rsUni = acObjUni.Close()
    
    Set acObjUni = Nothing
    Set acObjIns = Nothing

End Sub


Function xmlSCH(wkFileN As String) As String

    Dim objXML As MSXML2.DOMDocument60
'    Dim pElem As MSHTML.HTMLParaElement
'    Dim e As MSHTML.HTMLHtmlElement
    Dim rsLoad As Long
    Dim SCH As Object
    Dim prmXML As Long
    Dim wkCusCD As String
    Dim arMod() As Long

    '初期設定
    xmlSCH = ""
    prmXML = 0
    ReDim arMod(3)
    
    Set objXML = New MSXML2.DOMDocument60
    objXML.async = False
    
    rsLoad = objXML.Load(wkFileN)
    Debug.Print ("rsLoad:" & rsLoad)
    
    If objXML.parseError.ErrorCode <> 0 Then
        MsgBox "ロード失敗:  Code " & objXML.parseError.ErrorCode & vbCrLf & vbCrLf & objXML.parseError.reason
        Exit Function
    End If
    
   Debug.Print (UniPageN)
    If UniPageN = 1 Then
   '===========================1枚目の処理==============================
    For Each SCH In objXML.getElementsByTagName("P") 'Pタグ列を処理
    Debug.Print ("SCH.XML:" & SCH.XML)
        If InStr(SCH.XML, "支払通知番号") > 0 Then 'SCH.XMLから"支払通知"があった場合はIf
            prmXML = prmXML + 1
            Debug.Print ("prmXML:" & prmXML)
            
            'InStr(検索元, 検索ワード)見つからない場合:0,見つかった場合:1以上
            arMod(0) = InStr(SCH.XML, "お客様コードNO:") + 13 'お客様コードが始まる位置　先頭から9文字目
            Debug.Print ("arMod(0):" & arMod(0))
            arMod(1) = InStr(SCH.XML, "支払通知番号") 'お客様コードが終わる位置　支払い通番号から-0文字目
            Debug.Print ("arMod(1):" & arMod(1))
            wkCusCD = Mid(SCH.XML, arMod(0), (arMod(1) - arMod(0))) 'Mid(String,start,[,length])
            Debug.Print ("wkCusCD:" & wkCusCD)
        End If
    Next
    Else
    '=======================2枚目以降の処理==============================
    For Each SCH In objXML.getElementsByTagName("Table") 'thタグ列を処理したい"
    Debug.Print ("SCH.XML:" & SCH.XML)
        If InStr(SCH.XML, "お客様コードNO") > 0 Then
            prmXML = prmXML + 1
            Debug.Print ("prmXML:" & prmXML)
            'InStr(検索元, 検索ワード)見つからない場合:0,見つかった場合:1以上
            arMod(0) = Len(SCH.XML) '全文字数の取得
            Debug.Print ("arMod(0):" & arMod(0))
            arMod(1) = InStr(SCH.XML, "お客様コードNO:") + 9 'お客様コードが始まる位置　先頭から9文字目
            Debug.Print ("arMod(1):" & arMod(1))
            wkCusCD = Mid(SCH.XML, arMod(1), (arMod(0) - arMod(1))) 'Mid(String,start,[,length])
            Debug.Print ("wkCusCD:" & wkCusCD)
        End If
    Next
    End If
     

    xmlSCH = wkCusCD '現在の取引先CD
    Debug.Print ("xmlSCH:" & xmlSCH)
    Set objXML = Nothing    'Objectの開放
    
End Function

Answer 1

パブリック変数は関数の外で宣言してください。
またmergePDFとxmlSCHが同じモジュールに存在しているのであれば、publicをつける必要はありません。

Dim UniPageN As Long     'ページ数

Sub mergePDF(stPg As Long, edPg As Long, wkAr() As String, wkctm As String, ExpFld As String)
    Dim acObjUni As New Acrobat.AcroPDDoc            '結合用に使うAcrobatオブジェクト
    Dim acObjIns As New Acrobat.AcroPDDoc            '追加用に使うAcrobatオブジェクト
    Dim rsUni As Long '結合用PDF戻り値
    Dim rsIns As Long    '挿入用PDF戻り値
    Dim i As Long
    Dim wkInsFile As String
    UniPageN = 0     'ページ数
～

Answer 2

private UniPageN As Long
Sub mergePDF(stPg As Long,
    UniPageN = 0     'ページ数

モジュールレベルで変数を適用したければ、
プロシージャの外で宣言してください。

【ExcelVBA入門】変数の適用範囲(Dim・Public)について徹底解説！
変数の適用範囲