『引数が間違った型、許容範囲外、または競合しています。』のエラーで考えられることは?

Question

前提・実現したいこと

エクセル上データを、csvファイルに手書き出したいです。
・文字コードはutf-8
・bomn 無し　の状態が欲しいです。

該当のソースコード

Public Sub CsvOutput()

   Dim Target As String, i As Long, j As Long, buf As String
    Target = ActiveWorkbook.Path & "\data.txt"
    
    MaxRow = Range("A1").End(xlDown).Row
    
    With CreateObject("ADODB.Stream")
        .Charset = "UTF-8"
        .Open      'ファイルを書き込みで開く
        For i = 1 To MaxRow
            buf = ""
            For j = 1 To 12    '何行あるかの指定
            
              'データの間にカンマを入れて変数に入れる
                buf = buf & Cells(i, j) & ","
            Next j
            .WriteText Left(buf, Len(buf) - 1), 1
        Next i
        .SaveToFile Target, 2
        
        .Position = 0 'ストリームの位置を0にする
        .Type = adTypeBinary 'データの種類をバイナリデータに変更
        .Position = 3 'ストリームの位置を3にする
        
        Dim byteData() As Byte '一時格納用
        byteData = .Read 'ストリームの内容を一時格納用変数に保存
        .Close '一旦ストリームを閉じる（リセット）
        
        .Open 'ストリームを開く
        .Write byteData 'ストリームに一時格納したデータを流し込む
        .SaveToFile Target, adSaveCreateOverWrite
       .Close
    End With

MsgBox "csvに記載完了"

End Sub

発生している問題・エラーメッセージ

.Type = adTypeBinary 'データの種類をバイナリデータに変更 
　の部分で
『引数が間違った型、許容範囲外、または競合しています。』

というエラーが出ます。

補足情報（FW/ツールのバージョンなど）

環境
whindous 7
Excel 2016

Answer 1

修正しておきました。
そもそもの原因はadTypeBinaryが未定義だからです。
https://excelwork.info/excel/adodbstream/
上記のURLなどには、adTypeBinaryが1である旨のことが書かれていますが、
adTypeBinaryが1で定義済みであるといっているわけではありません。
これを使うには自分で定義しないといけません。
自分で定義していないので、実行すると、adTypeBinaryはEmptyの値になり提示されたエラーが表示されます。
変数の定義を強要する癖をつけてください。
Option Explicitを先頭に記述すると、未定義の変数をエラーにできます。
そうすれば、adTypeBinaryが未定義であることが即座にわかり、悩まなくて済むようになります。
ほかにも、未定義の変数があるのでその分も追記しました。
あと、.SaveToFile Target, 2・・・は不要なのでコメントアウトしておきました。

Option Explicit

Public Sub CsvOutput()
    Const adTypeBinary = 1
    Const adTypeText = 2
    Const adSaveCreateOverWrite = 2
    Dim Target As String, i As Long, j As Long, buf As String
    Dim maxrow As Long
    Target = ActiveWorkbook.Path & "\data.txt"

    maxrow = Range("A1").End(xlDown).Row
    
    With CreateObject("ADODB.Stream")
        .Charset = "UTF-8"
        .Open      'ファイルを書き込みで開く
        For i = 1 To maxrow
            buf = ""
            For j = 1 To 12    '何行あるかの指定

                'データの間にカンマを入れて変数に入れる
                buf = buf & Cells(i, j) & ","
            Next j
            .WriteText Left(buf, Len(buf) - 1), 1
        Next i
        '.SaveToFile Target, 2  'ここでクローズしない

        .Position = 0    'ストリームの位置を0にする
        .Type = adTypeBinary    'データの種類をバイナリデータに変更
        .Position = 3    'ストリームの位置を3にする

        Dim byteData() As Byte    '一時格納用
        byteData = .Read    'ストリームの内容を一時格納用変数に保存
        .Close    '一旦ストリームを閉じる（リセット）

        .Open    'ストリームを開く
        .Write byteData    'ストリームに一時格納したデータを流し込む
        .SaveToFile Target, adSaveCreateOverWrite
        .Close
    End With

    MsgBox "csvに記載完了"

End Sub

Comments

[torachi]

返信遅くなってしまい、すみません。
うまく行きました！！
有難う御座います。

Answer 2

下記サイトを参考にされたのでしょうか。
.SaveToFile Target, 2　が不要のように思います。
（こちらで動作確認は行っていません。）

エクセルVBAでBOM無しのUTF-8でCSVファイルなどを出力する方法
https://tonari-it.com/excel-vba-utf8n-bom/

Answer 3

ADODB.Stream には、”.WriteText Left(buf, Len(buf) - 1), 1”　で、テキスト(文字列）が書き込まれていますから、このstreamのタイプは"adTypeText"[テキストデータ]になっているはずです。
そのStreamを開いたまま（すでにutf-8のテキストデータが入っている状態）で、タイプをバイナリー変えるのは無茶です。

そもそも「csvファイル（テキストファイルの一種）に書き出したい」のに、バイナリーに変えるという意図が不明です。