UnityでPCからAndroidにプラットフォームを変えたら見た目が変わるのをどうにかしたい

Question

Unityで作った水の屈折っぽいものをAndroidに表示させたいのですが、プラットフォームを変更したら見た目が変わってしまいました。
どうにかしてPCのものをそのまま見れるようにしたいのですがどうすればいいかわかりません
左がプラットフォームがPC、右がAndroidのものです。
　
水の部分のShaderは下のコードです。

Shader "Custom/refract"
{
    Properties
    {
        _Color("Color", Color) = (0.8, 0.5, 0.5, 0.1)
        _MainTex("Albedo (RGB)", 2D) = "white" {}
        _Glossiness("Smoothness", Range(0,1)) = 0.5
        _Metallic("Metallic", Range(0,1)) = 0.0
        _Refraction("Refraction Index", Range(1.0, 3.0)) = 1.33
        _Distance("Refraction Distance", Float) = 10.0
    }
        SubShader
        {
            Tags { "Queue" = "Transparent" "RenderType" = "Transparent" }

            GrabPass {}

            CGPROGRAM
            #pragma surface surf Standard alpha
            #pragma target 3.0

            sampler2D _MainTex;
            sampler2D _GrabTexture;
            sampler2D _CameraDepthTexture;

            struct Input
            {
                float2 uv_MainTex;
                float3 worldPos;
                float3 worldNormal;
            };

            half _Glossiness;
            half _Metallic;
            fixed4 _Color;
            float _Refraction;
            float _Distance;

            void surf(Input IN, inout SurfaceOutputStandard o)
            {
                #define DISTANCE_DIVISOR 16.0
                #define ITERATION_COUNT 32
                #define DEPTH_THRESHOLD 0.1
                #define EDGE_BLENDING_EXPONENT 4.0

                // まず屈折方向を求め...
                float3 eyeDir = normalize(IN.worldPos - _WorldSpaceCameraPos);
                float3 refractionDir = refract(eyeDir, normalize(IN.worldNormal), 1.0 / _Refraction);

                // 透明物体の表面を起点に、少しずつ屈折方向へ進みながら
                // デプスをチェックしていき、他のオブジェクトと衝突する点を求める
                float stride = _Distance / DISTANCE_DIVISOR;
                float s = 1.0;
                float4 refractionPos = float4(IN.worldPos, 1.0);
                float4 refractionViewPos;
                float4 refractionClipPos;
                float backgroundDepth;
                float hit = 0.0;
                for (int i = 0; i < ITERATION_COUNT; i++)
                {
                    refractionPos.xyz += s * stride * refractionDir;
                    refractionViewPos = mul(UNITY_MATRIX_V, refractionPos);
                    refractionClipPos = mul(UNITY_MATRIX_P, refractionViewPos);
                    backgroundDepth = LinearEyeDepth(SAMPLE_DEPTH_TEXTURE_PROJ(_CameraDepthTexture, ComputeScreenPos(refractionClipPos)));
                    if (s * (backgroundDepth + refractionViewPos.z) < 0.0)
                    {
                        // もし衝突が検出されたら、進行方向を逆転させ
                        // 進行スピードを半減させて衝突しなくなるまで戻る
                        // 衝突しなくなったら再び進行方向逆転・スピード半減...を繰り返し
                        // なるべく正確な接触位置を求める
                        hit = 1.0;
                        s *= -1.0;
                        stride *= 0.5;
                    }
                }

                // このようなデプスだけを頼りにした衝突判定では、画面内のオブジェクトが奥行き方向に
                // どれだけの厚みを持っているかわからないので、本来であればオブジェクトの背後を
                // 素通りしていくべき屈折光経路まで衝突していると判定されてしまうことになる
                // しょうがないので「衝突している」と判定されたとしても、オブジェクトのデプスと
                // 検出された衝突点のデプスがある程度ずれているようなら誤検出と見なして検出を取り消す
                // また、判定境界の部分に発生するノイズを軽減するため、境界付近では判定値をなめらかに変える
                float depthDelta = abs(backgroundDepth + refractionViewPos.z);
                hit = hit * saturate(1.0 - pow(depthDelta / DEPTH_THRESHOLD, EDGE_BLENDING_EXPONENT));

                // 衝突していると判定された場合はグラブテクスチャの色を、そうでなければ
                // リフレクション用キューブマップの色を屈折色として採用する
                float4 grabTexColor = tex2Dproj(_GrabTexture, ComputeGrabScreenPos(refractionClipPos));
                float4 backgroundColor = UNITY_SAMPLE_TEXCUBE(unity_SpecCube0, refractionDir);
                float4 refractionColor = lerp(backgroundColor, grabTexColor, hit);
                fixed4 surfaceColor = tex2D(_MainTex, IN.uv_MainTex) * _Color;

                o.Albedo = surfaceColor.rgb * surfaceColor.a;
                o.Metallic = _Metallic;
                o.Smoothness = _Glossiness;
                o.Alpha = 1.0;
                o.Emission = refractionColor.rgb * surfaceColor.rgb * (1.0 - surfaceColor.a);
            }
            ENDCG
        }
}

どうか解決法を教えていただけるとありがたいです。よろしくお願いします

Answer 1

デプステクスチャが利用できない状態になっているのかもしれません。
水オブジェクトに下記のようなスクリプトをアタッチしてみると変化はあるでしょうか?

using UnityEngine;

[ExecuteAlways, RequireComponent(typeof(Renderer))]
public class DepthTextureEnabler : MonoBehaviour
{
    private void OnWillRenderObject()
    {
        var currentCamera = Camera.current;
        if (currentCamera != null)
        {
            currentCamera.depthTextureMode |= DepthTextureMode.Depth;
        }
    }
}