エクセルのtodoリストをoutlookのtodoリストにマクロを使って反映させたい

Question

前提・実現したいこと

発生している問題・エラーメッセージ

outlookで以下のコードで実行を押しても、outlookのtodoリストに反映されません。
エラーメッセージはでていません。
気になるのは、outlookのマクロを実行すると、エクセルのタスクリストファイルが画面には表示されていないのに開いていることになり？、ファイルを開こうとしても読み取り専用でしか開くことができません。

該当のソースコード

Sub TaskRegWithExcel()

Dim objExcel As Excel.Application

Dim wb As Workbook

Dim ws As Worksheet

Dim strFile As String

Dim i As Long

Dim objTask As TaskItem

strFile = "C:/Users/Desktop/タスクリスト.xlsx"

Set objExcel = New Excel.Application

Set wb = objExcel.Workbooks.Open(strFile)

Set ws = wb.Worksheets("タスク一覧")

For i = 2 To maxRow

    Set objTask = CreateItem(olTaskItem)

    With objTask

        .Subject = ws.Cells(i, 1).Value  'タスクのタイトル

        .StartDate = ws.Cells(i, 2).Value       '開始日

        .DueDate = ws.Cells(i, 3).Value         '期限

        .ReminderSet = ws.Cells(i, 4).Value     'アラームを鳴らすかどうか

        .ReminderTime = ws.Cells(i, 5).Value    'アラームを鳴らす時間

        .Body = ws.Cells(i, 6).Value            'タスク内容

        .Save

    End With

Next i

End Sub

試したこと

For i = 2 To maxRow　→　For i = 2 To10
のようにすると
「インデントが有効の範囲にありません」といわれました（実際には50行ほどのタスクがあります）。

Answer 1

Forループの終わりであるmaxRowという変数がどこにも宣言されておらず、中身の定義もされていません。よって、Forループ自体が機能せずにエラーメッセージが出ていなかっただけでしょう。このようなミスをなくすためには、プログラムの最初の行に以下の1行を入力してください。

Option Explicit

これをつけておけば、宣言されていない変数で実行しようとした時点でエラーになりますので、ミスをなくすことができるはずです。
Excelの最終行番号をmaxRowに代入してからForループを回してください。

質問者さんが試された通り、Forループの終わりを10などにしていれば正常に動くはずです。
該当のExcelデータがわかりませんので何とも言えませんが、入力するセルを間違えていないかチェックしたり、日付のセルに余計な文字が入っていたり（言い方を変えるとシリアル値ではないデータになっているとエラー）、TRUEかFALSEを入力するセルに余計な文字が入っていないかチェックしたり、そういった類の話になりそうに思います。
まずは本番のデータではなく、1行か2行の簡単なサンプルデータで間違いないタスクリストを作って試してみると動くでしょう。
ちなみに、エラーメッセージですが「インデント」ではなく「インデックス」だと思われます。

あと、開いたExcelを閉じるコードが記載されておりませんので、実行したら該当のExcelファイルは開きっぱなしです。
最後に以下のコードを追加して閉じてください。

wb.Close

念のため、質問者さんのコードを書き換えた状態で載せておきます。

Option Explicit

Sub TaskRegWithExcel()
    
    Dim objExcel As Excel.Application
    Dim wb As Workbook
    Dim ws As Worksheet
    Dim strFile As String
    Dim i As Long
    Dim objTask As TaskItem
    Dim maxRow
    
    strFile = "C:\Users\Desktop/タスクリスト.xlsx"
    
    Set objExcel = New Excel.Application
    Set wb = objExcel.Workbooks.Open(strFile)
    Set ws = wb.Worksheets("タスク一覧")
    
    maxRow = ws.Cells(Rows.Count, 1).End(xlUp).Row  '該当のExcelファイルの最終行を取得
    
    For i = 2 To maxRow
        Set objTask = CreateItem(olTaskItem)
        With objTask
            .Subject = ws.Cells(i, 1).Value         'タスクのタイトル
            .StartDate = ws.Cells(i, 2).Value       '開始日
            .DueDate = ws.Cells(i, 3).Value         '期限
            .ReminderSet = ws.Cells(i, 4).Value     'アラームを鳴らすかどうか
            .ReminderTime = ws.Cells(i, 5).Value    'アラームを鳴らす時間
            .Body = ws.Cells(i, 6).Value            'タスク内容
            .Save
        End With
    Next i
    
    wb.Close
    
End Sub

Comments

[cir]

丁寧な回答ありがとうございます。
上記のコードを使ったところ、問題なく動かすことができました。

次回からは、サンプルデータで試すことを忘れずにやっていきたいと思います。
素人にもわかりやすい説明をありがとうございました。