vbaのsortの「key1:=Range(”A1”)」の列を変数を使って設定したい

Question

前提・実現したいこと

Excel vbaにて、並び替えを自動で行うようにしたいのです。
通常key1:=RANGE("A1")のように記述すると思うのですが、
Aにあたる部分を変数を利用して自由に設定できるようにしたいです。

発生している問題・エラーメッセージ

実行時エラー'1004':
'Range'メソッドは失敗しました:'_Globalオブジェクト'

該当のソースコード

Dim リスト As Worksheet
  Set リスト = ThisWorkbook.Worksheets("シート名")

Dim 変数 as Variant
変数 = リスト.Range("1:1").Find("任意の行頭名").Column

リスト.Range("A1").CurrentRegion.Sort _
  Key1:=Range(Cells(1, 変数)), _
  Order1:=xlDescending

試したこと

Range(Cells(1, 変数).Address)でもダメでした。
具体的などのように記述をすればいいのかわかりません...。

補足情報（FW/ツールのバージョンなど）

Excel2013

Answer 1

「Cells(rowIndex, columnIndex)」　で出来るかと思います。
※rowIndex、columnIndexは任意の行番号、列番号

Answer 2

リスト.Range("A1").CurrentRegion.Sort _
  Key1:=リスト.Cells(1, 変数), _
  Order1:=xlDescending

Cells(1, 変数) はRangeオブジェクトなので、それを Range()の中に入れる必要はない。いれたらエラーになる。
また、Cells(1, 変数) というように Worksheet指定を省略するとActiveSheetが対象になるので、きちんと リスト.Cells(1, 変数) というように Worksheet指定を省略しないように。

追記

Findメソッドは Rangeオプジェクトを返します。
Sortメソッドの Key1 には、Rangeオプジェクトを指定します。
これが理解できれば、下記のようにシンプルに記述できます。

    Dim リスト As Worksheet
    Set リスト = ThisWorkbook.Worksheets("Sheet2")

    Dim キー As Range
    Set キー = リスト.Range("1:1").Find("任意の行頭名")

    リスト.Range("A1").CurrentRegion.Sort _
        Key1:=キー, Order1:=xlDescending