[bat]数字を任意の桁で0埋めする連番を保ちたい

Question

現状のプリフィックス連番をつけるリネームバッチだと

10番目以降が4桁の連番になってしまうのですが、３桁の状態に保ちたいです。

set count=1
for /f "tokens=*" %%n IN ('dir /b *.jpg') do (call :sub "%%n")

:sub
set name=%1
ren %1 00%count%_%name:~4%
set /a count+=1

＜現状の結果＞

001_画像.jpg
002_画像.jpg
...
0010_画像.jpg　←４桁になる

@echo off 
setlocal enabledelayedexpansion 
for /l %%a in (1,1,10) do (
  set num=%%a
  echo !num!
)
endlocal

https://jj-blues.com/cms/wantto-fill00/

なにかヒントのようなものがありましたら、よろしくお願いします。

Answer 1

00を足して右から3文字を切り出せばよいかと。

@echo off 
setlocal enabledelayedexpansion 
for /l %%a in (1,1,10) do (
  set num=00%%a
  set num=!num:~-3!
  echo !num!
)
endlocal

上のパターンに適用してみました。

set count=1
for /f "tokens=*" %%n IN ('dir /b *.jpg') do (call :sub "%%n")

:sub
set name=%1
set num=00%count%
ren %1 %num:~-3%_%name:~4%
set /a count+=1

Comments

[xu0124]

ありがとうございます｡できれば上のバッチ処理での適応でしたが参考にさせていただきます｡

[ttyp03]

実装例がわかればあとは流用してもらえればよいと思いあえて簡単な方を修正しました。
追記で上のパターンに適用したものを回答しましたのでご確認ください。

[xu0124]

ありがとうございます！！こちらの書き方が一番スマートですね！！

Answer 2

1001から始めて、下三桁を取ります。

set count=1001
for /f "tokens=*" %%n IN ('dir /b *.jpg') do (call :sub "%%n")
exit /b

:sub
set name=%1
ren %1 %count:~-3%_%name:~4%
set /a count+=1

Comments

[xu0124]

本当にありがとうございます!
目から鱗です!