Access2010でサブフォームにレコードごとの行番号(連番)を振りたい

Question

##質問内容
伝票管理システムを作成している者です。

伝票入力フォームを作ったのですが、そのフォームにあるサブフォームにレコードごとに行番号を振りたいです。

条件としては、レコードを削除しても欠番にならないようになることです。

例）
1 aaa bbb ccc ddd
2 eee fff ggg hhh
3 iii jjj kkk lll
のレコードあるとして、２番のレコードを削除した場合、３番がひとつ繰り上がって
２番になる
といった感じです。
↓
1 aaa bbb ccc ddd
2 iii jjj kkk lll

わかる方いましたら、教えてくださると幸いです。
ご回答、よろしくお願いします。

なお、不明な点があればコメントください。

##追記
・メインフォームの参照しているテーブル
＜伝票テーブル(T_WSlip)＞

フィールド名	データ型	備考
F_SlipCode	テキスト型	伝票コード(主キー)
F_StaffCode	テキスト型	担当者コード
F_CustomerCode	テキスト型	顧客コード
F_ApplyCode	テキスト型	適用コード
F_ProcessDate	日付/時刻型	処理日
F_ApplyValue	長整数型	割引した値

・サブフォームの参照しているテーブル
＜伝票詳細テーブル(T_WSlipDetail)＞

フィールド名	データ型	備考
F_SlipCode	テキスト型	伝票コード(主キー)
F_LineNum	長整数型	行番号(主キー)
F_ProductCode	テキスト型	商品コード
F_Cost	通貨型	単価
F_Qty	長整数型	数量

登録順に行番号を振っていきたいと考えています。

Comments

[sazi]

サブフォームに連結しているテーブル構造と一意キーおよび何順の連番にしたいかを追記して下さい

[dit.]

ここの回答者でもあるhatenaさんのサイトにこんな記事があります。参考になりませんか？
https://hatenachips.blog.fc2.com/blog-entry-58.html
追加情報である「その2」「その３」も今後役立つかもしれません。
サンプルファイルを見ると新規レコードに番号を振る方法も書いてあります。

[sazi]

@dlt.さん
過去質問（https://teratail.com/questions/192819）で紹介しましたが、要件に合わないという事でした。
どう合わないのかは分かりませんが。

[退会済みユーザー]

上と下のボタンの機能をなくしたの形を求めています

[sazi]

@Yryuさん
それはその機能を実装しなければ良いだけではないですか？

[dit.]

saziさん、過去質問見たつもりでしたがコメントまできちんと読んでませんでした。確かにありましたね。

Yryuさん、全てコピーしろと言っているわけではなく、考え方を参考にしてほしいという意味で書きました。
どの部分が何をしているのか確認してみてください。
課題で作成しているとの事だったと思いますが、あなたがどこまでわかっていて、どこまで調べて、どこまでできているかこの質問内容からはわかりません。
丸投げにならないように「ここまではできた」が見えるようにしてください。

[hatena19]

「上と下のボタンの機能をなくしたの形」
dit.さんの紹介していただいたページのサンプルで、上下ボタンのクリック時のコードとコントロール自体を削除するだけで、ご希望の動作になります。いちどご確認ください。それでだめなら、どこが希望と違うか具体的に提示してください。

[退会済みユーザー]

返信が遅くなってしまって申し訳ございません。
dit.さん、コメントありがとうございます。
＞全てコピーしろと言っているわけではなくー
もちろん重々承知はしております。自分なりに様々なサイトや提示してくださったサイトも確認し考えてはみたのですが、勉強と能力不足の私には、全てを理解するにはい至りませんでした。図々しいことはわかっていますが、
今後とも私にご知恵をお貸しいただければ幸いです。

Answer 1

質問内容を実現するのに必要なこと。

1. サブフォームは、F_LineNum（行番号）で昇順に並べ替えを設定しておく。

2. 新規追加時

更新前処理イベント(Form_BeforeUpdate)で、新規レコードの時、F_LineNumに CurrentRecor(レコード番号)を代入

1. レコード削除時

削除後確認イベント(Form_AfterDelConfirm)で、RecordsetClone を利用してカレントレコードから最終レコードまで移動してF_LineNumを連番に更新

下記のコードをサブフォームのモジュールに記述

Option Compare Database
Option Explicit
 
Private Sub Form_AfterDelConfirm(Status As Integer)
    If Status <> acDeleteOK Then Exit Sub '削除を取り消したら何もしない
    If Me.NewRecord Then Exit Sub '新規レコードの場合も何もしない
    With Me.RecordsetClone
        .Bookmark = Me.Bookmark 'フォームのカレントレコードへ移動
        Do Until .EOF 'レコードセットの最後まで
            .Edit
            !F_LineNum = .AbsolutePosition + 1 '行番号更新
            .Update
            .MoveNext
        Loop
    End With
End Sub
 
Private Sub Form_BeforeUpdate(Cancel As Integer)
    If Me.NewRecord Then Me.F_LineNum = Me.CurrentRecord
End Sub

下記のページにサンプルがあります。

帳票サブフォームで行番号フィールドの連番を維持する - hatena chips

Comments

[退会済みユーザー]

ご回答ありがとうございます。
上記のコードを試してみたのですが、２行目のレコードが出てこないのですがどうすればいいでしょうか

[hatena19]

サブフォームで新規レコードを入力しても1レコードしか表示されないのですか。
サブフォームは帳票フォームまたはデータシートビューになってますか。
あるいは、「追加の許可」が「いいえ」になっているとか。
「データ入力用」が「はい」になっているとか。
どちらにしても、提示したコードは関係ないです。フォームの設定の問題だと思いますので、それを確認してください。

[退会済みユーザー]

設定に間違いがありました。すみません。
その結果、無事問題が解決いたしました。
ありがとうございました。

Answer 2

「並び順」などという行番号を表示する順番を管理するだけのフィールドを用意し、レコードを削除したときには、「並び順」フィールドを再採番するようにすればいいのではないでしょうか？

1 aaa bbb ccc ddd 「並び順フィールドは 1」
2 eee fff ggg hhh　「並び順フィールドは 2」
3 iii jjj kkk lll　「並び順フィールドは 3」

2番目のレコードを削除したときには、次のようなプログラムを走らせます

Sub 並び順振り直し()
    
    Dim rs   As DAO.Recordset
    Dim i    As Long
    
    On Error GoTo Err_Renumber
    
    Set rs = Me.RecordsetClone
    
    If rs.RecordCount > 0 Then
        With rs
            .MoveFirst

            i=0  '初期化
            
            Do Until rs.EOF
                i = i + 1
                .Edit
                ![並び順] = i
                .Update
                .MoveNext
            Loop
        End With
    End If
    
　　Me.Requery

Err_Renumber:
    rs.Close
  
End Sub
コード

Comments

[sazi]

並びが崩れる事は少ないかもしれませんが、order by されていないので、並びは完全には保証されていないのではありませんか？
そもそも、RecordsetCloneは読み取り専用です。

[u_zu]

レコードソースはorder byされているクエリーを想定しておりました。
RecordsetCloneで、私の環境では問題なく動作しますが。。。

※あと、Err_Renumberの上に Me.requeryを入れないといけませんでしたね。

[sazi]

>RecordsetCloneで、私の環境では問題なく動作しますが
RecordsetClone直接じゃなくて、setしてるから大丈夫なんですかね？
読み取り専用という事でそういった事は試した事はなかったのです。すみません。
読み取り専用はプロパティでした・・・

[u_zu]

いえいえ、今後ともよろしくお願いします。

[sazi]

コードはマークダウンした方がいいですよ。

[hatena19]

フォームの Recordset, RecorsetClone, RecordSet.Clone すべて更新可能ですよ。
下記もご参考に。

フォームの Recordset, RecorsetClone, RecordSet.Clone の違いとは？ - hatena chips
https://hatenachips.blog.fc2.com/blog-entry-108.html

[u_zu]

hatenaさん　ありがとうございます。すごいサイトですね！

Answer 3

T_WSlipDetailのF_LineNumをオートナンバーに変更します。
新たに行番号のコントロールを追加しそのコントロールソースに以下を設定します
F_LineNumのコントロール（下記ではtxt_LineNumとしています）は非表示にします。

=IIf(IsNull([txt_LineNum]),Null,DCount("*","T_WSlipDetail","F_LineNum <=" & [txt_LineNum]))

※F_LineNumをオートナンバーに変更することで、意味合い的にT_WSlipDetailの主キーはF_LineNumになります。
明細全体での一意キーとなり、F_SlipCodeで伝票事にブロック化されます。
但し、ワークであり表示している伝票に関するデータのみだと思いますので、正式なデータに登録する際には考慮が必要です。

Comments

[退会済みユーザー]

回答ありがとうございます。
まず、行番号のところに#エラーと出てしまいます。
それと、２行目が表示されないです。

[sazi]

新規行も加味した内容に変更しました。