Windowsバッチで、テキストファイルからデータを抽出

Question

下記の内容のテキストファイルがありまして、その中からidとファイル名をWindowsバッチで取り出し、一番下の形式のテキストファイルを作りたいと思っています。
forとfindstrで色々やってみたのですが、狙い通りのファイルを作る事ができませんでした。
Windowsバッチで下記の出力ファイルを作る事は可能でしょうか？
ご教授のほど、宜しくお願いいたします。

----- ここから入力ファイルの内容 -------
#コメント行
#コメント行

id=a
file=C:\xx\あ.txt

#コメント行
#コメント行

id=bb
file=C:\xx\い.txt

#コメント行
#コメント行

id=dd
file=C:\xx\うえ.txt

----- ここまで入力ファイルの内容 -------

----- 下記の形式のファイルを作りたい -------
a,あ.txt
bb,い.txt
dd,うえ.txt

Answer 1

とりあえずこんな感じでしょうか。

@echo off
setlocal

for /F "tokens=1,2 delims==" %%A in (%1) do call :procline %%A "%%~B"
goto :eof

:procline
if "%~2" == "" goto :eof

if "%1" == "id" set ID=%~2
if "%1" == "file" echo %ID%,%~nx2

引数にファイル名を指定して実行すると、結果を標準出力に出力します。
とりあえず「入力ファイルの内容」を渡して「下記の形式のファイル」が出力されたことは確認しましたが、ファイルパスに"="が混ざっているとうまく動きません。いろんなパターンに対応させるにはさらに工夫が必要です。

★改良版

@echo off
setlocal

for /F "eol=#" %%A in (%1) do call :procline "%%A"
goto :eof

:procline
set LINE=%~1
if "%LINE:~0,3%" == "id=" set ID=%LINE:~3%
if "%LINE:~0,5%" == "file=" call :output %ID% "%LINE:~5%"
goto :eof

:output
echo %1,%~nx2

環境変数の参照で文字数指定ができることを思い出しました。こっちの方が問題は少ないかと思います。

Comments

[kamiyui_bidan]

・コメント行にも「=」が存在する
・ファイル名に空白を含む可能性がある
・CSV作成時、文字列は"で囲んで良い

上記の追加仕様がありましたので、最終的に以下のようになりました。
ありがとうございました。m(__)m

for /F "tokens=1,2 delims== eol=#" %%A in (in.txt) do (
call :output %%A "%%~B"
)

exit

:output
if "%1" == "id" set fileID=%2
if "%1" == "file" (
echo %fileID%,%~nx2>>out.txt
)