dist関数の使い方

Question

processingで半径100の円ｃを書き円ｃに外接する四角形Rを書いた後１００個の点を打ち円の中にあれば青色、円の外なら赤色の点となるプログラムを作っていて、点と円の中心の距離を求める際にdist関数を用いているのですが、エラーがでてしまいます。float d=dist(x[i], y[i], l, m);の入れる場所をsetupやdrawの中に入れてみたり、エラーメッセージに変数iが存在しないとでてくるのでfloat d=dist(x, y, l, m);にしてiを消してみたりと思いつく限り色々やってみたのですがうまくいかないので何が悪いのか教えてください。

int l=100,m=100;
float [] x=new float[100];
float [] y=new float[100];
float d=dist(x[i], y[i], l, m);
void setup() {
  size(200, 200);
  rect(0, 0, 200, 200);
  ellipse(100, 100, 200, 200);

}


void draw() {

  for (int i=0; i<100; i++) {
    x[i]=random(0, 200);
    y[i]=random(0, 200);
  
  }

  if (d<100) {
    stroke(0, 0, 255, 100);
  } else {
    stroke(255, 0, 0, 100);
  }
  point(x[i], y[i]);
}

Comments

[stdio]

分からないところがいまいち伝わらないので箇条書きで書いて頂いてよろしいですか？
それとコードはcodeで囲って下さい。

[ex_nh0]

すいません、まだこのサイトで質問するのに慣れてないのでcodeで囲むというのがよくわかりません。
なのでコードはint l=100,m=100;から下のすべてです。
あとわからない部分についてですが
・float　ｄ＝dist(x[i],y[i],l,m)でエラーが出てしまう理由と改善点
どうかよろしくお願いします。

[thkana]

「わからない」ならやらなくていいのでしょうか...

質問の編集に入り、プログラム部分を選択して記入欄上の方の<code>をクリックすれば出来るはずです。
手動で、プログラム部分の前後に
```Processing
int l=100,m=100;
<略>
point(x[i], y[i]);
}
```
としてもいいですけれど。（`と'は違う記号なので注意)

Answer 1

float [] x=new float[100];

float [] y=new float[100];

次のように float と [] の間のスペースを取り除いてください。

float[] x=new float[100];
float[] y=new float[100];

これでエラーは消えますが、他にも間違いがあるので、どのみちうまく動きません。
しかしそれは別問題なので、改めて直してください。

Comments

[Zuishin]

「他の間違い」はスコープの間違いだったり、ループの間違いだったりと多岐にわたります。

[thkana]

> float と [] の間のスペースを取り除いてください。
私のてもとではそれではエラーに変化はありませんでした。

Answer 2

思いつく限り色々やってみた

エラー対策は、エラーメッセージを見て、ソースを見て、ちゃんと考えるものです。考えずに目茶苦茶やってもそうそう当たるものではありません。

i cannot be resolved to a variable

iは変数として解決(解釈出来ない)と言われているのですから、まずiの宣言を確認してみて下さい。
float d=dist(x[i], y[i], l, m);でiが登場する以前にiなんて宣言してないでしょ?
いちばん先頭にでも
int i;
を追加すれば、そのエラーは消えます。というか、そうするとプログラム全体でも文法エラーはなくなります。

エラーはなくても、プログラムは(多分あなたが思ったようには)動きませんけどね。文法エラーがある、というのはそれはプログラムとしての体をなしていないということなので問題外。エラーがなくなってやっと、テストで正しい日本語で解答欄を埋めた段階と思えばいいかしら。解答欄を埋めたからといって合格点なわけじゃないです。今回のように...

---

Processing(というかその中で動いているJava)では、「代入」というのは、その時点で=の右辺を計算した「結果の値」を左辺の変数の値にする(俗に「入れる」という)だけです。
float d=dist(x[i], y[i], l, m);
では、例えばその時(iは宣言されて適切な値だったとして)dist(x[i],y[i],l,m)の計算をして、それが例えば25だったら、dの値を25にする「だけ」です。(ここは代入じゃなくて「初期化」ですけれど、とにかくその「値」だけが扱われるということ)
きっと、
if (d<100) {
のところで、dと書いたらその時のdist(x[i], y[i], l, m)が新しく計算されてその値と100とを比較する...と考えたんじゃないかと思いますけど、それは違います。最初の計算で25だったら、新しくdに値を代入しない限り、プログラムが終わるまでdの値は25のまま。

---

もうひとつ、変数にはスコープ(適用範囲)というものがあります。

  for (int j=0; j<100; j++) {//前述のエラー対策で宣言したiと区別するためjに名前を変えます
    x[j]=random(0, 200);
    y[j]=random(0, 200);
  }//jの有効範囲はここまで
//略
  point(x[i], y[i]); //この場所では有効なjという変数は無い。

このjは、つまりfor文の間しか有効ではありません。最後のx[i],y[i]のiはこのfor文とは関係なく、最初に宣言したiが適用されます。もし、iを0～99まで変化させた点を打ちたいのなら、point()はfor文の中に含む場所に書いてやる必要があります。
なお、ある変数名(例えばi)が有効な中に、明確に区切られた範囲であれば(今回のfor文のように)名前が同じで、でも実体は別の変数を作ってしまうことが出来ます。あくまで別の変数になるので注意して下さい。

---

おまけ。私だったらこう書きます。(これが正解、とかいうわけではありません)
点を打ってしまったらx,yのデータはもう使わないので、さっさと描画すれば配列にデータを保存する必要はありません。
width, heightといったシステムが値を設定する変数を使えば、例えばウインドウのサイズを変えてもプログラム本体は全然いじらなくても大きい/小さい画に出来たりします。
このような画なら、画面の中心を原点にするように考えた方が考えやすくありませか? Processingでは座標の変換が簡単なので、そのようにしてみました。

void setup() {
  size(200, 200);
  background(255);
  ellipse(width/2, height/2, width, height);
}


void draw() {
  translate(width/2, height/2);//ウインドウの真ん中を0,0とする
  for (int i=0; i<100; i++) {
    float x=random(-width/2, width/2);
    float y=random(-height/2, height/2);
    float d=dist(0, 0, x, y);
    if (d<width/2) {
      stroke(0, 0, 255, 255);
    } else {
      stroke(255, 0, 0, 255);
    }
    point(x, y);
  }
}

Comments

[ex_nh0]

回答ありがとうございました。まだ勉強中ですのでわからないことだらけですのでしっかり説明してもらって
とても助かります。