Excel VBAで別ブックへのデータ入力ができません。

Question

前提・実現したいこと

Excel VBAで別ブックへのデータ入力をしたいです。

###質問の内容の詳細
Excel VBAで親マクロから子マクロを呼び出し、その子マクロ内で作業中のブックとは
別のブックの任意のワークシートへデータ入力をしたいのですが、できなく困っています。

また、構文エラーはなく、マクロは実行されています。

該当のソースコード【子マクロのみソースコードを記載】

Sub 手続き名(ByVal urt2 As Variant, ByRef urm2() As Variant, ByVal mm As Integer, ByVal tn2 As String)
'イテレータ
Dim ii As Integer
'セルの番地指定
Dim cr2 As Integer, cc2 As Integer
'Workbooks型の変数
Dim book1 As Workbook

cr2 = 1
cc2 = 1

Workbooks.Open Filename:="マクロで開くワークブックのオブジェクト名"
Set book1 = ActiveWorkbook

'結果の出力
With book1
    With .Worksheets("任意のワークシート名")
        
        'データ出力先のセルのアドレスの指定
        Do Until .Cells(cr2, cc2).Value = ""
            cc2 = cc2 + 1
        Loop
        cc2 = cc2 + 2

        .Cells(cr2, cc2).Value = "テスト"    **'この"テスト"も出力されません。**
        .Cells(cr2 + 1, cc2).Value = urt2 
        For ii = 1 To mm
            .Cells(cr2 + 1 + ii, cc2).Value = urm2(ii)
        Next ii
    End With
End With

book1.Close SaveChanges:=True

End Sub

改行も含んでコードの下から11行目の"テスト"も出力されないということは、
おそらくbook1内のワークシートの指定が間違っていると思いますが、自分で調べても
分からなかったので質問しました。
基本的な質問で申し訳ありませんが、ご回答よろしくお願いいたします。

Answer 1

Sub 手続き名(ByVal urt2 As Variant, _
             ByRef urm2() As Variant)
    Dim wb As Workbook
    Dim rngDataBody As Range
    Const FName As String = "マクロで開くファイルのフルパス"

    Set wb = Workbooks.Open(Filename:=FName)

    '結果の出力セル範囲の取得
    With wb.Worksheets(1).Cells(1).CurrentRegion
        Set rngDataBody = Intersect(.Offset(2), .Columns(.Columns.Count)).Offset(, 2)
    End With

    '結果の書き込み
    With rngDataBody
        .Cells(0, 1).Value = urt2
        .Resize(UBound(urm2, 1)).Value = urm2
    End With

    wb.Close SaveChanges:=True
End Sub

Workbooks.Openメソッドは、関数のように返り値があり、
開いたブックそのものを返します。
開いたブックはアクティブに「なるはず」ですが、
次の行が実行されるまでに、アクティブになっているのか担保されないかも知れないので、
動作が不安定になります。
（開いているブックのどれかがアクティブにはなっているので、エラーにならない？）
あと、Workbooks.Openメソッドに渡すのは「オブジェクト名」ではなく、
ファイルのフルパス（文字列）ですので誤解なきよう。

また、最終列を探すためにループをしたり、
配列をシート上に展開するためにループをVBAで書く必要はありません。

Answer 2

オープンするところを次のようにしてみたら何か変わらないでしょうか。

Workbooks.Open Filename:="マクロで開くワークブックのオブジェクト名"
Set book1 = ActiveWorkbook
↓
Set book1 = Workbooks.Open(Filename:="マクロで開くワークブックのオブジェクト名")