VBA データクラスのようなものを作りたい

Question

現在VBAを使用してマクロを作成しています。
そこで、数値の変わらない変数を宣言するだけのクラス(モジュール？)を作成したいのですがうまくいきません。
良い方法などございましたらご教授頂けませんでしょうか。
イメージとしては

Sub Data()

    Public A As Integer
    Public B As String
    Public C As Integer

    A = 50
    B = "リンゴ"
    C = 780

End Sub

のようなクラスを作って各変数を宣言し、

Sub Main()

    Call Data
    
    Msgbox A
    Msgbox B
    Msgbox C

End Sub

といった感じでメインクラスで呼び出して使いたいのです。
現在は上記のように実装し実行すると
「Sub、 Function、 またはProperty が必要です。」
とコンパイルエラーが表示され、思ったとおりの動作になりません。
初心者故に考え方自体が間違っているような気がしないでもないのですが、
どうにか実現する方法はございませんでしょうか。

Answer 1

VBAエディタで挿入→クラスモジュールでクラスを追加できます。
クラスでは以下のようにメンバを定義します。

Public a As String

Private Sub Class_Initialize()

    a = "リンゴ"

End Sub

Class_Initializeがコンストラクタなので、こちらで変数の初期化を行います。
（VBAでは変数の宣言と同時に初期化ができないので）

モジュールでは以下のように記述してクラスのインスタンス化およびメンバの呼び出しを行います。

Public Sub test()

    Dim class As Class1
    
    Set class = New Class1
    MsgBox class.a

End Sub

なお、クラスだけは以下のように宣言とインスタンス化を同時に行うこともできます。

Dim class As New Class1

また、扱う値に数値が多いのであれば列挙型を利用するのも一つの手です。

Enum EnumName
    Member1 = 10
    Member2 = 20
End Enum

Public Sub test()
    Msgbox EnumName.Member1
    Msgbox EnumName.Member2
End Sub

Comments

[Alice0225]

わかりやすいご解説ありがとうございます。
期待する動作が実現できました！

[hatena19]

Public で宣言してしまっては、外部から自由にアクセスできてしまいますので、クラスにする意味がないような。

> 数値の変わらない変数を宣言するだけのクラス(モジュール？)を作成したい

とのことなので、ここは、Property Get のみ宣言して、読み取り専用にすべきと思います。

Public Property Get a() As String
a = "りんご"
End Property

書き込み専用なら、Property Let のみ。
読み書きできるようにするなら、Property Get と Property Let と両方宣言する、というように使い分けることができるのがクラスのメリットの一つです。

[lilithchan]

きっちり書くのであればhatena19さんのおっしゃる書き方がベストです。
が、VBAでのクラスはオブジェクト指向に必要な機能がかなり削られており、他の言語のクラスと同様に扱う必要は個人的にはないと思っています。
特に今回のように単なる値の列挙であれば、メンバ変数に外部から値を書き込まないというルールさえ設けていればpublicで宣言しても別に問題はないと思います。

ここまで書いた上であれですが、個人的には数値はEnumで宣言、他はマスタシートを設けるかConstで素直に宣言するのがベストだと思います。

Answer 2

VBAではクラスを作れないと思います。

定数を定義するならモジュール内で
Public Const A As Integer = 50
Public Const B As String = "リンゴ"
Public Const C As Integer = "780"
と記述すればよいかと思います。

ユーザー定義型というものを使えばクラスのような使い方もできるかと。
http://officetanaka.net/excel/vba/variable/12.htm

Comments

[Alice0225]

定義すべき定数の数が結構多くなりそうな為、それだけを記述したものを切り離して作りたかったのですが無理なのですね。。。

[tomo.ina]

そうでしたら、定数記述用の標準モジュールを作成すればよいですよ。

[tomo.ina]

すいません。VBAでもクラスは作れるみたいですね。
勉強不足でしたm(_ _)m

[Alice0225]

いえいえ、ご回答いただけただけでも嬉しいです。
貴重なお時間を割いて頂きありがとうございました！

Answer 3

VBAでもクラスは作成できます。

質問の例が、クラスのサンプルとして適切かどうかは別にして、そのままクラスにすると下記のようになります。

VBAウィンドウで、[挿入]-[クラスモジュール]をクリックします。
下記のコードを記述します。

Option Explicit

Public Property Get A() As Integer
    A = 50
End Property

Public Property Get B() As String
    B = "りんご"
End Property

Public Property Get C() As Integer
    C = 780
End Property

コンパイル後、名前を clsData として保存します。
標準モジュールに下記のコードを記述します。

Public Sub clsDataTest()
    Dim Data As New clsData

    MsgBox Data.A
    MsgBox Data.B
    MsgBox Data.C

End Sub

クラスでは値はプロパティで取得するといのが原則です。

プロパティが読み取り専用では、あまり使いみちがないので、もう少し有用なサンプルを。
上記の clsData のコードを下記に修正します。

Option Compare Database
Option Explicit

    Private pA As Integer
    Private pB As String
    Private pC As Integer

Public Property Get A() As Integer
    A = pA
End Property

Public Property Let A(ByVal vA As Variant)
    pA = vA
End Property

Public Property Get B() As String
    B = pB
End Property

Public Property Let B(ByVal vNewValue As Variant)
    pB = vB
End Property

Public Property Get C() As Integer
    C = pC
End Property

Public Property Let C(ByVal vNewValue As Variant)
    pC = vC
End Property

これで、プロパティの設定ができるようになります。

使用例としては、

標準モジュール

Public Sub clsDataTest()
    Dim Data(1 To 3) As clsData
    Dim i As Long, kei As Long
    

    Set Data(1) = New clsData
    With Data(1)
        .A = 50
        .B = "りんご"
        .C = 780
    End With
    
    Set Data(2) = New clsData
    With Data(2)
        .A = 51
        .B = "みかん"
        .C = 600
    End With
    
    Set Data(3) = New clsData
    With Data(3)
        .A = 52
        .B = "バナナ"
        .C = 500
    End With

    For i = 1 To 3
        kei = kei + Data(i).C
    Next
    
    MsgBox "合計は" & kei
End Sub

このようにクラスモジュールは New で複数のインスタンスを生成できます。

ここまでなら、ユーザー定義型でもできますが、クラスだとさらにメソッドを持たせたり、いろいろ拡張性があります。

Comments

[Alice0225]

そのような方法もあるのですね…勉強になります！