Excel vba グラフにNewseriesで系列を追加する際に系列名が設定できない

Question

前提・実現したいこと

Excel上にて、シート「結果」にある値を元にシート「図」にある「グラフ 1」（散布図）に系列を追加するマクロを目指して作成しています。

関数「kyokusen」を実行後、系列名、系列の範囲（と系列の色）をsetして、関数「graph_series1」に値を渡し、newseriesにてそれぞれを備えた新たな系列を「グラフ 1」に追加しています。

発生している問題・エラーメッセージ

系列の追加そのものは成功しています。

グラフ系列名を「kname」にて設定しているのですが、マクロ実行後、反映されません。より具体的には「データ ソースの選択」ウィンドウ中の系列名としては出てくるのですが、「編集」ボタンを押して「系列の編集」ウィンドウ上の「系列名」に反映されません。ここが空欄になります。この状態を解消できません。

ただ、このファイルを保存して終了後、もう一度開くと、「系列名」に「="独自曲線"」のように文字列として設定されています。
なお、グラフの追加した系列を選択した際に現れる計算式は「=SERIES("独自曲線",結果!$A$2:$A$12,結果!$B$2:$B$12,1)」となっています。

該当のソースコード

以下はModule1にて記述しています。

Sub kyokusen()

'グラフ系列名
Dim Kname As Range

'グラフ参照範囲
Dim nx As Range
Dim ny As Range

'系列の色（青）
Dim mycolor As Long: mycolor = RGB(0, 0, 255)

Dim CH1 As Chart: Set CH1 = Worksheets("図").ChartObjects("グラフ 1").Chart
Dim HQ As Worksheet: Set HQ = Worksheets("結果")

CH1.ChartArea.ClearContents

    With HQ
        Set Kname = .Range("D1")
        
        Set nx = .Range("A2:A12")
        Set ny = .Range("B2:B12")
        
        Call graph_series1(CH1, Kname, nx, ny, mycolor)
    End With

End Sub

Sub graph_series1(CH As Chart, Kname As Range, nx As Range, ny As Range, mycolor As Long)

With CH.SeriesCollection.NewSeries

    .Name = Kname
    .XValues = nx
    .Values = ny
    
    '線の幅:1pt　マーカー:なし
    .MarkerStyle = xlMarkerStyleNone
    .Format.Line.ForeColor.RGB = mycolor
    .Format.Line.Weight = 1
    .Format.Line.DashStyle = msoLineSolid
End With

End Sub

試したこと

Knameを文字列（string型）にしてみましたが改善は見られず。
graph_series1の中のKnameを直接編集し、セルを参照してみましたが改善は見られず。
数式を入力してみましたが改善は見られず。
（画像にはありませんが）凡例を表示してみたところ、系列名が表示されました。

rangeでの参照ではなく数式入力が必要？そもそも個別の系列名の設定は「.name」ではない？個人で調べる限りではvbaのグラフに関しては、ネット上では情報が錯綜していたりSetSourceDataでの説明だったりして、どうにもよくわからなくなってしまいました。

補足情報（FW/ツールのバージョンなど）

発生した環境はWindows7＋Excel2013、及びWindows8.1＋Excel2016です。

※大元のマクロは本当はもっといろいろ面倒な記述があるのですが、今回投稿に当たり要点を絞って再構成しております（それでも上述の状態で問題は発生しております）。あらかじめご容赦ください。

Answer 1

ああああ、編集の画面で系列名が上手く出ないという話でしたか。
すいません。画面に出てこないと勘違いしてました。

With CH.SeriesCollection.NewSeries

    .Name = "=" & Kname.Address(, , , True)

としてください。

Comments

[glam0337_k]

回答ありがとうございます。新規ブックにコピペで改めて作ってみましたが変わらず。
提示された行を追加しても状況に変化はありませんでした。
今使っているパソコンともう一台で同じ症状が出ているので書き間違えてるのかと思ったんですが…
ともあれ、記述的には問題ないと言う事なのでしょうか。
確かに「系列名が表示されない」というだけではあります。

[glam0337_k]

「系列の編集」ウィンドウにて系列名に出てきました！
ありがとうございます。助かりました。