バッチ処理でのフォルダ、ファイル作成

Question

バッチファイルの質問

現在のコードは以下です。

@echo off
setlocal enabledelayedexpansion

rem カレントディレクトリにSongsフォルダを作成する

set FILE_PATH=Songs\
mkdir Songs

if %errorlevel% == 0 (

for %%i in (*.txt) do (
    set FILE=%%i
    rem それぞれのテキストファイルを1行ずつ読み込む
    for /f "delims=" %%a in (%FILE%) do ( 
    set NAME=%%a
    goto :exit_for
   )
   :exit_for
   set MAKE_FOLDER=%FILE_PATH%%NAME%
   echo %NAME%
   echo %MAKE_FOLDER%
   if exist "%MAKE_FOLDER%" ( 
      for /f "delims=" %%a in (%FILE%) do ( 
      echo %%a>> %MAKE_FOLDER%\%FILE%_output.txt
     )
   ) else (
      mkdir %MAKE_FOLDER%
      for /f "delims=" %%a in (%FILE%) do ( 
      echo %%a>> %MAKE_FOLDER%\%FILE%_output.txt
     )
   ) 
)
) 

このコードだと、デスクトップに複数のファイルがあるにもかかわらず、1ファイルしか作成されません。
なぜでしょうか。なぜ一番外側のfor文が機能していないのでしょうか。

追記①

@echo off
setlocal enabledelayedexpansion

rem カレントディレクトリにSongsフォルダを作成する

set FILE_PATH=Songs\
mkdir Songs

if %errorlevel% == 0 (

 for %%i in (*.txt) do (
   set FILE=%%i
   rem それぞれのテキストファイルを1行ずつ読み込む
   call :subroutine %FILE%
   set MAKE_FOLDER=%FILE_PATH%%NAME%
   if exist "%MAKE_FOLDER%" ( 
      for /f "delims=" %%a in (%FILE%) do ( 
      echo %%a>> %MAKE_FOLDER%\%FILE%_output.txt
     )
   ) else (
      mkdir %MAKE_FOLDER%
      for /f "delims=" %%a in (%FILE%) do ( 
      echo %%a>> %MAKE_FOLDER%\%FILE%_output.txt
     )
   ) 
 )
) 

:subroutine
for /f "delims=" %%a in (%1) do ( 
    set NAME=%%a
    goto :exit_for
)
:exit_for
exit /b

追記②

@echo off
setlocal enabledelayedexpansion

rem カレントディレクトリにSongsフォルダを作成する

set FILE_PATH=Songs\
mkdir Songs

if %errorlevel% == 0 (

 for %%i in (*.txt) do call subroutine1 %%i
   
   rem それぞれのテキストファイルを1行ずつ読み込む
    for /f "delims=" %%a in (%FILE%) do call:subroutine2 %%a
   set MAKE_FOLDER=%FILE_PATH%%NAME%
   if exist "%MAKE_FOLDER%" ( 
      for /f "delims=" %%a in (%FILE%) do call:subroutine3 %%a
   ) else (
      mkdir %MAKE_FOLDER%
      for /f "delims=" %%a in (%FILE%) do call:subroutine3 %%a
   ) 
) 

:subroutine1
set FILE=%1

:subroutine2
set NAME=%1
goto :exit_for
:exit_for
exit /b

:subroutine3
%1>> %MAKE_FOLDER%\%FILE%_output.txt

追記③

@echo off
setlocal enabledelayedexpansion

rem カレントディレクトリにSongsフォルダを作成する

set FILE_PATH=Songs\
mkdir Songs

if %errorlevel% == 0 (

for %%i in (*.txt) do call: function1 %%i

   set MAKE_FOLDER=%FILE_PATH%%NAME%

   if exist "%MAKE_FOLDER%" ( 
     call: function3 %%i
   ) else (
      mkdir %MAKE_FOLDER%
     call: function3 %%i
   ) 
)

:function1
set FILE=%1
call:function2 %FILE%

:function2
for /f "delims=" %%a in (%1) do ( 
set NAME=%%a
goto :exit_for
)
:exit_for
exit /b

:function3
for /f "delims=" %%a in (%1) do ( 
echo %%a>> %MAKE_FOLDER%\%1_output.txt
exit /b

追記④

@echo off
for %%i in (*.txt) do call :sub %%i
echo %FILE%
exit /b

:function1
set FILE=%1
exit /b

追記④に対するCMDの表示結果

The system cannot find the batch label specified -
The system cannot find the batch label specified -
The system cannot find the batch label specified -
The system cannot find the batch label specified -
無題2.txt

現在デスクトップには無題2.txtを含めtxtファイルが6つあります。

追記⑤

@echo off

rem カレントディレクトリにTempフォルダを作成する
set FILE_PATH=Temp\
mkdir Temp
if not %errorlevel% == 0 exit /b

for %%i in (*.txt) do call :sub %%i
exit /b

:sub
  set FILE=%1
  rem それぞれのテキストファイルを1行ずつ読み込む
  set /p NAME=<%FILE%
  set MAKE_FOLDER=%FILE_PATH%%NAME%
  if not exist "%MAKE_FOLDER%" mkdir "%MAKE_FOLDER%"
  type "%FILE%" >> %MAKE_FOLDER%\%FILE%_output.txt
exit /b

Comments

[Zuishin]

一番外側だけ残してその中に適当なコマンドを入れたらわかると思います。

Answer 1

先の質問に書いたとおりですが、

forにはいろいろ制約があるので、そのあたりを熟知していない限り、

for ～～～ do (
  ＝＝＝＝＝＝
)
・・・・・

は、全部、

for ～～～ do call :subr1
・・・・・
exit /b

:subr1
＝＝＝＝＝＝
exit/b

に書き直した方が良いです。

・括弧内で環境変数にセットしても参照するとforに入る前の値になる
・gotoするとforから抜ける

追記：
ループが1回で終わるのはgotoしているからです。
サンプル：

@echo off
for %%A in (aa bb cc) do (
	echo 1: %%A
	goto XX
:XX
	echo 2: %%A
)

gotoした時点で、forループの中であるという情報が無くなるようです。

#追記
こんな感じで。

@echo off
rem カレントディレクトリにSongsフォルダを作成する

set FILE_PATH=Songs\
mkdir Songs

if not %errorlevel% == 0 exit /b

for %%i in (*.txt) do call :sub %%i
exit /b

:sub
  set FILE=%1
  rem それぞれのテキストファイルを1行ずつ読み込む
  for /f "delims=" %%a in (%FILE%) do (
    set NAME=%%a
    goto :exit_for
  )
:exit_for
  set MAKE_FOLDER=%FILE_PATH%%NAME%
  echo %NAME%
  echo %MAKE_FOLDER%
  if exist "%MAKE_FOLDER%" ( 
    for /f "delims=" %%a in (%FILE%) do ( 
      echo %%a>> %MAKE_FOLDER%\%FILE%_output.txt
    )
  ) else (
    mkdir %MAKE_FOLDER%
    for /f "delims=" %%a in (%FILE%) do ( 
      echo %%a>> %MAKE_FOLDER%\%FILE%_output.txt
    )
  ) 
exit /b

もう少しコンパクトに書くと、

@echo off
rem カレントディレクトリにSongsフォルダを作成する
set FILE_PATH=Songs\
mkdir Songs
if not %errorlevel% == 0 exit /b

for %%i in (*.txt) do call :sub %%i
exit /b

:sub
  set FILE=%1
  rem それぞれのテキストファイルを1行ずつ読み込む
  set /p NAME=<%FILE%
  set MAKE_FOLDER=%FILE_PATH%%NAME%
  echo %NAME%
  echo %MAKE_FOLDER%
  if not exist %MAKE_FOLDER% mkdir %MAKE_FOLDER%
  type %FILE% >> %MAKE_FOLDER%\%FILE%_output.txt
exit /b

Comments

[Chandler_Bing]

なるほどありがとうございます。
もう少しリサーチして返信します。

[Chandler_Bing]

追記①のようにコードを変換しました。
結果は同じでした。
サブルーチンでgoto:をして同じなのでしょうか。

[otn]

繰り返しになりますが、
for ～～ do (
～～
)
を全部
for ～～ do call xxxx
に書き直してください。

[Chandler_Bing]

了解しました。
今から書き直します。すみません。

[Chandler_Bing]

書きな押したのですが、インターナルエラーがでます。
サブルーチンの中でサブルーチンを呼ぶべきでしょうか。

[otn]

> サブルーチンの中でサブルーチンを呼ぶべきでしょうか。
はい。そうですね。

[Chandler_Bing]

ありがとうございます。
書き直しました。

しかしlabelが見つかりませんとなります。

どうかご教授お願い致します。

[Chandler_Bing]

ありがとうございます。ご提示いただい追記のコードはエラーがでます。
私の最初のコードのほうが結果だけ見ると完成形に近い感じです。

otnotn様に最初に頂いたご指摘に戻るため
追記④を実行しました。
またご教授頂けると嬉しいです。

[otn]

>追記のコードはエラーがでます。
途中で方針変更したときの修正ミスでした。

[Chandler_Bing]

長くありがとうございます。
出来れば追記④の質問にも答えていただければ嬉しいです。

[Chandler_Bing]

また追記して頂いた2つ目のコードですが
set /p NAME=<%FILE%

で一行目だけが抽出できるのでしょうか。

[otn]

はい。set /p は1行入力するコマンドです。

追記4の質問とは？

[Chandler_Bing]

回答ありがとうございます。
質問を編集し、追記④を追加しました。

なぜこのような現象になるのか教えていただきたいです。

[Chandler_Bing]

長々申し訳ないですが、どうか返信お願いします。

[otn]

「何をしたらこうなる」という風に書いてください。意味がわかりません。

[Chandler_Bing]

追記④を実行すると追記④の下に貼った表示結果になります。
デスクトップにあるtxtファイルがすべて表示されると思っていましたが、

The system cannot find the batch label specified -
The system cannot find the batch label specified -
The system cannot find the batch label specified -
The system cannot find the batch label specified -
無題2.txt

のような結果になります。
現在デスクトップにはファイルが6つあるので数自体はあっていますが、
なぜ無題2.txt以外はファイル名が表示されないのでしょうか。

[Chandler_Bing]

回答お待ちしております。

[otn]

subというラベルがないので、callが全部エラーになって、そのあとのechoが1回だけ実行され、たまたまFILEに入っていた値が表示されている。

・ラベルを修正する。
・echoをサブルーチン内部で行う。
の2点を修正してください。

[Chandler_Bing]

上手くいきました。

ありがとうございます。

しかしい依然として、追記で頂いたコードが機能しておりません。

下のコードが一番完成形に近い形で出力されるのですが、
歌手名がフォルダで作成されるはずですが、

仮に
txt１には歌手名ABC
txt2には歌手名DEF
の場合、

ABCというフォルダは作成されるのですが、
DEFに関しては拡張子なしのファイルが出来てしまいます。

なぜでしょうか。

[otn]

パス名に空白が入っているとか？
その場合は何らかのエラーメッセージが出ていると思いますが、ディレクトリ名、ファイル名などを全部 " で囲んでください。

[Chandler_Bing]

本当にありがとうございます。
エラーメッセージは出ておりません。

””で全て囲ってみます。

[Chandler_Bing]

追記５ののように変更しました。

２人以降のファオルダは作成されましたが、
フォルダの中身が空になってしまっています。

[otn]

> ””で全て囲ってみます。
一部しか囲んでませんが？？

[Chandler_Bing]

全てカッコで囲った分を実行し成功しました。
長くお付き合いいただきありがとうございました。

[Chandler_Bing]

※文