数字によってパターンマッチング

Question

入力された数字でパターンマッチングさせたい

入力された数字番目のフィボナッチ数を計算して出力するプログラムを作ったのですが、数字に応じて序数の、st,nd,rd,thを場合分けしようとした際、以下のようにcondで条件分岐させる以外にパターンマッチングなどうまい方法はあるでしょうか．
P.S.
Elixirでの標準入力でもっとうまい方法があれば教えていただきたいです...

該当のソースコード

defmodule Fib do
    def of(0), do: 0
    def of(1), do: 1
    def of(n) do
        of(n-1) + of(n-2)
    end
    def print_loading(n) do
        cond do
            div(n,10) == 1 ->
                IO.puts "now #{n}st fibonacci number loading"
            div(n,10) == 2 ->
                IO.puts "now #{n}nd fibonacci number loading"
            div(n,10) == 3 ->
                IO.puts "now #{n}rd fibonacci number loading"
            true ->
                IO.puts "now #{n}th fibonacci number loading"
        end
    end
end
#C言語でのscanf
num = IO.gets("input number?\n")
        |> String.replace("\n","")
        |> String.to_integer

worker = Task.async(fn -> Fib.of(num) end)
Fib.print_loading(num)
IO.puts "wait for the task"

result = Task.await(worker)

IO.puts "result is #{result}"

補足情報（FW/ツールのバージョンなど）

Erlang/OTP 22 [erts-10.4.4] [source] [64-bit] [smp:4:4] [ds:4:4:10] [async-threads:1] [hipe]

Elixir 1.9.1 (compiled with Erlang/OTP 22)

Answer 1

数字に応じて序数の、st,nd,rd,thを場合分けしようとした際、以下のようにcondで条件分岐させる以外にパターンマッチングなどうまい方法はあるでしょうか．

パターンマッチするならcaseとガードを使うと素直に書けそうです。

    def print_loading(n) do
        ordinal = case rem(n, 10) do
            _ when 11 <= n and n <= 13 -> "#{n}th"
            1 -> "#{n}st"
            2 -> "#{n}nd"
            3 -> "#{n}rd"
            _ -> "#{n}th"
        end
        IO.puts "now #{ordinal} fibonacci number loading"
    end

caseの部分を別の関数（ordinal_of/1）に分けてもいいかもしれません。

    def print_loading(n) do
        IO.puts "now #{ordinal_of n} fibonacci number loading"
    end

    def ordinal_of(n) 11 <= n and n <= 13, do: "#{n}th"
    def ordinal_of(n) do
        case rem(n, 10) do
            1 -> "#{n}st"
            2 -> "#{n}nd"
            3 -> "#{n}rd"
            _ -> "#{n}th"
        end
    end

（元のコードのdev(n, 10)（除算）は間違いのようでしたので、rem(n, 10)（余り）に変えました）

追記

111は111stではなくて111thなので、以下のように書くのが正解でした。

    def print_loading(n) do
        ordinal = case {rem(n, 100), rem(n, 10)} do
            {m, _} when 11 <= m and m <= 13 -> "#{n}th"
            {_, 1} -> "#{n}st"
            {_, 2} -> "#{n}nd"
            {_, 3} -> "#{n}rd"
            _ -> "#{n}th"
        end
        IO.puts "now #{ordinal} fibonacci number loading"
    end

Comments

[marny]

詳しい回答ありがとうございます！divとremは失礼しました．
11~13の序数の場合分けはすっかり忘れていました...
3桁の場合含めてcaseとガードについて大変勉強になりました．